VB.NET でdatagridviewを使ってSQLserverのテーブル更新

Question

SQLserverのテーブルを編集したいです。

DataGridViewに表示まではできるのですが、その後
・内容の編集
・行削除
・行追加
をしたら、ボタンをクリックして更新という動作を行いたいです。

簡単に行う方法はありますか？

特定のテーブルだけというわけではないので、可能であればデータソース構成ウィザードは使用したくありません。

よろしくお願いいたします。

Answer 1

他で少し回答が出ていますがDataGridViewを含んだ場合。
主キーが設定されている事が前提ですが、DataSetクラスとSqlDataAdapterクラス、SqlCommandBuilderクラスを使うと編集結果をデータベースへ自動で更新する事ができます。
簡単？かは人それぞれなのでお気にめすか分かりませんがウィザードを使わずコードで行うとこんな感じ。必要最低限なので後で工夫してくださいね。
DataSetやDataTableは別個(メモリ)に表形式で持っていますのでデータベースとの接続を切ってもデータを保持しています。
まぁここではまたデータベースを更新しないといけないので切らずに。

Imports System.Data.SqlClient
Public Class Form1
    Private Cn As New SqlConnection()
    Private Builder As New SqlConnectionStringBuilder()
    Private DaAdap As SqlDataAdapter
    Private DaSet As New DataSet()

    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles Me.Load

        Builder.DataSource = "(local)\SQLEXPRESS"
        Builder.InitialCatalog = "<データベース名>"
        Builder.IntegratedSecurity = True '特に指定がなかったのでWindows統合認証

        Cn.ConnectionString = Builder.ConnectionString
        DaAdap = New SqlDataAdapter("select * from <テーブル名>", Cn)
        '追加・更新・削除を自動で処理するためのオブジェクト
        Dim CmdBuilder As New SqlCommandBuilder(DaAdap)

        DaAdap.Fill(DaSet)
        DataGridView1.DataSource = DaSet.Tables(0)

    End Sub

    '更新ボタン
    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click

        'DataGridViewで編集した結果をDataSetを通してデータベースを更新
        DaAdap.Update(DaSet)

    End Sub

    Private Sub Form1_Closing(sender As Object, e As CancelEventArgs) Handles Me.Closing
        DaAdap.Dispose()
        Cn.Dispose()
    End Sub

Comments

[ya_ay]

できました、ありがとうございます。エラー処理等追加して使用させていただきます。

Answer 2

特定のテーブルだけというわけではないので、可能であればデータソース構成ウィザードは使用したくありません。

そこを考え直さないと難しいと思いますが、「可能であれば」程度の話で必須ではないのであれば、やはり Visual Studio のウィザードを使って定番の構成のアプリを作る以外に現実的な方法はないと思います。

ご存知かもしれませんが、DB が SQL Server であれば以下のチュートリアル：

チュートリアル : データベースへのデータの保存 (単一テーブル)
https://docs.microsoft.com/ja-jp/previous-versions/0f92s97z(v=vs.120)

10 行でズバリ !! 非接続型のデータ アクセス (ADO.NET) (C#)
https://code.msdn.microsoft.com/windowsdesktop/10-ADONET-C-cbfe7688

・・・のように Visual Studio のデータソース構成ウィザードを利用して型付 DataSet + TableAdapter を作って、それを利用してアプリを作ると、以下のページの図のような構造のアプリが、ほとんど自分でコードを書くこと無しに作れます。

Windows フォーム アプリケーションでのデータへの接続
https://docs.microsoft.com/ja-jp/previous-versions/wxt2cwcc(v=vs.120)

操作に慣れると 10 分もかからず作れるはずです。自力で一からコードを書く場合のような種々の問題に悩むことはなくなり、開発工数は激減するはずです。保守工数も減るはずです。お試しください。

【追記】

書き忘れましたが、データソース構成ウィザードを使うメリットとして、アプリの作成が簡単になるだけではなく、Visual Studio 2008 から新しく追加された TableAdapterManager クラスを利用できることがあります。

TableAdapterManager には、階層更新を実現するロジックを持つ UpdateAll メソッド、手動トランザクション処理が実装されており、これを使わない手はないと思います。

TableAdapterManager
http://surferonwww.info/BlogEngine/post/2011/12/21/TableAdapterManager.aspx

Comments

[ya_ay]

ありがとうございます、読んで理解を深めます。