Elixirでatomをキーに持つマップをファイルに保存したい

Question

やりたいことはタイトルの通りで，どうするのが良いのかわからず困っています．
%{key1: "value1", key2:"value2"}
のようなマップをリストにしたものをファイルに保存しようとしています．
イメージとしてはデータベースのレコードを保存です．

Poisonを使ってJSON形式にして保存・読み出しはできたのですが，これを用いて保存してしまうと，Atomのキーが文字列として取り扱われるので，次に読み出したときには文字列のキーとして読み込まれてしまいます．このような場合，どう取り扱うのが正しいのでしょうか？

Answer 1

Poisonならdecodeの際にキーをatomに変換するkeys: :atoms!オプションを使うといいでしょう。

iex> map = %{key1: "value1", key2: "value2"}
%{key1: "value1", key2: "value2"}

# mapをjson文字列に変換する
iex> json = Poison.encode!(map)
"{\"key2\":\"value2\",\"key1\":\"value1\"}"

# json文字列をmapに変換する。その際、キーはatomにする
iex> Poison.decode!(json, %{keys: :atoms!})
%{key1: "value1", key2: "value2"}

別の方法として、JSONではなく、Erlang組み込みのシリアライズフォーマットであるErlang external term formatを使うこともできます。

JSON（JavaScript Object Notion）は元々はJavaScriptのオブジェクトをシリアライズするために考案されたフォーマットですので、ErlangやElixirのatomのようなJavaScriptにはないデータ型は表現できません。Erlangは分散システムの開発が得意な言語ですので、ノード間でErlangのデータ（Erlang termと呼ばれます）を送受信するための専用のシリアライズフォーマットが昔から言語に組み込まれています。このフォーマットならmapだけでなく、atomなども表現できます。

ただし、JSONは人間が直接読めるフォーマットですが、Erlang external term formatはbinary（バイト列）なので人間には読めません。その代わり、全てのErlang termが表現できます。

iex> map = %{key1: "value1", key2: "value2"}
%{key1: "value1", key2: "value2"}

# Erlang termをシリアライズする
iex> bin = :erlang.term_to_binary(map)
<<131, 116, 0, 0, 0, 2, 100, 0, 4, 107, 101, 121, 49, 109, 0, 0, 0, 6, 118, 97,
  108, 117, 101, 49, 100, 0, 4, 107, 101, 121, 50, 109, 0, 0, 0, 6, 118, 97,
  108, 117, 101, 50>>

# Erlang termをデシリアライズする
iex> :erlang.binary_to_term(bin)
%{key1: "value1", key2: "value2"}

# binaryを印字可能な文字に変換するにはBase.encode16が使える
iex> encoded = Base.encode16(bin)
"8374000000026400046B6579316D0000000676616C7565316400046B6579326D0000000676616C756532"

iex> Base.decode16(encoded)
{:ok,
 <<131, 116, 0, 0, 0, 2, 100, 0, 4, 107, 101, 121, 49, 109, 0, 0, 0, 6, 118, 97,
   108, 117, 101, 49, 100, 0, 4, 107, 101, 121, 50, 109, 0, 0, 0, 6, 118, 97,
   108, 117, 101, 50>>}