バッチファイル ループ処理について

Question

各ファイルのコピー時間を計測時間をも求めるバッチを作成しているのですが、
なかなかうまく行きません。

＜仕様＞
C:\work\01_学習資料\01_Windows\bat\tmp
にある01-1G.dat、02-1M.dat、03-5M.datファイルを

C:\work\01_学習資料\01_Windows\bat\tmp1
へ1つ1つコピーしてコピー時間を秒単位で求めます。

@echo off

set LogPath=C:\work\01_学習資料\01_Windows\bat\tmp\
set SrcPath=C:\work\01_学習資料\01_Windows\bat\tmp\
set DstPath=C:\work\01_学習資料\01_Windows\bat\tmp1\

rem 1Gファイルコピー時間計測
set S_time_tmp=%time: =0%
set hh=%S_time_tmp:~0,2%
set mi=%S_time_tmp:~3,2%
set ss=%S_time_tmp:~6,2%
set sss=%S_time_tmp:~9,2%
set S_datetime=%hh%%mi%%ss%

echo 開始：%S_datetime% > %LogPath%01_%S_datetime%.log 
copy %SrcPath%01-1G.dat %DstPath%

rem 終了時刻設定
set E_time_tmp=%time: =0%
set hh=%E_time_tmp:~0,2%
set mi=%E_time_tmp:~3,2%
set ss=%E_time_tmp:~6,2%
set sss=%E_time_tmp:~9,2%
set E_datetime=%hh%%mi%%ss%

echo 終了：%E_datetime% >> %LogPath%01_%S_datetime%.log

timeout 2 > null


rem 1Mファイルコピー時間計測
set S_time_tmp=%time: =0%
set hh=%S_time_tmp:~0,2%
set mi=%S_time_tmp:~3,2%
set ss=%S_time_tmp:~6,2%
set sss=%S_time_tmp:~9,2%
set S_datetime=%hh%%mi%%ss%

echo 開始：%S_datetime% > %LogPath%02_%S_datetime%.log 
copy %SrcPath%02-1M.dat %DstPath%

rem 終了時刻設定
set E_time_tmp=%time: =0%
set hh=%E_time_tmp:~0,2%
set mi=%E_time_tmp:~3,2%
set ss=%E_time_tmp:~6,2%
set sss=%E_time_tmp:~9,2%
set E_datetime=%hh%%mi%%ss%

echo 終了：%E_datetime% >> %LogPath%02_%S_datetime%.log

timeout 2 > null

rem 5Mファイルコピー時間計測
set S_time_tmp=%time: =0%
set hh=%S_time_tmp:~0,2%
set mi=%S_time_tmp:~3,2%
set ss=%S_time_tmp:~6,2%
set sss=%S_time_tmp:~9,2%
set S_datetime=%hh%%mi%%ss%

echo 開始：%S_datetime% > %LogPath%03_%S_datetime%.log 
copy %SrcPath%03-5M.dat %DstPath%

rem 終了時刻設定
set E_time_tmp=%time: =0%
set hh=%E_time_tmp:~0,2%
set mi=%E_time_tmp:~3,2%
set ss=%E_time_tmp:~6,2%
set sss=%E_time_tmp:~9,2%
set E_datetime=%hh%%mi%%ss%

echo 終了：%E_datetime% >> %LogPath%03_%S_datetime%.log

上記コードでは、100ファイルあったっら非常に非効率になってしまうことは重々承知です。
ループを使ってなんとしたいのですが・・・・

一応、一つ一つ分解し簡略化した動作を確認しています。
まずは、コピー元フォルダ内のファイルが取得できるか確認。↓

@echo off

cd C:\work\01_学習資料\01_Windows\bat\tmp

for %%i in (*.dat) do (
	echo %%i
)

そして、以下のようにループで取得したファイル名をパスに連結すると
エラーとなってしまいます。%%1には、ファイル名が入っているので、

copy %SrcPath%%%i % DstPath%

としても大丈夫なような気もするのですが・・・・

@echo off

set LogPath=C:\work\01_学習資料\01_Windows\bat\tmp\
set SrcPath=C:\work\01_学習資料\01_Windows\bat\tmp\
set DstPath=C:\work\01_学習資料\01_Windows\bat\tmp1\

cd %SrcPath%


for %%i in (*.dat) do (
	rem echo %%i
	copy %SrcPath%%%i % DstPath%　
)
pause

---

11:24 追記↓
試行錯誤して下記の様に変更したら、1ファイルずつコピーできるようになりましたが、
logファイルがうまく生成されません。
logファイルは、log-YYYYMMDDSS.logという形式で出力させたいのですが、なぜか、
log-.logというファイルが1ファイルしか出来上がりません。

@echo off

set LogPath=C:\work\01_学習資料\01_Windows\bat\tmp\
set SrcPath=C:\work\01_学習資料\01_Windows\bat\tmp\
set DstPath=C:\work\01_学習資料\01_Windows\bat\tmp1\

cd %SrcPath%


for %%i in (*.dat) do (
	rem echo %%i
	
	set S_time_tmp=%time: =0%
	set hh=%S_time_tmp:~0,2%
	set mi=%S_time_tmp:~3,2%
	set ss=%S_time_tmp:~6,2%
	set S_datetime=%hh%%mi%%ss%

rem logファイル生成
	echo PC→XXServer > %LogPath%log-%S_datetime%.log 
	echo CopyFileName: %%i >> %LogPath%log-%S_datetime%.log 
	echo 開始時刻：%S_datetime% >> %LogPath%log-%S_datetime%.log 

	copy %%i %DstPath%

	set E_time_tmp=%time: =0%
	set hh=%E_time_tmp:~0,2%
	set mi=%E_time_tmp:~3,2%
	set ss=%E_time_tmp:~6,2%
	set E_datetime=%hh%%mi%%ss%

	echo 終了時刻：%E_datetime% >> %LogPath%log-%S_datetime%.log

	timeout /T 2 > null
)

pause

アドバイスの程、よろしくお願い致します。

Answer 1

forの中をサブルーチンにしてください。

for %%i in (*.dat) do call :SUB %%i
pause
exit /b
:SUB
    rem echo %1

    set S_time_tmp=%time: =0%
    set hh=%S_time_tmp:~0,2%
    set mi=%S_time_tmp:~3,2%
    set ss=%S_time_tmp:~6,2%
    set S_datetime=%hh%%mi%%ss%

rem logファイル生成
    echo PC→XXServer > %LogPath%log-%S_datetime%.log 
    echo CopyFileName: %1 >> %LogPath%log-%S_datetime%.log 
    echo 開始時刻：%S_datetime% >> %LogPath%log-%S_datetime%.log 

    copy %1 %DstPath%

    set E_time_tmp=%time: =0%
    set hh=%E_time_tmp:~0,2%
    set mi=%E_time_tmp:~3,2%
    set ss=%E_time_tmp:~6,2%
    set E_datetime=%hh%%mi%%ss%

    echo 終了時刻：%E_datetime% >> %LogPath%log-%S_datetime%.log

    timeout /T 2 > null

あと、1つのファイルのコピーが1秒以内で終わると、ログファイル名が重複して上書きされるので、追記にした方が良いと思います。
echo PC→XXServer >> %LogPath%log-%S_datetime%.log

Answer 2

% DstPath%
```の部分のスペースがおかしいかと

%DstPath%

### 追記
for内の環境変数に関しては「遅延環境変数」について調査されるとよいかと思います。
ただ、そうするよりは、下記のようにfor内を別のバッチファイルとしたほうがすっきりするかと
思います。

バッチ１

set DstPath=C:\dest

for %%i in (.) do (

バッチ２ %%i %DstPath%

)

pause

バッチ２

set LogPath=C:\log\

set S_time_tmp=%time: =0%

copy %1 %2

set E_time_tmp=%time: =0%