VBAでエクセルからワードのヘッダーを設定したい。

Question

前提・実現したいこと

ワードのヘッダーをエクセルから設定しようとしています。
最終的には、マクロのエクセルと同じフォルダに格納されているワードファイルを対象に機能させたいです。

自分なりに書いてみたのですが、次のエラーメッセージが出てしまい、思った様な結果を得られておりません。
大変お手数ですが、お知恵を拝借できないでしょうか。
よろしくお願い致します。

発生している問題・エラーメッセージ

Set hdr = dc.Sections(1).Headers '★☆型が一致しません★☆

該当のソースコード

Sub ヘッダーに文字列を入れる3()

Application.ScreenUpdating = False
Set mybook = ThisWorkbook.Sheets(1)

    Dim path As String
    Dim wdapp As Word.Application
    Dim wddoc As Word.Document
    Dim wdrg As Word.Range
    Dim c As Long
    Dim waitTime As Variant


    Set wdapp = CreateObject("Word.application")
    wdapp.Visible = True
    path = ThisWorkbook.path & "*.doc?"

Dim sec As Section
Dim hdr As HeaderFooter
Dim fName As String, dc As Document
fName = Dir(ThisWorkbook.path & "*.doc?", vbNormal)
Do While fName <> ""

Set dc = wdapp.Documents.Open(ThisWorkbook.path & "\" & fName)
    waitTime = Now + TimeValue("0:00:01")
    Application.Wait waitTime

Set hdr = dc.Sections(1).Headers '★☆型が一致しません★☆

With hdr.Range
.Delete
.Paragraphs.Alignment = wdAlignParagraphRight

.Text = mybook.Range("A1").Value

End With

dc.Close True
fName = Dir()
Loop
Application.ScreenUpdating = True
End Sub

Answer 1

他の方からも指摘があるように、Headers は、HeadersFootersコレクションです。
HeadersFootersコレクションは、HeaderFooterオブジェクトのコレクションなので、HeadersFootersコレクションにインデックス(wdHeaderFooterPrimary, wdHeaderFooterEvenPages, wdHeaderFooterFirstPage)で指定してHeaderFooterオブジェクトを取得します。

HeaderFooter オブジェクト (Word) | Microsoft Docs

提示のコードを修正するなら、

    Dim hdr As HeaderFooter

    Set hdr = dc.Sections(1).Headers(wdHeaderFooterPrimary)
    With hdr.Range
'        .Delete '上書きされるので必要なし
        .Paragraphs.Alignment = wdAlignParagraphRight
        .Text = mybook.Range("A1").Value
    End With

Comments

[qonoha]

ご回答頂きありがとうございました。

Answer 2

恐らくhdrの定義の型が違っているかと。
Headersで取得できるのはHeaderFooterオブジェクトではなく、HeadersFootersコレクションです。
https://docs.microsoft.com/ja-jp/office/vba/api/word.section.headers

Dim hdr As HeaderFooter
 ↓
Dim hdr As HeadersFooters

Comments

[qonoha]

ご回答頂きありがとうございました。

Answer 3

SETの仕方が分からなかったので冗長になっていますが
一応出来たので置いておきます。

'        Set hdr = dc.Sections(1).Headers '★☆型が一致しません★☆
'        With hdr.Range
'            .Delete
'            .Paragraphs.Alignment = wdAlignParagraphRight
'            .Text = mybook.Range("A1").Value
'        End With
        dc.Sections(1).Headers(1).Range.Delete
        dc.Sections(1).Headers(1).Range.Paragraphs.Alignment = wdAlignParagraphRight
        dc.Sections(1).Headers(1).Range.Text = mybook.Range("A1").Value

Comments

[qonoha]

ご回答頂きありがとうございました。