vb.netでピクチャボックス内のイメージの左上の座標を取得したい

Question

Visual studio 2017のVBでフォーム内にピクチャボックスを設置し、画像を表示しています。ピクチャボックスはマウスで移動できるようになっています。
下の図で言うと、灰色の部分がフォームの領域で青い部分がピクチャボックスの領域になっており、ピクチャボックスの中にパソコンの画像が表示されています。

ピクチャボックスを移動できるので、フォームのサイズを変更した場合などにピクチャボックスがフォームの外に行って、フォーム上に表示されなくなる事があったので、以下のようなソースでピクチャボックスがフォームの外に行った場合は、ピクチャボックスの座標をフォーム内に持ってくるようにしています。

  Sub FuncPictureBoxOverFix()

    If PictureBox1.Top > Me.ClientSize.Height - 10 Then
      PictureBox1.Top = Me.ClientSize.Height - 20
    End If

    If PictureBox1.Left > Me.ClientSize.Width - 10 Then
      PictureBox1.Left = Me.ClientSize.Width - 20
    End If

    If PictureBox1.Right < 10 Then
      PictureBox1.Left = -PictureBox1.Width + 20
    End If

    If PictureBox1.Bottom < 10 Then
      PictureBox1.Top = -PictureBox1.Height + 20
    End If

    Me.Refresh()
  End Sub

すると以下の図のようにピクチャボックスの端っこがフォーム内に表示されるようなりました。

しかしフォームに表示されているのはピクチャボックスの青い領域でイメージ自体は表示されていません。
ピクチャボックス内のイメージ（パソコンの画像）の左上の座標がわかれば、イメージの端っこがフォームに表示されるように修正できるのですが、イメージの左上の座標を取得する方法が分かりません。
どのようにすればイメージの座標を取得できるでしょうか。

Comments

[vann_2921]

パソコンの画像はどのやってピクチャーボックスに表示しているのでしょうか？
画像をみるとピクチャーボックスを3等分した真ん中の位置にあるように見えますがどうやって位置を調整しているのでしょうか？

[tada_tadaa]

PictureBox1.Image = System.Drawing.Image.FromFile(str)
↑の文で画像ファイルを読み込んでいます。strには画像ファイルのパスが格納されています。

＞3等分した真ん中の位置にあるように見えますがどうやって位置を調整しているのでしょうか？

3等分した真ん中の位置にあるようにみえるのは、たまたまそうなっているだけです。マウスの右クリックでディレクトリ内の前の画像ファイル、左クリックで次の画像ファイルを呼び出し、マウスのホイールを動かすとピクチャボックスが拡大したり縮小したりする仕組みになってますが、例えば横長で縦が短い画像を呼び出すと、イメージの左と右のピクチャボックスの領域である青い領域は小さくなります。逆に縦が長く、横が短い縦長の画像を読み込むとイメージの左と右の青い領域は広くなります。また、マウスのホイールを動かしてピクチャボックスを拡大したり縮小したりすると、ピクチャボックス内のイメージも大きくなったり小さくなったりしますが、ある時はイメージの左右にピクチャボックスの青い領域があったり、イメージの上下に青い領域があったりと青い領域は変動します。

イメージはピクチャボックスの真ん中に表示されているように見えますが、僕の方で何か真ん中に表示されるように設定した記憶はないです。関係してるかもしれないこととしては、ピクチャボックスのプロパティである「SizeMode」を「Zoom」に設定した事と、ピクチャボックスのプロパティ「Anchor」を「None」に設定した事でしょうか。

[KOZ6.0]

「PictureBox.ImageRectangleFromSizeMode」
https://referencesource.microsoft.com/#System.Windows.Forms/winforms/Managed/System/WinForms/PictureBox.cs,5c2ab37313f547c2
イメージのサイズとピクチャーボックスのクライアントサイズから描画先を決定している箇所です。
ソースは C# ですが、計算式はなんとなくわかると思います。
PictureBoxSizeMode.Zoom: の部分を参考にしてみてください。

Answer 1

コード書いてみました。

ImageRectangleFromSizeMode で、画像の PictureBox におけるクライアント座標が分かるので、
PictureBox の RectangleToScreen メソッドでスクリーン座標に変換し、
Form の RectangleToClient で Form のクライアント座標に変換します。

Public Class Form1

    Public Shared Function ImageRectangleFromSizeMode(pbox As PictureBox) As Rectangle
        Dim result As Rectangle = DeflateRect(pbox.ClientRectangle, pbox.Padding)
        If pbox.Image IsNot Nothing Then
            Select Case pbox.SizeMode

                Case PictureBoxSizeMode.Normal, PictureBoxSizeMode.AutoSize
                    result.Size = pbox.Image.Size

                Case PictureBoxSizeMode.StretchImage

                Case PictureBoxSizeMode.CenterImage
                    result.X += (result.Width - pbox.Image.Width) / 2
                    result.Y += (result.Height - pbox.Image.Height) / 2
                    result.Size = pbox.Image.Size

                Case PictureBoxSizeMode.Zoom
                    Dim imageSize As Size = pbox.Image.Size
                    Dim ratio As Single = Math.Min(pbox.ClientRectangle.Width / imageSize.Width,
                                               pbox.ClientRectangle.Height / imageSize.Height)

                    result.Width = imageSize.Width * ratio
                    result.Height = imageSize.Height * ratio
                    result.X = (pbox.ClientRectangle.Width - result.Width) / 2
                    result.Y = (pbox.ClientRectangle.Height - result.Height) / 2
            End Select
        End If
        Return result
    End Function

    Private Shared Function DeflateRect(rect As Rectangle, padding As Padding) As Rectangle
        rect.X += padding.Left
        rect.Y += padding.Top
        rect.Width -= padding.Horizontal
        rect.Height -= padding.Vertical
        Return rect
    End Function

    Private Sub PictureBox1_LocationChanged(sender As Object, e As EventArgs) Handles PictureBox1.LocationChanged
        Dim pbox As PictureBox = DirectCast(sender, PictureBox)
        Dim r As Rectangle = ImageRectangleFromSizeMode(pbox)
        Me.Text = RectangleToClient(pbox.RectangleToScreen(r)).ToString()
    End Sub

    <System.Runtime.InteropServices.DllImport("User32.dll")>
    Private Shared Function SendMessage(hWnd As IntPtr, uMsg As Integer, wParam As IntPtr, lParam As IntPtr) As IntPtr
    End Function

    <System.Runtime.InteropServices.DllImport("User32.dll")>
    Private Shared Function SetCapture(hwnd As Integer) As Boolean
    End Function

    <System.Runtime.InteropServices.DllImport("User32.dll")>
    Private Shared Function ReleaseCapture() As Boolean
    End Function

    Private Const WM_SYSCOMMAND As Integer = &H112
    Private Const SC_MOVE As Integer = &HF010

    Private Sub PictureBox1_MouseDown(sender As Object, e As MouseEventArgs) Handles PictureBox1.MouseDown
        Dim pbox As PictureBox = DirectCast(sender, PictureBox)
        SetCapture(pbox.Handle)
        ReleaseCapture()
        SendMessage(pbox.Handle, WM_SYSCOMMAND, SC_MOVE Or 2, 0)
    End Sub

End Class

PictureBox をドラッグして動かすと Form のタイトルバーに座標が表示されます。

Comments

[tada_tadaa]

回答ありがとうございます。
教えていただいたプログラムを試してみた所、FormのタイトルバーにX座標、Y座標、Width、Heightが表示されました。ピクチャボックス内に画像を読み込んでマウスでピクチャボックスを動かして、フォームの角に合わせたりしていると、ピクチャボックス自体はY座標が０、X座標が０の所に置いていたとしても、タイトルバーにはX=0,Y=0とは表示されずに、イメージの座標が表示されている事を確認できました。

また、WindowsAPIを使ってピクチャボックスをマウスで動かせるようにする技術や、画像の大きさとピクチャボックスの大きさから実際に表示されるイメージの大きさと座標を求める計算式、KOZ6.0様が教えてくれたリンク先に、C＃ではありましたが内部の挙動らしきものが載っていたりと、とても勉強になりました。