バッチファイルでのサブルーチン処理について

Question

バッチファイル内でサブルーチンを作るため、以下のような処理を作ったのですが、なぜかlogic1がIF文に入らなくても実行されてしまいます。

どうしてもわからず、宜しければご教示ください。
どうぞよろしくお願いいたします。

@echo off

call :set_wday

REM *** 水曜日または土曜日の場合にWED_OR_SATがTRUEになる
set WED_OR_SAT=FALSE
IF %WDAY%==3 set WED_OR_SAT=TRUE
IF %WDAY%==6 set WED_OR_SAT=TRUE

IF %WED_OR_SAT%==TRUE (
call :logic1
)

echo 12345

:logic1
	echo 6789
exit /b


:set_wday
	set TODAY=%date%

	REM *** 日付の分解
	set /a h=%TODAY:~0,2%
	set /a y=%TODAY:~2,2%
	set m1=%TODAY:~5,1%
	set m2=%TODAY:~6,1%
	if "%m2%" equ "/" (
	set /a m=m1
	set /a d=%TODAY:~7,2%
	) else (
	set /a m=m1*10+m2
	set /a d=%TODAY:~8,2%
	)
	if %m%==1 ( set /a y-=1&set /a m+=12 )
	if %m%==2 ( set /a y-=1&set /a m+=12 )

	REM *** ツェラーの公式
	set /a week_value=( y + (y/4) + (h/4) - 2*h + (13*(m+1)/5) + d ) %% 7

	REM *** 曜日の設定 WDAY = 0:SUN/1:MON/2:TUE/3:WED/4:THU/5:FRI/6:SAT
	if %week_value%==0 set WDAY=6
	if %week_value%==1 set WDAY=0
	if %week_value%==2 set WDAY=1
	if %week_value%==3 set WDAY=2
	if %week_value%==4 set WDAY=3
	if %week_value%==5 set WDAY=4
	if %week_value%==6 set WDAY=5
exit /b

Answer 1

IF %WED_OR_SAT%==TRUEを満たさない場合、
echo 12345を実行後、終了でよいのでしょうか？
それでは、echo 12345の後を実行しないよう、exitすればいいです。
（:logic1はジャンプ用のラベルでしかないため、そこでバッチ処理が終了するということはないです。
おそらく、IF %WED_OR_SAT%==TRUEを満たす場合、echo 6789を2回実行しているはずです。）

Comments

[grnfnt]

早速のご回答ありがとうございます。

このバッチを呼ぶためのバッチがあるのですが、echo 12345 の処理が終わった後、その下にも処理がありまして、それらが終わったら大元のバッチからまた違うバッチが読まれる仕組みとなってます。

サブルーチン同様と解釈しているので、なぜlogic1が実行されてしまうのかがどうしてもわからないんですよね。。

[kenshirou]

入れ違いで回答本文を補足しました。
exit /bでジャンプ前の行に戻ることができるので、サブルーチン的なイメージを持ってしまいますが、あくまでも:logic1はジャンプ用のラベルでしかない、と割り切って考えた方がよいかも知れません。
（処理行がラベルの所まで来たら、前に実行したかどうかは関係なく、制御命令がなければラベル以下も処理してしまう）

[grnfnt]

なるほど！そういうことでしたかー。
全て謎が解けてスッキリしました。

とてもご丁寧なご回答本当にありがとうございました。