`^' の Warning

Question

Haskell 学習中に理解できない Warning に突き当たったので、どなたかご教授いただければと思います。
最小構成とWarning の内容を以下に記載します。

{-# OPTIONS -Wall -Werror #-}

square' :: Double -> Double
square' x = x ^ 2

test.hs:5:15: Warning:
    Defaulting the following constraint(s) to type `Integer'
      (Integral b0) arising from a use of `^' at test.hs:5:15
      (Num b0) arising from the literal `2' at test.hs:5:17
    In the expression: x ^ 2
    In an equation for square': square' x = x ^ 2

環境は以下の通りです。

$ ghc --version
The Glorious Glasgow Haskell Compilation System, version 7.6.3

よろしくお願いします。

Answer 1

処理系がデフォルトの型を使ったという警告です

どうして型が決定できないか

読みやすさのために、質問者のコードを再掲します。

{-# OPTIONS -Wall -Werror #-}

square' :: Double -> Double
square' x = x ^ 2

このエラーは数値リテラル2の型が決定できないために、生じています。
Haskellでは数値リテラルの型は多相性を持ちます。
対話環境で、つぎのように試してみてください。

> 2 :: Integer
2
> :type it
it :: Integer
> 2 :: Double
2.0
> :type it
it :: Double
> :type 2
2 :: Num t => t

数値リテラル2は多相的であり、実際に計算が行われるときには、Numクラスに含まれる、どれかの型に決定されます。

さて、演算子(^)の型を見てみましょう。

(^) :: (Num a, Integral b) => a -> b -> a

第1引数はNumクラスに含まれる型の値、第2引数はIntegralクラスに含まれる型の値、返り値は第1引数と同じ型の値、となります。
ここで、問題の式を見てみましょう。

x ^ 2

リテラル2はNumクラスである型の値となります。また、演算子(^)を適用していることから、よりきびしく、Integralクラスの型の値であることを要求されます。しかし、それだけです。これだけでは数値2の型が定まりません。

型の決まらない「整数値」のデフォルトはInteger

ここで、Haskellには、型の決まらない「整数値」をデフォルトでIntegerとする、というルールがあります。そのルールで数値2の型はIntegerとなります。
しかし、この「デフォルトの型」はコードを書いた人の意図とは異なるかもしれません。そこで警告が出ます。

解決の方法の、いくつかを挙げます。
まず、質問者が -Wall -Werror としているのは大変良い習慣かと思います。
そこで、それを生かす方向で、いくつかの解決策を挙げておきます。

デフォルトの型を使うことへの警告をつぶす

コードを書く人が、Haskellがデフォルトとして選ぶ型を信頼しているなら、つぎのようにします。

{-# OPTIONS -Wall -fno-warn-type-defaults -Werror #-}

こうすると、Haskellがデフォルトの型を選択したときに、警告しなくなります。

型注釈をつける

より、おすすめの方法は、型注釈をつけることです。

square' x = x ^ (2 :: Integer)

このようにすれば、明示的に数値2の型をIntegerと特定することができます。
Int型の値のほうが、すこしだけ、空間効率が良い気がするので、つぎのようにするのも、いいかもしれません。

square' x = x ^ (2 :: Int)

演算子(**), (^), (^^)について

それぞれの型を再掲します。

(**) :: Floating a => a -> a -> a
(^) :: (Num a, Integral b) => a -> b -> a
(^^) :: (Fractional a, Integral b) => a -> b -> a

実は、型だけからでも、あるていど、これらのちがいは予想できます。
演算子(**)では、冪乗する数である第2引数はFloatingクラスの型の値です。
つまり、浮動小数点っぽい値だということです。
整数でなくてもいい、つまり、つぎのようなことができます。

> 3 ** 0.5
1.7320508075688772

それに対して、演算子(^)では、第2引数は整数値です。
つまり、x ^ yは、「xをy回、かけあわせたもの」です。
このとき、xはNumクラスのインスタンスである型の値なら、何でもいいです。
Numクラスのクラス関数に「かけ算」があるためです。

最後の(^^)については、第1引数がFractionalクラスの型、つまり、分数(小数)となっています。整数では、負の数での冪乗ができないためです。

> 2 ^ (- 1)
Exception: Negative exponent
> 2 ^^ (- 1)
0.5

どうして、(**)で解決したか

演算子(**)の型は、つぎのようになっています。

(**) :: Floating a => a -> a -> a

質問者が新しく定義した関数は、つぎのようになります。

square' :: Double -> Double
square' x = x ** 2

演算子(**)は、第1引数、第2引数、返り値のすべてが同じ型であることを、要求しています。
そしてsquare'では引数と返り値とがDouble型の値であることを、要求します。
これらから、数値2の型がDouble型に決定されます。

ただ、この解決は、あまり好ましくないと感じます。
「ある数を、1.5乗でもなく2.5乗でもなく2乗したい」という意図であれば、
上記の解決策がぴったりですが、
「ある数を、2回かけあわせたい」という意図であれば、演算子(^)が、ぴったりかと思います。
そして、第2引数の数値リテラルには、好みの整数型を指定してあげるのが良いと思われます。

Comments

[zeroyonichikyu]

丁寧かつ詳細な解説ありがとうございます. 質問したときは数値リテラルの型についてよくわかっておらず, 混乱していました.

teratailのUIに慣れておらず, 今方法を調べていますが, 分かり次第解決した方法をこちらの回答に付け替えさせていただきます.

[YoshikuniJujo]

こちらこそ、良い質問を、ありがとうございました。

Answer 2

@takotakot さんの回答をヒントに warning の理由について調べ、

*Main> :t (^)
(^) :: (Integral b, Num a) => a -> b -> a
*Main> :t (**)
(**) :: Floating a => a -> a -> a
*Main> :t (^^)
(^^) :: (Fractional a, Integral b) => a -> b -> a
*Main> :t 2
2 :: Num a => a

と、ここでようやくエラーメッセージの意味が理解出来ました。
(エラーではないのは定義上は不一致だが、計算上は問題ないと推論されたからでしょうか)

ご提案の通り ** を使用するか、

square' :: Double -> Double
square' x = x ^ (2 :: Int)

とすれば warning がでないことを確認しました。

累積の演算子が3種類ある理由や使い分けがまだイメージできませんが、今後の課題にしたいと思います。

Answer 3

英語で何と書いてあるか、分かりますか？キーワードは Integer。エラーメッセージはきちんと読みましょう。「Haskell 累乗」で検索するだけで見つかりますよ？
Haskell基礎文法最速マスター を読めば、どの演算子を用いればよいか分かります。** を用いるべきですね。

Comments

[zeroyonichikyu]

ありがとうございます。

[zeroyonichikyu]

Wallオプションを外すとコンパイルが通り、結果も問題なかったので、演算子そのものが間違いとは思いつきませんでした。

Integer と ^ と ** については調べてみます。