Visual Basic 透過について

Question

visual basicで一部を透過する方法を探しています。
Windows.Formsで作ろうと考えています
メインのパネルのプロパティにはOpacityという項目があり数値を変えると透過されました。
しかし、それをするとメインのパネルに乗っかっているUIたちも同じように透過されてしまいました。
一部を透過できる方法があれば教えていただきたいです。

Accepted Answer

Formの一部のみ半透明にするのはできなくはありません
「レイヤードウインドウ」で検索してみてください。
レイヤードウインドウを使った方法では、コントロールの描画を自分で行わないといけなくなったりとかなり大変でお勧めはしません。

次に、なるべく簡単な方法の提案です。
１．半透明表示のみを行うForm1を作る
２．コントロールをレイアウトするForm2を作る
３．Form1.Opacityにて半透明にする。
４．Form2.TransparencyKeyにて透過する
５．Form2をForm1の動きに追随させるようにする。

以下サンプル
Form1を半透明フォーム、Form2を半透明にしないコントロールを配置するフォームとする

```VB.NET
Public Class Form1

    Private GUIForm As New Form2

    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        '半透明にする
        Me.Opacity = 0.6

        'GUIのフォームの設定
        GUIForm.FormBorderStyle = FormBorderStyle.None
        GUIForm.StartPosition = FormStartPosition.Manual

        'BackColorではなくBackgroundImageを単色で塗りつぶして透過させる
        'Panelなど、FormのBackColorに連動して変化するものへの対応
        Dim bg As Bitmap = New Bitmap(GUIForm.Width, GUIForm.Height)
        Using g As Graphics = Graphics.FromImage(bg)
            g.Clear(Color.Green)
        End Using
        GUIForm.BackgroundImage = bg
        GUIForm.TransparencyKey = Color.Green

        'GUI用フォームを半透明フォームと同じ位置、同じ大きさにする
        GUIForm.Location = Me.PointToScreen(New Point(0, 0))
        GUIForm.Size = Me.ClientSize

        'GUIの表示
        GUIForm.Show(Me)

    End Sub

    Private Sub Form1_Resize(sender As Object, e As EventArgs) Handles Me.Resize
        GUIForm.Size = Me.ClientSize
    End Sub

    Private Sub Form1_LocationChanged(sender As Object, e As EventArgs) Handles Me.LocationChanged
        GUIForm.Location = Me.PointToScreen(New Point(0, 0))
    End Sub
End Class

```

このような感じとなります。
左側のコントロールがForm1にあるコントロールで、右側のコントロールがForm2にあるコントロールです。
![こんなかんじ](cca750697941541921efae16350bf05f.png)

ただ、この方法ですとコントロールがあるフォームが別フォームとなるため、Form2側にあるコントロールを触ると、Form1がActiveなフォームではなくなってしまいます。

Answer

Opacityでの動作が要件を満たさないなら、visibleとかzオーダーで工夫するというのはどうですか