VBでプロセスの開始と終了をしているとたまに「動作を停止しました」エラーが出る。

Question

●やりたいこと
何かしらの不具合で残留しているプロセスを一括で強制終了し、ついでに必要なプログラムを実行するプログラム（以下TaskCNT.exe）を作成しています。

TaskCNT.exeの実行時に時折「TaskCNTは動作を停止しました」エラーが発生してしまいます。
該当エラー発生時刻と思われるタイミングで、[イベントビューア]には下記の記録がありました。

障害が発生しているアプリケーション名: TaskCNT.exe、バージョン: 1.1.1.0、タイム スタンプ: 0x5d3a9089
障害が発生しているモジュール名: KERNELBASE.dll、バージョン: 10.0.14393.3085、タイム スタンプ: 0x5d1d7bde
例外コード: 0xe0434352
障害オフセット: 0x000dc1e2
障害が発生しているプロセス ID: 0x2708
障害が発生しているアプリケーションの開始時刻: 0x01d545a7464f77ec
障害が発生しているアプリケーション パス: C:\Users\800001\Documents\Tool\TaskCNT.exe
障害が発生しているモジュール パス: C:\windows\System32\KERNELBASE.dll
レポート ID: c943f0d1-f5b3-44b1-b5af-7e4d1721eb9f
障害が発生しているパッケージの完全な名前:
障害が発生しているパッケージに関連するアプリケーション ID:

「TaskCNTは動作を停止しました」エラーが出ているとTaskCNT.exeが終了ずに残った状態になってしまうため、エラーが出ないようにするかエラーを無視して動作するようにしたいです。
エラーの発生タイミングや原因が全く分からず、発生も毎回ではなく同じプロセスを実行させてもたまに出たり出なかったりします。

●調べたこと
また、Visual Studio でデバッグ中、TaskCNTからExcelマクロを実行した際、Excelマクロが何かしらの原因でエラーが発生したり強制終了したときにTaskCNT内のxlApp.Run(bookName & "!" & mtd)の部分で下記のエラーが出ることに気づきました。

型 'System.Runtime.InteropServices.COMException' のハンドルされていない例外が Microsoft.VisualBasic.dll で発生しました

追加情報:リモート プロシージャ コールに失敗しました。 (HRESULT からの例外:0x800706BE)

そこで、マクロやプロセスを実行する部分をまるっとTryで括るとマクロ強制終了時にエラーは出ずに本プログラムも正常に終了します。
しかし、肝心のKERNELBASE.dllが原因の「TaskCNTは動作を停止しました」エラーが不定期で発生する現象は直らず。

以下、ソースコードです。

Imports System.Management

Module Module1

    'メイン関数
    Sub Main()
        Dim Current_dir As String
        Dim tgt_process As Object, tgt As String

        'カレントディレクトリ取得
        Current_dir = My.Application.Info.DirectoryPath
        Console.WriteLine(Current_dir)

        '終了対象プロセスを取得
        tgt_process = Load_Settings(Current_dir & "\kill.ini")
        If IsArray(tgt_process) Then
            'すべてのプロセス一覧で実施する
            For Each tgt In tgt_process
                Dim arg As Object = Split(tgt, "?")

                'tgtのプロセスを取得
                Dim ps As System.Diagnostics.Process() =
            System.Diagnostics.Process.GetProcessesByName(arg(0))

                If UBound(arg) = 0 Then 'ユーザ名指定なくプロセス終了
                    For Each p As System.Diagnostics.Process In ps
                        'プロセスを強制的に終了させる
                        p.Kill()
                    Next
                ElseIf UBound(arg) = 1 Then 'ユーザ名指定でプロセス終了
                    '対象のユーザー名のみ強制終了
                    pkill_by_user(arg(1), ps)
                End If
            Next
        Else
            Console.WriteLine("kill.iniの記載が見当たりません。")
        End If

        '起動対象プロセスを取得
        tgt_process = Load_Settings(Current_dir & "\launch.ini")
        If IsArray(tgt_process) Then
            'すべてのプロセス一覧で実施する
            For Each tgt In tgt_process
                Dim arg As Object = Split(tgt, "?")

                '相対パスを絶対パスにする
                System.Environment.CurrentDirectory = Current_dir
                arg(0) = System.IO.Path.GetFullPath(arg(0))
'                Try '★←ここをTryで括るとマクロ強制終了時にエラーは出ないものの、原因不明のKERNELBASE.dllエラーは直らず
                If UBound(arg) = 2 Then 'Excelマクロ実行
                    Call CallMacro(arg(0), arg(1), arg(2))
                ElseIf UBound(arg) = 3 Then 'Excelマクロ実行（セーブフラグ付き）
                    Call CallMacro(arg(0), arg(1), arg(2), arg(3))
                ElseIf UBound(arg) = 0 Then 'プロセス起動
                    'tgtのプロセスを起動
                    Dim p As System.Diagnostics.Process = System.Diagnostics.Process.Start(tgt)
                End If
'                Catch ex As Exception
'                    Console.WriteLine("プロセス「" & tgt & "」が見つかりません。")
'                End Try

            Next
        Else
            Console.WriteLine("launch.iniの記載が見当たりません。")
        End If

        '#If DEBUG Then
        '        Console.WriteLine("続行するには何かキーを押してください．．．")
        '        Console.ReadKey()
        '#End If
    End Sub


    '設定ファイルを読み込む
    Function Load_Settings(ByVal fileName As String)
        Dim tmp_line As String, arynum As Long = 0, Ans_vrt = New String() {""}

        Load_Settings = ""  '戻り値をリセット

        If System.IO.File.Exists(fileName) Then     '設定ファイルが存在する場合のみ読み出す
            'fileNameをShift-JISコードとして開く
            Dim sr As New System.IO.StreamReader(fileName,
                 System.Text.Encoding.GetEncoding("shift_jis"))
            '内容を一行ずつ読み込む
            While sr.Peek() > -1
                tmp_line = sr.ReadLine()
                tmp_line = Trim(tmp_line)
                '#から始まっていたらエスケープ文字と判断
                If Left(tmp_line, 1) <> "#" And Len(tmp_line) > 0 Then
                    ReDim Preserve Ans_vrt(arynum)
                    Ans_vrt(arynum) = tmp_line
                    arynum = arynum + 1
                End If
            End While

            '内容が何か入っていたら実施
            If arynum > 0 Then
                Load_Settings = Ans_vrt     '戻り値を出す
            End If
        End If

    End Function

    'Excelのマクロを実行する
    Sub CallMacro(ByVal fileName As String, ByVal bookName As String, ByVal mtd As String, Optional ByVal saveE As Boolean = True)
        ' Excel.Application の新しいインスタンスを生成する
        Dim xlApp As New Object
        Dim xlBooks As Object

        xlApp = CreateObject("Excel.Application")
        xlBooks = xlApp.Workbooks

        ' xlApplication から WorkBooks を取得する
        ' 既存の Excel ブックを開く
        xlBooks = xlApp.Workbooks
        xlBooks.Open(fileName)

        ' Excel 表示有無
        xlApp.Visible = False
        '保存しますかダイアログ非表示
        xlApp.DisplayAlerts = False

        ' マクロを実行する
        xlApp.Run(bookName & "!" & mtd)   '★←マクロが強制終了するとここでエラー

        'セーブフラグがあれば保存する
        If saveE Then
            xlBooks(1).Save()
        End If

        ' Excel を終了する
        xlApp.Quit()
        System.Runtime.InteropServices.Marshal.ReleaseComObject(xlBooks)
        System.Runtime.InteropServices.Marshal.ReleaseComObject(xlApp)
    End Sub

    '特定ユーザーのプロセスを終了する
    Sub pkill_by_user(ByVal tgt_user As String, ByVal ps As System.Diagnostics.Process())
        Dim id_tgt_user = New String() {""}, ui As Long = 0
        Dim mc As New System.Management.ManagementClass("Win32_Process")
        Dim moc As System.Management.ManagementObjectCollection = mc.GetInstances()
        Dim mo As System.Management.ManagementObject
        For Each mo In moc
            Dim id As String = mo("ProcessId").ToString()

            Dim methodName(1) As String
            mo.InvokeMethod("GetOwner", methodName)
            Dim user As String = methodName(0)
            Dim domain As String = methodName(1)

            If tgt_user = user Then
                ReDim Preserve id_tgt_user(ui)
                id_tgt_user(ui) = id
                ui = ui + 1
            End If
        Next mo

        If ui > 0 Then
            For Each p As System.Diagnostics.Process In ps
                For Each u As String In id_tgt_user
                    'プロセスID一致検索
                    If p.Id = u Then
                        'プロセスを強制的に終了させる
                        p.Kill()
                    End If
                Next
            Next
        End If
    End Sub

End Module

Comments

[kenshirou]

恐らく、KERNELBASE.dllのエラーが出ているのは、何らかの理由でプロセスのKillがうまくいかなかったのではないかと思います。
ところで、何のプロセスをKillしようとしていますか？
例えば、何らかの理由でExcelのプロセスが残ってしまい、これをKillしようとしていますか？
そうであれば、ReleaseComObjectを行うべきオブジェクトが足りていないようにも思います。
（例えば、xlBooks(1)に該当するオブジェクトがReleaseComObjectされていないように見受けられます。）
もし違っていたらゴメンナサイ。

[ot2os]

> 恐らく、KERNELBASE.dllのエラーが出ているのは、何らかの理由でプロセスのKillがうまくいかなかったのではないかと思います。

ありがとうございます。

プロセスのkill部分も併せてまるっとTryで括ると該当のエラーなく動作するようになりました。
エラー自体が間欠的なものなのですが、今のところ丸一日問題なく動いているので多分大丈夫です。
ちょっと乱暴な対処ですが、原因がわかるまでこれで運用してみようと思います。

> ところで、何のプロセスをKillしようとしていますか？

Killしようとしているのは主にvbsやExcelのVBAマクロ、InternetExplorer等のプロセスです。
これらが動作が遅すぎたりエラーが出たりして止まることがあるのでKillしています。
そういった不具合がないように都度各スクリプトやマクロの修正はしているのですが、それでも何かしらの原因で止まってしまうことがあるのでこのような仕様にしています。

Excelブックの保存は「xlBooks.Save()」とすると「追加情報:公開メンバー 'Save' は型 'Workbooks' に見つかりませんでした。」エラーが出るので「xlBooks(1).Save()」を入れています。
Workbooksのオブジェクトの仕様がよくわからないのですが、「System.Runtime.InteropServices.Marshal.ReleaseComObject(xlBooks(1))」などと入れると「追加情報:インデックスが無効です。 (HRESULT からの例外:0x8002000B (DISP_E_BADINDEX))」が出てしまいます。

[kenshirou]

試してはいないのですが、例えば、「xlBooks(1).Save()」のところは
Dim bk As Object = xlBooks(1)
のようにブックオブジェクトのインスタンスを変数で受け、
bk.Save()
としてから、xlBooks変数のCOM解放の前に上記変数bkのCOM解放を行う、というイメージです。
ところで、System.Runtime.InteropServices.Marshal.ReleaseComObjectより、System.Runtime.InteropServices.Marshal.FinalReleaseComObjectを使用した方が安全だと言われています。
私は以下のサイト等を参考に、FinalReleaseComObjectを使用しています。
https://seikousyahenomichi.com/exceledit/

[ot2os]

ご教示いただいた方法で正常に動作しました。
継続して動作するかは引き続き検証してみます。

ありがとうございました。

Answer 1

kenshirouさんにいただいた情報を基にプロセスのkill部分を下記のようにtryで囲うことによって処置しました。
少々乱暴な方法ですが、数日経っても正常に動作しているようなのでひとまずこれで使ってみることにします。

ありがとうございました。

Try
    If UBound(arg) = 0 Then 'ユーザ名指定なくプロセス終了
        For Each p As System.Diagnostics.Process In ps
            'プロセスを強制的に終了させる
            p.Kill()
        Next
    ElseIf UBound(arg) = 1 Then 'ユーザ名指定でプロセス終了
        '対象のユーザー名のみ強制終了
        pkill_by_user(arg(1), ps)
    End If
Catch ex As Exception
    Console.WriteLine("プロセス「" & tgt & "」が終了できません。")
End Try

同じく、kenshirouさんにいただいた情報を基にExcelのマクロ実行後のブック保存と終了処理は下記のようにFinalReleaseComObjectにしました。
こちらも数日動作していますが問題ないようです。

'セーブフラグがあれば保存する
If saveE Then
    Dim bk As Object = xlBooks(1)
    bk.Save()
    System.Runtime.InteropServices.Marshal.FinalReleaseComObject(bk)
End If

' Excel を終了する
xlApp.Quit()
System.Runtime.InteropServices.Marshal.FinalReleaseComObject(xlBooks)
System.Runtime.InteropServices.Marshal.FinalReleaseComObject(xlApp)