【Googleスプレッドシート】QUERY関数で同じ列を２回表示させたい。

Question

クエリ関数の結果も戻りのリストが望んだ通りに表示されません。

同じ列を２回表示させようとしたら、エラーメッセージが発生しました。
表示させる方法が見つけられなくて質問させていただきます。

発生している問題・エラーメッセージ

「#VALUE!：」と表示されています。

関数QUERYのパラメータ２のクエリ文字列が解析できません：COLUMN_ONLY_ONCE:H

該当のソースコード：Googleスプレッドシート　QUERY関数

=QUERY(A3:I,"Select A,B,C,D,H,H,MAX(I) Where I is not null Group by A,B,C,D,H ",1)

試したこと

select関数の順番の入替、Group　byの順番の入替をしてみましたが、解消されません。
Selectの中の２つ目のHを除くと問題は置きません。

補足情報（FW/ツールのバージョンなど）

Answer 1

エラーメッセージを見る限り、H列を２回表示させるのは難しいと思います。

COLUMN_ONLY_ONCE:H

無理やりですが、表を結合してH列を重複させ、A~IをColに置き換えるのはどうでしょうか。

A → Col1
B → Col2
C → Col3
D → Col4
E → Col5
F → Col6
G → Col7
H → Col8
H → Col9
I → Col10

=Query({A1:H,H1:I},
"SELECT
  Col1,
  Col2,
  Col3,
  Col4,
  Col8,
  Col9,
  MAX(Col10)
WHERE
  Col10 IS NOT NULL
GROUP BY
  Col1,
  Col2,
  Col3,
  Col4,
  Col8,
  Col9
")

Comments

[naka2S]

「配列にして繰り返し」目からうろこです。
最終的に以下にて意図した抽出ができました。ありがとうございます。

=Query({A3:H,H3:I},"SELECT Col1, Col2, Col3, Col4, Col8, MAX(Col10), Col9
WHERE　 Col10 IS NOT NULL　GROUP BY　 Col1, Col2, Col3, Col4, Col8, Col9
")