STS(Eclipse)でJUnit5を使用したいが、Java11ではエラーになる件

Question

Open JDK11を使用し、STS(バージョン4.4.0 2019/10/15に最新版をダウンロード）でGradleプロジェクトを作っています。
Spring Bootで簡易的なアプリを作ったところまではよいのですが、
JUnit5が以下のようなエラーが出てしまい動きません。

原因が分からず困っています。
Java1.8を使っていた時はJUnit5が利用できたのですが、Java11では利用できないのでしょうか。

以下build.gradleの設定になります。

buildscript {
    ext {
        springBootVersion = '2.1.1.RELEASE'
    }
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath("org.springframework.boot:spring-boot-gradle-plugin:${springBootVersion}")
        classpath('org.junit.platform:junit-platform-gradle-plugin:1.0.0')
    }
}

apply plugin: 'java'
apply plugin: 'eclipse'
apply plugin: 'idea'
apply plugin: 'org.springframework.boot'
apply plugin: 'io.spring.dependency-management'
apply plugin: 'org.junit.platform.gradle.plugin'

group = 'com.example'
version = '0.0.1-SNAPSHOT'
sourceCompatibility = 11

compileJava.options.encoding = "UTF-8"

configurations {
	developmentOnly
	runtimeClasspath {
		extendsFrom developmentOnly
	}
}

repositories {
	mavenCentral()
}

dependencies {

    implementation 'org.springframework.boot:spring-boot-starter-jdbc'
    implementation 'org.springframework.boot:spring-boot-starter-thymeleaf'
    implementation 'org.springframework.boot:spring-boot-starter-web'
    developmentOnly 'org.springframework.boot:spring-boot-devtools'
    runtimeOnly 'com.h2database:h2'
    testImplementation 'org.springframework.boot:spring-boot-starter-test'

    testImplementation('org.junit.jupiter:junit-jupiter-api:5.2.0')
    testImplementation('org.junit.jupiter:junit-jupiter-params:5.2.0')
    testImplementation('org.junit.jupiter:junit-jupiter-engine:5.2.0')
    testImplementation('org.mockito:mockito-core:2.21.0')
    testImplementation('org.mockito:mockito-junit-jupiter:2.21.0')
    
}

どうしても同じ結果しか出て来ず困っています。
どうやらSTS(Eclipse)はgradleのタスク実行時にSTS固有の設定を読み込むようですが、そちらをJava11に設定しても結果は同様です。検索でいろいろ調べたのですが、ヒットしませんでした。

何か対応策がありましたらご教授ください。

Comments

[退会済みユーザー]

古いSTSは Java11 は非対応ですけどね?

[spring_boot]

ありがとうございます。
STSは2か月ほど前にダウンロードしたものを使用していました。
改めて最新のものでも動かしましたが同じ結果でした。

[退会済みユーザー]

openjdkでの起動をstsがサポートしてるのか？という問題もあるよな

Answer 1

このbuild.gradleでユニットテストが実行できるかお試しください。

buildscript {
    ext {
        springBootVersion = '2.1.1.RELEASE'
    }
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath('org.springframework.boot:spring-boot-gradle-plugin:${springBootVersion}')
    }
}

plugins {
    id 'org.springframework.boot' version '2.1.1.RELEASE'
    id 'io.spring.dependency-management' version '1.0.8.RELEASE'
    id 'java'
}

group = 'com.example'
version = '0.0.1-SNAPSHOT'
sourceCompatibility = '11'

compileJava.options.encoding = 'UTF-8'

configurations {
    developmentOnly
    runtimeClasspath {
        extendsFrom developmentOnly
    }
}

repositories {
    mavenCentral()
}

dependencyManagement {
    imports {
        mavenBom 'org.junit:junit-bom:5.5.2'
    }
}

dependencies {
    implementation 'org.springframework.boot:spring-boot-starter-jdbc'
    implementation 'org.springframework.boot:spring-boot-starter-thymeleaf'
    implementation 'org.springframework.boot:spring-boot-starter-web'
    developmentOnly 'org.springframework.boot:spring-boot-devtools'
    runtimeOnly 'com.h2database:h2'

    testImplementation('org.springframework.boot:spring-boot-starter-test') {
        exclude group: 'junit', module: 'junit'
    }

    testImplementation('org.junit.jupiter:junit-jupiter')
    testRuntimeOnly('org.junit.platform:junit-platform-launcher') {
        because 'allows tests to run from IDEs that bundle older version of launcher'
    }
    testImplementation('org.mockito:mockito-junit-jupiter')
}

test {
    jvmArgs = [
          '-ea'
        , '-Dfile.encoding=UTF-8'
    ]
    useJUnitPlatform()
}