ESP-DevKitC3台を通信させる方法

Question

前提・実現したいこと

ESP32-DevKitCを3台使用し、2台でそれぞれがロータリーエンコーダを用いて値を取りもう1つとLEDテープを繋ぎ、色を2つのロータリーエンコーダの数値をもとに変化させる、というものをつくりたいです。また、それぞれが有線接続できない場所でも数値がやり取りできるようにしたいです。
本当に始めたばかりで、的外れなことを言っているかもしれません...
しかしこれ以上何を試せばいいかわからず、完全に詰まってしまいました。
「わからないことが分からないから何を聞けばいいのかわからない」状態です。
情けないことこの上無いですが、お力添えしていただければ助かります。よろしくお願いします。

試したこと

ライブラリにあるSimpleWifiSeverを試しました。このようにそれぞれの開発ボードが優先接続不可能な離れた場所でも数値のやり取りが出来るようにしたいです。このライブラリはなんとな～～～く理解できた気がするので、これを応用して作ることが出来ればうれしいです。
回答よろしくお願いします。

補足情報（FW/ツールのバージョンなど）

Comments

[y_waiwai]

いまいち意味不明ですが、Wifiでは通信はできないという前提なんでしょうか？

[dodox86]

最終的にやりたいことが盛りだくさんな訳ですが、それぞれはできているのでしょうか。あるいは全てできていないけど、最終的に3台で相互に通信できる必要があるので、それがそもそもできるかどうか心配で質問されているとか。今のままだとほぼ丸投げに近く、回答がつきづらいと思います。ひとつひとつ課題を片付けてはいかがでしょうか。

[LivingDays24_7]

ありがとうございます。
仰る通り、最終的に3つを相互で通信させる必要があるけれどそもそも出来るのかということが質問意図です。

[y_waiwai]

近距離ならWifiを使う、Wifiが使えない程遠いなら、有線でつなぐ、有線でも無理な距離（数百メートル以上？）なら、手はないでしょうね

[thkana]

「数値のやり取り」と書いているけど、本当に「やり取り」? それとも、ロータリーエンコーダを繋いだヤツからLEDテープを繋いだのに一方的にデータが流せればいいだけ?

ロータリーエンコーダとかLEDテープの操作には問題ないとして、

面倒だからUDPを使うとして、LEDテープを繋いだ1台のWifiをAPに設定、2台をそれに接続してデータを送信、受けた側はWiFiUDP::remoteIP();でデータの送信元を区別しながら適宜データを処理してやれば...とか思うのだけど。
(質問に回答というよりは自分で試してみたいけど週末までは無理だ。)

[LivingDays24_7]

おっしゃる通りロータリーエンコーダ側からLEDテープ側の一方通行で問題ありません。
ありがとうございます。

Answer 1

いまさらになっちゃいますが、3台接続の部分をやってみたのでとりあえず。ちょっと勘違いがあってえらく時間かかっちゃいました...

1台をWifiのAPで、通信上のサーバにします。
これに対して、他の2台がWiFiで接続し、UDPで適宜データを送信します。
サーバ側では、どちらの子機からデータを受け取ったかはIPアドレス情報で判別出来ます。

手持ちの基板の関係で、ESP32とESP8266を混ぜて/入れ替えて実験しました。
ESP8266をAP/Serverにしたとき、やたらにUDPの取りこぼしがあるのが気になりますが、ESP32をAP/Serverにしたときは見ている範囲では取りこぼしは見えなかったので、ESP32で使っている範囲では大丈夫なのではないか、と思います。

// 共通ヘッダ
const unsigned int UDP_PORT = 55555;

const char* SSID = "ESP32-WiFi";  // SSID
const char* PASS = "esp32wifi";   // password

const IPAddress SERVERIP(192, 168, 20, 254); // サーバのIP 他の機器と重ならないこと
const IPAddress SUBMASK(255, 255, 255, 0); // subnetmask

const IPAddress CLIENTIP_1(192,168,20,1); // 子機1のIP
const IPAddress CLIENTIP_2(192,168,20,2); // 子機2のIP

// AP/Server
// ESP32シンボルはESP32ライブラリで定義される
ifdef ESP32
#include <WiFi.h>
#else
#include <ESP8266WiFi.h>
#include <Wifiudp.h>
#endif
#include "addr.h"

WiFiUDP Udp;

IPAddress myIP;

//WiFiをアクセスポイントとしてオープン
void wifiInit(String ssid, String pass, IPAddress ip, IPAddress subMask) {
  WiFi.softAP(SSID, PASS);
  delay(100);//安定化
  WiFi.softAPConfig( ip, ip, subMask);
  delay(100);
  myIP = WiFi.softAPIP();
  Udp.begin(UDP_PORT);
}

void setup() {
  wifiInit(SSID, PASS, SERVERIP, SUBMASK);

  Serial.begin(115200);
  /* 各種情報を表示 */
  Serial.print("SSID: ");
  Serial.println(SSID);
  Serial.print("AP IP address: ");
  Serial.println(myIP);
}

void loop() {
  if (Udp.parsePacket())//UDP受信あり?
  {
    char rd[4] = {0};
    Udp.read(rd, 4);
    IPAddress rmt = Udp.remoteIP();
    Udp.flush();//残データがあったら捨てる
    Serial.print(rd);
    Serial.print(" from ");
    Serial.println(rmt);
  }
}

// 子機側 
// 2台めはCLIENTIP_2にする
#define CLIENT CLIENTIP_1
#ifdef ESP32
#include <WiFi.h>
#else
#include <ESP8266WiFi.h>
#include <WifiUDP.h>
#endif
#include "addr.h"

WiFiUDP Udp;

IPAddress myIP;
void wifiInit(const char* ssid, const char* pass, IPAddress ip) {
  delay(100);
  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, pass);
  
  WiFi.config(ip, SERVERIP, SUBMASK);
  do {
    delay(100);
  } while (WiFi.status() != WL_CONNECTED);
  delay(100);
  myIP = WiFi.localIP();
}

void setup() {
  Serial.begin(115200);
  Serial.println("\nWiFi Connecting");
  wifiInit(SSID, PASS, CLIENT);
  Serial.print("Connected.\nI AM ");
  Serial.println(myIP);

  Udp.begin(UDP_PORT);
}

void loop() {
  char buf[16];
  if (WiFi.status() == WL_CONNECTED) {
    if (Udp.beginPacket(SERVERIP, UDP_PORT) != 0) {
      sprintf(buf, "%03d", (int)(millis() % 1000));
      Udp.write((uint8_t*)buf, 4);
      Udp.endPacket();
      Serial.print("Send: ");
      Serial.println(buf);
    }
  } else {
    Serial.println("Disconnected");
  }
  delay(501);
}

Comments

[dodox86]

回答者のひとりですが、参考になるフォローありがとうございます。取りこぼしの差は多分にESP32とESP8266のCPU性能からする基本性能の違いな気がしますが、UDPなのでそもそも取りこぼしあっても仕方ないかなとは思います。（ブロードキャスト系で取りこぼし無しを前提にする仕様は、ハード／ソフト共に酷かと）

[thkana]

自分でやってみたいお題として頂いただけですので...で、せっかくやったから晒しておこうと。

私も深追いはしていないのですが、いくらUDPとはいえ、上記プログラムで500ms毎に4byteのデータを送って数回に一回は取りこぼすという状況なので激しすぎ。CPU性能のせいに出来るレベルじゃなく、なにか間違ってる感があります。Arduino用ボードライブラリも最新(ESP8266 2.50)になってることを確認したし、あと何だろう...って、ここが何の場かを考えれば別途質問を立てるのが筋かな。もう少し足掻いてみてからそうしようかしら。

[dodox86]

> 500ms毎に4byteのデータを送って数回に一回は取りこぼすという状況なので激しすぎ。
確かにそれはちょっとひどいですね。今後、発展した他の処理を追加するのもままならない。

[thkana]

ESP8266のWifiをステーションモードにしてUdpを受けさせてみると特にはこぼさない。AP処理が重いのかな。目的を果たすという点では既存のWifiネットワークがあるならそれを使うとか、あるいはTCPを使うとかの対応もあり、ということで回答としてはこの辺までで。

Answer 2

最終的に3つを相互で通信させる必要があるけれどそもそも出来るのかということが質問意図です。

心配せずとも、3台が同時に送受信すること自体はプログラミング次第でどうにでもなるので大丈夫です。

お試しになったSimpleWiFiServerと思わしきコードをgithubで読ませていただきましたが、TCPのサーバー、WEBサーバーと言っても良いですが、それをシンプルに実装したサンプル例のようです。こちらで考えると、3台の内1台をサーバーにして、残りの2台をクライアントにすれば必要に応じて接続、切断あるいは繋ぎっぱなしで1対2で通信の連携は取れそうです。

WiFiの接続とは別のレベルになるので、3台がWiFiでアクセスポイントに接続。接続成功したら1台がTCPサーバーになって残り2台がTCPクライアントになるようなかたちです。それぞれがサーバーとクライアントになれば数珠繋ぎで通信することだってできます。

WEBで検索すると、HTTP(WEBサーバー)ではなく、WebSocketで実装してリアルタイムにデータ通信している例もありました。TCPではなく、データを相互に投げっぱなしで良いのであればUDPで良いかもしれませんし、MQTTなんて通信方法もあります。処理したい内容次第です。ご自分でとにかく作って課題をひとつずつ解決して、コピペで終わらず内容を理解すればその先の応用もできるのではないでしょうか。

Comments

[LivingDays24_7]

このような丸投げ質問に対して非常に丁寧なお返事をありがとうございます！
先行きが少し見えたので実践してみようと思います。
ありがとうございました！

[dodox86]

今のご心配が少しでも解消できたようで良かったです。今回のご質問として終わったのであれば閉じていただければ幸いです。（BAを催促しているわけではありませんｗ）