GDI+ で汎用エラーが発生しました。

Question

画像の合成をしています。
１回目は問題なく合成できました。
しかし、２回目は「GDI+ で汎用エラーが発生しました。」というエラーが発生してしまいます。
念のため、該当するファイルを削除しようとしたら、「vshost32.exeによってファイルは開かれているため、操作を完了できません。ファイルを閉じてから再実行してください。」というメッセージがでます。
このファイルを閉じる方法を教えてください。

１回目で合成した画像

２回目に合成しようとしたら、このエラーが出ました

該当ファイルを削除しようとしたら出たメッセージ

FileName = DirName & "\" & System.IO.Path.GetFileNameWithoutExtension(TextBox3.Text) & ".jpg"
Using Jpeg As Bitmap = FormUtil.CreateClientBitmap(Me, New Rectangle(709, 158, 435, 370))
    Jpeg.Save(FileName, Imaging.ImageFormat.Jpeg)
    Dim g As Graphics = Graphics.FromImage(PictureBox2.Image)
    Dim img As New Bitmap(FileName)
    Dim srcRect As New Rectangle(0, 0, 435, 376)
    Dim desRect As New Rectangle(TextBox13.Text, TextBox14.Text, 435 * (TextBox15.Text / 100), 376 * (TextBox15.Text / 100))
    '画像の一部を描画する
    g.DrawImage(img, desRect, srcRect, GraphicsUnit.Pixel)
    g.Dispose()
    PictureBox2.Invalidate()
    FileName = DirName & "\Test" & System.IO.Path.GetFileNameWithoutExtension(TextBox3.Text) & ".jpg"
    PictureBox2.Image.Save(FileName, Imaging.ImageFormat.Jpeg)
End Using

インターネットのサイトを探しましたが、思うようなサイトが見つかりません。
何方か、お力添えお願いします。

環境
Windows 10
Microsoft Visual Studio 2010

Comments

[KOZ6.0]

Dim img As New Bitmap(FileName)
が Dispose されていないですね
g.DrawImage(img, desRect, srcRect, GraphicsUnit.Pixel)
ここは Jpeg で良いのでは？

[sake]

早速の回答、ありがとうございました。
img.Dispose()
で解決しました。
追加の質問で申し訳ありませんが、教えてください。
合成したときに直前の画像の上に上書きされてしまいます。
直前の画像データをクリアしてから合成することは可能でしょうか？
色々と甘えてしまい、申し訳ありませんがよろしくお願いします。

[KOZ6.0]

最初の背景画像を保存しておいて、再度合成すれば良いです。
PictureBox2.Image = DirectCast(BackBmp.Clone, Bitmap)
(合成処理)

[KOZ6.0]

Clone すると、リソースが増えるので、背景画像を描画したほうがいいですね。

[sake]

ご指摘のように、一旦
PictureBox2.ImageLocation = Nothing
PictureBox2.ImageLocation = TextBox3.Text
として、合成処理をしましたが、
Dim g As Graphics = Graphics.FromImage(PictureBox2.Image)
のところで、「NULL値を入れることは出来ません」というメッセージがでました。
どのようにしたらPictureBox2に新しいソースを読み込むことができますか？
VB.NETを使い始めて間もないので、色々分からない事ばかりです。
よろしくお願いします。

Answer 1

質問に関しての回答ですが、New Bitmap(fileName) とすると、Bitmap オブジェクトがファイルを開きっぱなしにするので書き込みがエラーになります。
Dispose すると解放されるので書き込み可能になります。

追加の質問については以下回答します。

(1) まず Form のフィールドとして

Private BackBmp As Image

を宣言します。

(2) Form_Load では、PictureBox2.Image に、空のビットマップを割り当てます。

Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    Dim cs As Size = PictureBox2.ClientSize
    PictureBox2.Image = New Bitmap(cs.Width, cs.Height)
End Sub

(3) 画像の取り込みは、読み込んだビットマップを (1) のフィールドに格納し、Picture2.Image に描画します。

Private Sub LoadBitmap()
    Using stream As New IO.StreamReader(TextBox3.Text)
        If BackBmp IsNot Nothing Then
            BackBmp.Dispose()
        End If
        BackBmp = Image.FromStream(stream.BaseStream)
    End Using
    Using g As Graphics = Graphics.FromImage(PictureBox2.Image)
        g.Clear(SystemColors.Control)
        g.DrawImage(BackBmp, 0, 0)
    End Using
    PictureBox2.Invalidate()
End Sub

(4) 合成処理は、(1) に格納したビットマップを Picture2.Image に描画してから行います。

Private Sub CombineImage()
    Using g As Graphics = Graphics.FromImage(PictureBox2.Image)
        g.Clear(SystemColors.Control)
        g.DrawImage(BackBmp, 0, 0)

        '合成処理

    End Using
    PictureBox2.Invalidate()
End Sub

以上です。

Comments

[sake]

ありがとうございました。
わざわざ丁寧なモジュールを付けて頂いて、大変助かりました。
またお世話になる機会があると思いますが、その節もよろしくお願いします。