[VBScript] csvファイルの内容を編集する

Question

vbsにて、csvファイルを読み込み、
以下のように編集することは可能でしょうか。
D&Dでスクリプトを実行することとします。

＜実行前＞
| A　　 　B 　　C
――――――――――――
1|名前　 性別　 出身地　
2|tanaka 男 　 新潟
3|takeda 男　　 東京
4|ishida 男 　 東京
5|sato 男 　 東京

＜実行後＞
| 　 A　　 B C D　　 E
―――――――――――――――――――
1|tanaka 男 　新潟 0001 　PC　
2|takeda 男　　東京 0002　 PC
3|ishida 男 　東京 1001 スマートフォン
4|sato 男 　東京 1002　 スマートフォン
5|

＜内容＞
・１行目を削除
・D列、E列に値を追加
※D列の値は、0001の次は0002みたいにコードで連番になるようにする
※E列の値には、D列の値が「00010999」の場合、E列の値が「PC」
D列の値が「10011999」の場合、E列の値が「スマートフォン」と表示されるようにする
実際に、csvファイル内の値の数が多いため、汎用性があるコード、
また、よろしければ一文一文のコードの説明や、F列、G列に値がある場合にどうコードを追加すれば良いか
ご教示頂けると幸いです。

ファイル編集には、filesystemobjectを使用すれば良い、splitを使用すると良いなど
googleで検索するとよく記載があるのですが、希望の動作になるようなサンプルがないため
現時点では解決困難となっております。（調査中）

お手数ですが、宜しくお願い致します。

Answer 1

実行するPCにExcelが入っているなら、Excelとして操作したほうが楽かと思います。
以下、サンプル。

Option Explicit

If WScript.Arguments.Count = 0 then
    WScript.Quit(-1)
End If

Dim xls	' Excel
Dim bk	' ワークブック
Dim sh	' ワークシート
Dim r	' 行数カウンタ
Dim e	' E列

' Excel関連のオブジェクト作成
Set xls = CreateObject("Excel.Application")
Set bk = xls.Workbooks.Open(WScript.Arguments(0))
Set sh = bk.Worksheets(1)

' メッセージは無視する
xls.DisplayAlerts = False

' 1行目削除
sh.Rows(1).Delete

' 2行目以降に情報付加
r = 1
Do While sh.Cells(r, 1) <> ""
	sh.Cells(r, 4).Value = "'" & Right("0000" & CStr(r), 4)
	e = ""
	If r >= 1 And r <= 999 Then
		e = "PC"
	ElseIf r >= 1001 And r <= 1999 Then
		e = "スマートフォン"
	End If
	sh.Cells(r, 5).Value = e
	r = r + 1
Loop

bk.Save						' 保存
bk.Close					' ブック閉じる
xls.DisplayAlerts = True	' メッセージ有効化
xls.Quit					' Excel閉じる
Set xls = Nothing			' オブジェクト解放

Excelが入っていない場合、FileSystemObject等での処理になります。
とりあえず今回は割愛します。

Comments

[naomoi]

ご回答ありがとうございました。
助かりました。

Answer 2

E列の説明が抜けてます。

Comments

[naomoi]

失礼しました、質問内容を補記しました。

[ttyp03]

ここは回答を記入する欄です。
修正依頼は質問本文下部にある「追記・修正依頼」からお願いします。