回答編集履歴

  「そういうことじゃない！」ってのは承知しています^^;

  ライブラリを使うとどのくらい簡単になるか試しました。

 

  ```Processing

  import fisica.*;

 

  FWorld world;

 

  void setup() {

  size(500, 500);

  colorMode(HSB);

 

  Fisica.init(this);

  world = new FWorld();

  world.setEdges();

  world.setGravity(0, 0);

  world.setGrabbable(false);

 

  for (int i = 0; i < 3; i++) {

  FBody ball = createBall();

  ball.setPosition(random(50, width - 50), random(50, height - 50));

  world.add(ball);

  }

  }

 

  void draw() {

  background(255);

  world.step();

  world.draw();

  }

 

  void contactStarted(FContact contact) {

  FBody b1 = contact.getBody1();

  FBody b2 = contact.getBody2();

  if (b1.isStatic() || b2.isStatic()) return;

  if (b1.getJoints().size() != 0 && b2.getJoints().size() != 0) return;

 

  FRevoluteJoint joint = new FRevoluteJoint(b1, b2);

  joint.setDrawable(false);

  world.add(joint);

  }

 

  FBody createBall() {

  FCircle ball = new FCircle(random(40, 60));

  ball.setDamping(0);

  ball.setRestitution(1);

  ball.setVelocity(random(-300, 300), random(-300, 300));

  ball.setFillColor(color(random(256), 128, 255));

  ball.setNoStroke();

  return ball;

  }

 

  // ちょい寂しいのでおまけ

  void mousePressed() {

  FBody ball = createBall();

  ball.setPosition(mouseX, mouseY);

  world.add(ball);

  }

  ```