【 TabControl 】選択中のTabページのタイトル部分を太字にしたい

Question

前提・実現したいこと

TabControlで選択されたTabページのタイトル部分のみ
太字にする

発生している問題・エラーメッセージ

以下のコードにて実装をしました。ですが以下の通りの問題が
発生しました。

　・選択されたTabページ内のタイトル部分以外全てのFontが
太字になってしまいます(パターン1)。
・Tabページ内のタイトル部分は太字になりますが、
全てのTabページ内のFontも太字になってしまいます。(パターン2)

実現したいのはTabページのタイトル部分（帯の部分）のみ
太字にすることで、そのほかのボタンのテキストやラベルの
フォントは変更したくありません。

/*******************************************************/
コード補足

【変数名】 【説明】
iSelectTabIdx ： TabControl.SelectedIndexにて取得した選択中のタブページのインデックス
TabControlMain ： TabControl
TabPage1 ： TabControlのタブページ1
TabPage2 ： TabControlのタブページ2
TabPage3 ： TabControlのタブページ3
/*******************************************************/

パターン1

'選択Tabごとに分岐
            Select Case iSelectTabIdx
                Case 0
                    'ユーザー情報
                    TabPage1.Font = New Font(TabPage1.Font, FontStyle.Bold)
                    TabPage2.Font = New Font(TabPage2.Font, FontStyle.Regular)
                    TabPage3.Font = New Font(TabPage3.Font, FontStyle.Regular)
                Case 1
                    'ユーザー情報2
                    TabPage1.Font = New Font(TabPage1.Font, FontStyle.Regular)
                    TabPage2.Font = New Font(TabPage2.Font, FontStyle.Bold)
                    TabPage3.Font = New Font(TabPage3.Font, FontStyle.Regular)
                Case 2
                    'ユーザー情報3
                    TabPage1.Font = New Font(TabPage1.Font, FontStyle.Regular)
                    TabPage2.Font = New Font(TabPage2.Font, FontStyle.Regular)
                    TabPage3.Font = New Font(TabPage3.Font, FontStyle.Bold)
            End Select

パターン2

'選択Tabごとに分岐
            Select Case iSelectTabIdx
                Case 0
                    'ユーザー情報
                    TabControlMain.Font = New Font(Me.Font, FontStyle.Bold)
                    TabControlMain.Font = New Font(Me.Font, FontStyle.Regular)
                    TabControlMain.Font = New Font(Me.Font, FontStyle.Regular)
                Case 1
                    'ユーザー情報2
                    TabControlMain.Font = New Font(Me.Font, FontStyle.Regular)
                    TabControlMain.Font = New Font(Me.Font, FontStyle.Bold)
                    TabControlMain.Font = New Font(Me.Font, FontStyle.Regular)
                Case 2
                    'ユーザー情報3
                    TabControlMain.Font = New Font(Me.Font, FontStyle.Regular)
                    TabControlMain.Font = New Font(Me.Font, FontStyle.Regular)
                    TabControlMain.Font = New Font(Me.Font, FontStyle.Bold)
            End Select

補足情報（FW/ツールのバージョンなど）

VB.NET
Visual Studio2015

なお、InputManやSpreadなどGprapeCityのライセンスを保有しております。
「GprapeCity製品では実現できる」などもございましたらお教えください。

Answer 1

タブコントロールのタブをオーナードローすれば、変更できますよ。

Public Class Form1

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        'タブコントロールの描画モードをオーナードローに変更
        TabControl1.DrawMode = TabDrawMode.OwnerDrawFixed
    End Sub
 
    Private Sub TabControl1_DrawItem(ByVal sender As System.Object, ByVal e As System.Windows.Forms.DrawItemEventArgs) Handles TabControl1.DrawItem
        Dim backBrush As SolidBrush
        Dim foreBrush As SolidBrush
        Dim font As Font

 '背景や文字色、フォントは自由に設定してください

        If TabControl1.SelectedIndex = e.Index Then
            backBrush = New SolidBrush(Color.Navy)
            foreBrush = New SolidBrush(Color.White)
            font = New Font("Arial Black", 11, FontStyle.Bold)
        Else
            backBrush = New SolidBrush(SystemColors.Control)
            foreBrush = New SolidBrush(Color.Black)
            font = New Font("Arial Black", 11, FontStyle.Regular)
        End If
 
        Dim format As StringFormat = New StringFormat()
        Dim rect As RectangleF = New RectangleF(e.Bounds.X, e.Bounds.Y + 6, e.Bounds.Width, e.Bounds.Height)
        format.Alignment = StringAlignment.Center

        e.Graphics.FillRectangle(backBrush, e.Bounds)
        e.Graphics.DrawString(TabControl1.TabPages(e.Index).Text, font, foreBrush, rect, format)
    End Sub
End Class

Comments

[xxx8]

早速調べてみましたが、文字色や背景の例がほとんで
"太字にする"というFontのないようが見当たりません
お手数をおかけしますが参考になるサイトを
お知りの場合、お教えいただけないでしょうか。

[xxx8]

ご丁寧にコードまで添えて頂きまして誠にありがとうございます。

実装してみます。

[xxx8]

迅速なご対応誠にありがとうございました。
無事、実装することができ、やりたいことも実現できました。
誠にありがとうございます。