VB.netでクラスで宣言したオブジェクトの中にさらにArrayListでオブジェクトを代入してXMLシリアル化保存したい

Question

●やりたいこと
クラスでSettingsという名前のオブジェクトを宣言し、中にArrayListでさらに複数のオブジェクトを代入し、それをファイルに保存しようとしています。
XMLシリアル化が一番簡単そうなので、この方法を使っています。

今回はSettingsの中にArrayListでMailsという名前のオブジェクトを代入しようとしています。

●質問
そのまま実行すると、後述のButton1_Clickの時点で変数の作成はできるのですが、Button2_ClickでXML保存の際、serializer.Serialize(sw, SettingList)のところで「型 'System.InvalidOperationException' のハンドルされていない例外が System.Xml.dll で発生しました」エラーが出ます。

一応、Settingsの中にInherits Mailsを宣言すればエラーが出ずに動作はするのですが、下記のようにSettings直下に余計な値もできてしまいます。（Mail下の値が本来保存したい値。）
また、Inheritsは1回しか宣言できないので、新たに他のオブジェクトを実装できません。

<?xml version="1.0" encoding="utf-8"?>
<Settings xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema">
  <name />
  <mode>0</mode>
  <adjust>0</adjust>
  <Enable>false</Enable>
  <Honbun />
  <MailTo />
  <CC />
  <BCC />
  <Group />
  <Member />
  <Mail>
    <anyType xsi:type="Mails">
      <name>hogehoge</name>
      <mode>0</mode>
      <adjust>0</adjust>
      <Enable>false</Enable>
      <Honbun />
      <MailTo />
      <CC />
      <BCC />
    </anyType>
  </Mail>
</Settings>

ソースコードを以下に記載いたします。

・クラスでSettingsとMailsを作る

Option Explicit On

'設定ファイル
Public Class Settings
    'Inherits Mails      '←★これを入れると一応動作はする
    Public Group As ArrayList        '部署リスト（未実装）
    Public Member As ArrayList     '社員リスト（未実装）
    Public Mail As ArrayList          'メールアドレスリスト

    Public Sub New()
        Group = New ArrayList
        Member = New ArrayList
        Mail = New ArrayList
    End Sub
    Public Sub New(ByVal isGroup As ArrayList, ByVal isMember As ArrayList, ByVal isMail As ArrayList)
        Group = isGroup
        Member = isMember
        Mail = isMail
    End Sub
End Class


'設定通知メール詳細
Public Class Mails
    Public name As String
    Public mode As Long
    Public adjust As Long
    Public Enable As Boolean
    Public Honbun As String
    Public MailTo As String
    Public CC As String
    Public BCC As String

    Public Sub New()
        name = ""
        mode = 0
        adjust = 0
        Enable = False
        Honbun = ""
        MailTo = ""
        CC = ""
        BCC = ""
    End Sub
    Public Sub New(ByVal isname As String, ByVal ismode As Long,
                   ByVal isadjust As Long, ByVal isEnable As Boolean, ByVal isHonbun As String,
                   ByVal isMailTo As String, ByVal isCC As String, ByVal isBCC As String)
        name = isname
        mode = ismode
        adjust = isadjust
        Enable = isEnable
        Honbun = isHonbun
        MailTo = isMailTo
        CC = isCC
        BCC = isBCC
    End Sub
End Class

・実際のファイルの保存とロード

Option Explicit On

Module Module1
    Public SettingList As New Settings
    Private XML_dir As String = "C:\Windows\Temp"

    '設定情報をロード
    Public Sub LoadSettingsXML()
        Dim serializer As New System.Xml.Serialization.XmlSerializer(
            GetType(Settings))
        '読み込むファイルを開く
        If System.IO.File.Exists(XML_dir & "\setting.xml") Then
            Dim sr As New System.IO.StreamReader(
            XML_dir & "\Settings\setting.xml", New System.Text.UTF8Encoding(False))
            'XMLファイルから読み込み、逆シリアル化する
            SettingList = DirectCast(serializer.Deserialize(sr), Settings)
            'ファイルを閉じる
            sr.Close()
        End If
    End Sub
    '設定情報を保存
    Public Sub SaveSettingsXML()
        Dim serializer As New System.Xml.Serialization.XmlSerializer(
            GetType(Settings)) '
        'ファイルが解放されるまでTryにする
        Dim result As DialogResult = System.Windows.Forms.DialogResult.Retry
        While result = DialogResult.Retry
            Try
                Dim sw As New System.IO.StreamWriter(
                                XML_dir & "\setting.xml", False, New System.Text.UTF8Encoding(False))
                serializer.Serialize(sw, SettingList)   '←★ここで「型 'System.InvalidOperationException' のハンドルされていない例外が System.Xml.dll で発生しました」エラー
                sw.Close()
                Exit While
            Catch ex As System.IO.IOException
                result = MessageBox.Show("ファイル書き込みができません。下記ファイルが使用中です。" &
                                         vbCrLf & vbCrLf & XML_dir & "\setting.xml",
                                         "ファイル使用中エラー", MessageBoxButtons.RetryCancel)
            End Try
        End While
    End Sub

End Module

・操作用のウィンドウ

Option Explicit On

Public Class Form1

    Dim SansyouWatashi_Mails As ArrayList

    'フォーム起動時に実施
    Private Sub Form1_Shown(sender As Object, e As EventArgs) Handles Me.Shown
        SansyouWatashi_Mails = SettingList.Mail   'SettingList.Mailの内容を参照渡しして編集する用
    End Sub

    '新規作成
    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        Dim New_Name As String, New_Mail As Mails
        New_Name = InputBox("名前を入力してください", "新しい設定")
        New_Mail = New Mails()
        New_Mail.name = New_Name
        SansyouWatashi_Mails.Add(New_Mail)
    End Sub

    Private Sub Button2_Click(sender As Object, e As EventArgs) Handles Button2.Click
        Call SaveSettingsXML()
    End Sub

    Private Sub Button3_Click(sender As Object, e As EventArgs) Handles Button3.Click
        Call LoadSettingsXML()
    End Sub

End Class

Answer 1

ArrayList は任意の型を格納できるためどの型としてシリアライズすればいいのかが分かりません。そのため例外が発生しています。

Settings.Mail プロパティには Mails 型のオブジェクトしか格納しない前提なら、Mail プロパティに XmlArrayItem 属性を指定すればシリアライズできます。
他にもシリアライザのコンストラクタの extraTypes で Mails の型情報を渡す方法などもあります。

Public Class Settings
    'Inherits Mails      '←★これを入れると一応動作はする
    Public Group As ArrayList        '部署リスト（未実装）
    Public Member As ArrayList     '社員リスト（未実装）

    <System.Xml.Serialization.XmlArrayItem(GetType(Mails))> Public Mail As ArrayList          'メールアドレスリスト

    Public Sub New()
        Group = New ArrayList
        Member = New ArrayList
        Mail = New ArrayList
    End Sub
    Public Sub New(ByVal isGroup As ArrayList, ByVal isMember As ArrayList, ByVal isMail As ArrayList)
        Group = isGroup
        Member = isMember
        Mail = isMail
    End Sub
End Class

コード

Comments

[ot2os]

ありがとうございます！
いただいた方法で狙い通りの動作になりました！

ちなみに、ご提案いただいた`extraTypes`の方法は、実際のファイルの保存を行うモジュールの下記行を書き換えることによって実現しました。

●書き換え前
```lang-VB.net
Dim serializer As New System.Xml.Serialization.XmlSerializer(
GetType(Settings)) '
```

●書き換え後
```lang-VB.net
Dim et As Type() =
New Type() {GetType(Mails)} '複数型ある場合はここにコンマ区切りで列挙
Dim serializer As New System.Xml.Serialization.XmlSerializer(
GetType(Settings), et) '
```

こちらは実は同じ方法を試そうとして失敗していたのですが、serializerの`GetType(Settings)`の部分を`GetType(System.Collections.ArrayList)`を指定してしまいうまくいっていませんでした。
上記のコードでうまくいきました。