VB.NET DataTableからDictionary型への変換

Question

前提

環境　VisualStudio2008

・データベースから値を取得して、その値をコンボボックスに表示させたいと考えています。
・コンボボックスに表示させるにあたり、Dictionary型へ変換した後に表示させます

実現したいこと

・コンボボックスにデータベースから取得した値を表示させる
・データテーブルを辞書型に変換する

発生している問題・エラーメッセージ

■メッセージ

同一のキーを含む項目が既に追加されています。

該当のソースコード

            ComBox.DisplayMember = "Key"
            ComBox.ValueMember = "Value"

            'コンボボックス
            Dim dic As New Dictionary(Of String, String)

             For i = 0 To DataKey.Rows.Count - 1
       
                dic.Add(DataKey.ToString, DataValue.ToString)

            Next

            ComBox.DataSource = New BindingSource(dic, Nothing)

上記のコードで試した結果、記載しているエラーメッセージが表示されています。
データはsqlから取得出来ているのですが、dicの中にデータが入っていません。
空白""が入ってしまっている結果、エラーが生じているのだと想定しています。

どのように修正すればデータをdicに取得することが出来、
コンボボックスに値を表示させることが出来るのでしょうか。

ご教示よろしくお願いいたします。

Comments

[YAmaGNZ]

エラーメッセージの通りキーに同じ値があります。
Dictionaryには同じキーを設定できません。
データベースから読み込んだデータはどうなっているのでしょうか？

[inu_catperson]

ご指摘ありがとうございます。
データベースから読み込んだデータは以下のようになっています
DataKey リンゴ,メロン,ブドウ
DataValue 1,2,3

以上のように正しくデータ取れているのですが、
1回目にdicにデータを入れた後、dicの中身がkey,valueいずれも""となってしまっています。データは取れているけれど、dicに入っていないので代入時の私のコードの書き方に問題があるのだろうと考えています。

[YAmaGNZ]

DataKey、DataValueとは何なのでしょうか？
DataKeyに関してはRowsがありそうなのでDataTableっぽいですが・・・
ループ内でDictionaryに追加するのではなく、追加しようとしているものをログ出力するなりしてみましょう。
DataTableの中の値の取り出し方等を理解されていないように思えます。

[退会済みユーザー]

何を何で作っているかぐらいは書きませんか？　（例: Visual Studio 2008 で Windows Forms アプリをフレームワーク .NET Framework 4.8 で作ってます）

[退会済みユーザー]

> コンボボックスに表示させるにあたり、Dictionary型へ変換した後に表示させます

なぜですか？　そうする理由は？

以下の記事は DataGridView の ComboBox に DataTable のデータを表示するものですが（ステップ 17 ～ 21）、単独の ComboBox でも同様にできると思いますけど？

DataGridView に ComboBox を表示
http://surferonwww.info/BlogEngine/post/2014/01/23/how-to-show-combobox-column-in-datagridview.aspx

[退会済みユーザー]

質問者さん、その後無言ですが、回答したのでそれに対するフィードバックを返してください。役に立った/立たなかったぐらいは返せるのでは？ 役に立たなかったならどこがダメかを書くとより期待に近い回答が出てくるかも。解決したなら解決に役立った回答にベストアンサーをつけてクローズしてください。とにかく無言で放置は NG です。

Answer 1

例として、以下のような SQL Server のテーブルに、

以下の SELECT クエリを投げて、

SELECT CategoryID, CategoryName FROM Categories

DataTable に取得した CategoryID, CategoryName を、それぞれ ComboBox の ValueMember, DisplayMember として設定・表示してみます。

以下のコードのように、ADO.NET + SqlClient で DataTable を作成し、それを ComboBox の DataSource に直接設定すれば表示できます。コメント ① のコードがそれです。

コンボボックスに表示させるにあたり、Dictionary型へ変換した後に表示させます

その必要はないはずですが、そのコードも載せておきます。コメント ② 以下のコードがそれです。

Imports System.Data.SqlClient

Public Class Form1
    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        ' DataTable の作成
        Dim connString As String = "・・・接続文字列・・・"
        Dim selectQuery As String = "SELECT CategoryID, CategoryName FROM Categories"
        Dim table = New DataTable()
        Using connection = New SqlConnection(connString)
            Using command = New SqlCommand(selectQuery, connection)
                Dim adapter = New SqlDataAdapter(command)
                adapter.Fill(table)
            End Using
        End Using

        ' 参考に DataGridView に表示
        Me.DataGridView1.DataSource = table

        ' ① ComboBox の DataSource に DataTable を設定 
        Me.ComboBox1.DisplayMember = "CategoryName"
        Me.ComboBox1.ValueMember = "CategoryID"
        Me.ComboBox1.DataSource = table

        ' ② DataTable から Dictionary を作成
        Dim dictionary As New Dictionary(Of Int32, String)
        For Each item As DataRow In table.Rows
            Dim categoryId As Int32 = CType(item("CategoryID"), Int32)
            Dim categoryName As String = CType(item("CategoryName"), String)

            ' Key の重複防止（重複すると ArgumentException）
            If Not dictionary.ContainsKey(categoryId) Then
                dictionary.Add(categoryId, categoryName)
            End If
        Next

        ' Dictionary から List を作成し ComboBox の DataSource に設定
        Dim list As New List(Of KeyValuePair(Of Int32, String))
        list.AddRange(dictionary)
        Me.ComboBox2.DisplayMember = "Value"
        Me.ComboBox2.ValueMember = "Key"
        Me.ComboBox2.DataSource = list
    End Sub
End Class

結果は以下の通り。左の ComboBox が ① のコードのもの、右の ComboBox が ② のコードのものです。