VB.netでListViewを仮想モードでサムネイルを表示しているが、項目を選択しているときに選択状態の青い色にするか、もしくは項目の背景色を青い色にしたい

Question

VB.netでListViewを仮想モードで開いてサムネイル（小さい画像の一覧）を表示しています。

Public Class Form1
  Public imageDir As String = "C:\Users\user\Pictures" ' 画像ディレクトリ
  Public jpgFiles As String() = System.IO.Directory.GetFiles(imageDir, "*.jpg", IO.SearchOption.TopDirectoryOnly)
  Public thumbnail(jpgFiles.Length) As Image
  Public width1 As Integer = 100
  Public height1 As Integer = 80
  Public Imagelist1 As New ImageList
  Public index As Integer = 0

  ' 幅w、高さhのImageオブジェクトを作成
  Function createThumbnail(ByVal image As Image, ByVal w As Integer, ByVal h As Integer) As Image
    Dim canvas As New Bitmap(w, h)

    Dim g As Graphics = Graphics.FromImage(canvas)
    g.FillRectangle(New SolidBrush(Color.White), 0, 0, w, h)

    Dim fw As Double = CDbl(w) / CDbl(image.Width)
    Dim fh As Double = CDbl(h) / CDbl(image.Height)
    Dim scale As Double = Math.Min(fw, fh)
    Dim w2 As Integer = CInt(image.Width * scale)
    Dim h2 As Integer = CInt(image.Height * scale)

    g.DrawImage(image, (w - w2) \ 2, (h - h2) \ 2, w2, h2)
    g.Dispose()

    Return canvas
  End Function

  Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    ListView1.Enabled = True
    ListView1.Visible = True
    ListView1.VirtualMode = True
    ListView1.OwnerDraw = True

    Imagelist1.ImageSize = New Size(width1, height1)
    ListView1.LargeImageList = Imagelist1
    ListView1.VirtualListSize = jpgFiles.Length

    For i As Integer = 0 To jpgFiles.Count - 1
      thumbnail(i) = Nothing
    Next
  End Sub

  Private Sub ListView1_RetrieveVirtualItem(sender As Object, e As RetrieveVirtualItemEventArgs) Handles ListView1.RetrieveVirtualItem
    e.Item = New ListViewItem(jpgFiles(e.ItemIndex), e.ItemIndex)
  End Sub

  Private Sub ListView1_DrawItem(sender As Object, e As DrawListViewItemEventArgs) Handles ListView1.DrawItem
    e.DrawDefault = False
    e.DrawBackground()

    If thumbnail(e.ItemIndex) Is Nothing Then
      Dim original As Image
      Try
        original = Bitmap.FromFile(jpgFiles(e.ItemIndex))
      Catch
        original = My.Resources.Resource1._error
      End Try
      thumbnail(e.ItemIndex) = createThumbnail(original, Width, Height)
    End If

    Dim imagerect As New Rectangle(New Point(e.Bounds.X + ((e.Bounds.Width - width1) / 2), e.Bounds.Y), New Size(width1, height1))
    e.Graphics.DrawImage(thumbnail(e.ItemIndex), imagerect)
    'e.Item.ForeColor = Color.AliceBlue   ' ←コメント状態を解除するとListView1が高速で点滅状態になる
    'ListView1.Items(index).BackColor = Color.Aqua   ' ←コメント状態を解除するとListView1が高速で点滅状態になる

    e.DrawFocusRectangle()
    ListView1.Items(index).Focused = True
    ListView1.Items(index).Selected = True   ' ←選択状態の時の青い色にならない
  End Sub

  Private Sub Button2_Click(sender As Object, e As EventArgs) Handles Button2.Click
    index = index - 1
    If index < 0 Then index = 0

    ListView1.Items(index).Focused = True
    ListView1.Items(index).Selected = True         ' ←選択状態の時の青い色にならない
    ListView1.Items(index).BackColor = Color.Aqua  ' ←色が変わらない
  End Sub

  Private Sub Button3_Click(sender As Object, e As EventArgs) Handles Button3.Click
    index = index + 1
    If index > ListView1.Items.Count - 1 Then index = ListView1.Items.Count - 1

    ListView1.Items(index).Focused = True
    ListView1.Items(index).Selected = True        ' ←選択状態の時の青い色にならない
    ListView1.Items(index).BackColor = Color.Aqua ' ←色が変わらない
  End Sub

  Private Sub ListView1_ItemActivate(sender As Object, e As EventArgs) Handles ListView1.ItemActivate
    ListView1.Items(index).BackColor = Color.Aqua    ' ←色が変わらない
  End Sub

  Private Sub ListView1_VirtualItemsSelectionRangeChanged(sender As Object, e As ListViewVirtualItemsSelectionRangeChangedEventArgs) Handles ListView1.VirtualItemsSelectionRangeChanged
    ListView1.Items(e.EndIndex).BackColor = Color.Aqua ' ←色が変わらない
  End Sub
End Class

フォームにはListViewの他にButton2とButton3が配置してあります。Button2で前の項目を、Button3で次の項目を選択状態にして項目の背景色を変えるコードを書いたつもりです。しかしButton2やButton3を押しても選択状態にならず背景色も変わりません。僕の勝手な推測ですが、

ListView1.OwnerDraw = True
を設定している事により、描画の必要性があるときに

** Private Sub ListView1_DrawItem(sender As Object, e As DrawListViewItemEventArgs) Handles ListView1.DrawItem**
が呼び出されて描画処理を行っているようなのですが、どうもいろんなタイミングでListView1_DrawItemが呼び出されているのではないかと思います。ListViewをスクロールした時や最初にサムネイル一覧を作成する時は呼び出される必要があると思いますが、その他のたいして呼び出す必要がなさそうな時、例えば

**ListView1.Items(index).Selected = True **
を実行した時や
ListView1.Items(index).BackColor = Color.Aqua
を実行した時なども呼び出されているっぽいです。
そしてListView1_DrawItemでの描画処理で上書きしてしまって何も変化がないように見えているのではないかと思います。

ListView1_DrawItemが呼び出されたときに、それがスクロール処理や一番最初のサムネイル作成以外で呼び出された事が分かれば処理を抜けるようにすれば上書きを防ぐことが出来るのではないかと思いますが、どういうイベントによって呼び出されたのかを知る方法が分かりません。

ListViewの選択された項目を選択状態の時の薄い青色の状態か、項目の背景色を目立つ色に変えたいのですが、どのようにすればいいでしょうか。

---

追記　1月10日20時19分

YAmaGNZ様が教えてくれたコードを
Dim imagerect As New Rectangle(New Point(e.Bounds.X + ((e.Bounds.Width - width1) / 2), e.Bounds.Y), New Size(width1, height1))
の直前に挿入したのですが、全部の項目が赤色になってしまいました。
また、Button2やButton3を押しても色が変わりません。（なんとなく該当の項目がちらついているようには見えます）
項目をマウスでクリックしても色が変わりません。予想では選択した項目だけ赤色でほかは無色になると思ってたのですが、そうはなっていないのでどこかがおかしいと思うのですがどこがおかしいのか分かりません。
プロパティの変更は
ListView1.MultiSelect = False
ぐらいしか変更してないと思います。コードの変更箇所だけ下に載せてみます

    Private Sub ListView1_DrawItem(sender As Object, e As DrawListViewItemEventArgs) Handles ListView1.DrawItem
    e.DrawDefault = False
    e.DrawBackground()

    If thumbnail(e.ItemIndex) Is Nothing Then
      Dim original As Image
      Try
        original = Bitmap.FromFile(jpgFiles(e.ItemIndex))
      Catch
        original = My.Resources.Resource1._error
      End Try
      thumbnail(e.ItemIndex) = createThumbnail(original, Width, Height)
    End If

    'ここから追加-------------------------------------------------------
    If (e.State And ListViewItemStates.Selected) <> 0 Then
      '選択されているので選択色（例で赤とする）で塗りつぶす
      e.Graphics.FillRectangle(Brushes.Red, e.Bounds)
    Else
      '選択されていないので通常色で塗りつぶす
      Using b = New SolidBrush(e.Item.BackColor)
        e.Graphics.FillRectangle(b, e.Bounds)
      End Using
    End If
    'ここまで------------------------------------------------------------

    Dim imagerect As New Rectangle(New Point(e.Bounds.X + ((e.Bounds.Width - width1) / 2), e.Bounds.Y), New Size(width1, height1))
    e.Graphics.DrawImage(thumbnail(e.ItemIndex), imagerect)
    'e.Item.ForeColor = Color.AliceBlue   ' ←コメント状態を解除するとListView1が高速で点滅状態になる
    'ListView1.Items(index).BackColor = Color.Aqua   ' ←コメント状態を解除するとListView1が高速で点滅状態になる

    e.DrawFocusRectangle()
    'ListView1.Items(index).Focused = True '←コメントにしました
    'ListView1.Items(index).Selected = True '←コメントにしました  ' ←選択状態の時の青い色にならない
  End Sub

再質問で申し訳ないのですがよろしくお願いいたします。

---

追記2 1月10日21時43分
Debug.WriteLine(e.State)
でe.Stateの状態を調べた所、全部の項目が選択状態になっていました。なので全部赤色になってたわけです。なぜselectedになっているのかは分かりません。selectedの代わりにfocusで試してみた所focusは一つの項目だけ設定されてたので一つの項目だけが赤色になるようにできました。
If (e.State And ListViewItemStates.Selected) <> 0 Then
を
If (e.State And ListViewItemStates.Focused) <> 0 Then
あるいは
If e.ItemIndex = index Then
にすることでうまい具合に動作するようになりました。

---

追記3 1月10日22時06分
YAmaGNZ様がe.Item.Selectedの事を教えてくださり試してみた所うまく動作しました。
If (e.Item.Selected And ListViewItemStates.Selected) <> 0 Then
ありがとうございました。

---

追記4 1月10日22時29分
YAmaGNZ様のご指摘があり正しいのは
If e.Item.Selected Then
だとの事です。それと「選択されている」と判断するのであればFocusedやItemIndexではなく、Selectedを使用すべきとの事です。

Answer 1

OwnerDrawにするということは全て自分で描画しなくてはなりません。
なので背景の色を変えたいのであれば自分でその色に塗ることになります。

'アイテムの領域を黒で塗りつぶす
e.Graphics.FillRectangle(Brushes.Black, e.Bounds)

その他のたいして呼び出す必要がなさそうな時、例えば

ListView1.Items(index).Selected = True
を実行した時や
ListView1.Items(index).BackColor = Color.Aqua
を実行した時なども呼び出されているっぽいです。

DrawItemイベントは再描画が必要な時に呼び出されます。
なのでSelected = Trueとしたときはそのアイテムが選択状態になります。
なので選択された状態を描画する必要があります。なのでDrawItemイベントが発生します。
また、BackColor = Color.Aquaと背景色を変更したのであれば、その背景色となるよう
描画する必要があります。なのでDrawItemイベントが発生します。

選択時に背景を変更するのであれば

If (e.State And ListViewItemStates.Selected) <> 0 Then
    '選択されているので選択色（例で赤とする）で塗りつぶす
    e.Graphics.FillRectangle(Brushes.Red, e.Bounds)
Else
    '選択されていないので通常色で塗りつぶす
    Using b = New SolidBrush(e.Item.BackColor)
        e.Graphics.FillRectangle(b, e.Bounds)
    End Using
End If

といった感じで自分で描画の処理を書いてください。

またDrawItemイベント内で
'e.Item.ForeColor = Color.AliceBlue ' ←コメント状態を解除するとListView1が高速で点滅状態になる
'ListView1.Items(index).BackColor = Color.Aqua ' ←コメント状態を解除するとListView1が高速で点滅状態になる
と再描画が必要になるようなプロパティを操作すると再度DrawItemが呼ばれることになります。
なのでそのような操作を行わないようにしましょう。

Comments

[tada_tadaa]

YAmaGNZ様、回答ありがとうございます。
YAmaGNZ様の教えてくれたコードを試してみたのですが、うまくいかず分からなかったので質問欄に追記で変更箇所だけ載せてみました。再質問で申し訳ないのですが原因がお分かりになるのであれば教えていただけないでしょうか。

[YAmaGNZ]

申し訳ありませんが、現在は動作を確認できない状況です。
なのでご自身でデバッガでステップ実行しながら各プロパティの値を確認しつつ、どのように動作しているかを確認してください。
また、リファレンスも確認するようにしてください。
コードに関しては
https://docs.microsoft.com/ja-jp/dotnet/api/system.windows.forms.drawlistviewitemeventargs.state?view=netframework-4.8
などサンプルソースが載っていますのでそちらも参考にしてみてください。

[tada_tadaa]

了解しました。各プロパティをよく確認する事にします。
分かりやすい回答をありがとうございました。

[YAmaGNZ]

選択されているかの判断をe.Item.Selectedで判断してはどうですかね？

[tada_tadaa]

回答をありがとうございます。
If (e.Item.Selected And ListViewItemStates.Selected) <> 0 Then
で試してみた所うまく動作しました。質問欄に追記で
ListViewItemStates.Focused
を試したらうまくいったのでその方法を使う事にしたと書いたところでした。
また追記でe.Item.Selectedの事も書いておこうと思います。
とりあえず問題解決出来て良かったです。
ありがとうございました。

[YAmaGNZ]

FocusedやItemIndex ですと意味が違いますので「選択されている」と判断するのであればSelectedを使用すべきかと思います。

[tada_tadaa]

了解しました。選択を判断する場合はSelectedを使うようにします。

[YAmaGNZ]

＞If (e.Item.Selected And ListViewItemStates.Selected) <> 0 Then
SelectedはBooleanなので
If e.Item.Selected Then
です

[tada_tadaa]

了解しました。質問欄にも追記でその事を説明しておきます。