perlで２つのファイルのマッチング処理について

Question

前提・実現したいこと

perlで２つのファイルのマッチング処理について何か方法があればご教授くださいませ。
下記のようなカンマ区切りの２ファイルがあり、双方のファイルの3列目(code2)と4列目(code3)を結合して比較し、存在すれば、２つ目のファイルの末尾に、1つ目のファイルの5列目と6列目の情報を付与したいと考えてます。マッチする際のキーが完全一致の場合は処理できたのですが、前方一致でもマッチしたものとした場合、どのように処理をすればいいのか解らずご質問させていただきました。どうぞよろしくお願い致します。

1つ目のtextファイル(連番,code1,code2,code3,flg1,flg2)
0000001,0640941,01101001001,１－１,A,M
0000002,0640941,01101001001,１－６,T,M
0000003,0640941,01101001001,１－８,w,M
.
.
.

2つ目のtextファイル(連番,code1,code2,code3)
0103300001,0640941,01101001001,１－１
0103300002,0640941,01101001001,１－６－２０
0103300003,0640941,01101001002,１－８－１０
.
.
.

結果ファイル
0103300001,0640941,01101001001,１－１,A,M ##ﾏｯﾁしたので情報を付与
0103300002,0640941,01101001001,１－６－２０,T,M ##ﾏｯﾁしたので情報を付与
0103300003,0640941,01101001002,１－８－１０, ##ｱﾝﾏｯﾁ
.
.
.

該当のソースコード

sub match_test {

	my %match = ();

	my $in_file = 'C:/work/data1.txt';	
	open IN, "<:encoding(cp932)", "$in_file" or die "!$\n";
	
	my $outfile = 'C:/work/value.txt';
	open OUT, ">:encoding(cp932)", "$outfile" or die "!$\n";
	
	while (<IN>){
		chomp;
		my @arr = split(/,/,$_,-1);
		my $key1 = $arr[2] . $arr[3];
		$match{$key1} = [$arr[4],$arr[5]];
	}
	close(IN);

	my $in_file2 =  'C:/work/data2.txt';
	open IN2, "<:encoding(cp932)", "$in_file2" or die "!$\n";

	while (<IN2>){

		chomp;
		my @arr = split(/,/,$_,-1);
		my $key2 = $arr[2] . $arr[3];
		
		my $m_data = $match{$key2};
		my $a1 = $m_data->[0];
		my $a2 = $m_data->[1];
			
		if (exists($match{$key2})){
			print OUT join(',',@arr,$a1,$a2) . "\n";
		}else{
			next;
		}
	
	}
	close (IN2);
}

補足情報（FW/ツールのバージョンなど）

windows7proにて操作しております。

Answer 1

正規表現で%matchのkeyに対してマッチングしてgrepでフィルタリング。引っかかったものがあるか否かで判定。

以下、grepの使用例です。

use strict;
use warnings;

my %x = ('abc'=>1, 'acb'=>2, 'ba'=>3, 'ca'=>4);

foreach my $testkey ('a', 'b', 'c', 'x'){
  my @res = grep {/^$testkey/} keys %x;
  print "Tested key: $testkey\n";
  if(scalar @res > 0){
    print "  matched: @res\n";
  }else{
    print "  None matched\n";
   }
}

Comments

[-JIJI-]

早々のご返信ありがとうございます。まだまだ勉強不足を実感しております。非常に勉強になりました。ご質問させていただきました内容は、処理中ではありますが、無事解決いたしました。grepを使用した処理もあわせて処理完了後に試してみます。今後ともどうぞよろしくお願い致します。

Answer 2

力技ですがこんな感じ？

while (<IN2>){

        chomp;
        my @arr = split(/,/,$_,-1);
        my $key2 = $arr[2] . $arr[3];

        for my $i (keys %match) {
            if (index($key2, $i) == 0) {
                my $m_data = $match{$i};
                my $a1 = $m_data->[0];
                my $a2 = $m_data->[1];
                print OUT join(',',@arr,$a1,$a2) . "\n";
                last;
            }
        }

    }
    close (IN2);

Comments

[-JIJI-]

早々のご返信ありがとうございます。早速現在処理を実行中で、途中経過ですが、思ったとおりの処理が実行されておりました。まだまだ勉強不足を実感しております。非常に勉強になりました。ご返信もはやく、思い通りの処理が実行できましたので、ベストアンサーとさせていただきます。今後ともよろしくお願い致します。