ボリュームラベルの値をファイル名に代入するには

Question

バッチファイルを作っています。
外付けドライブEのファイル一覧をテキストファイルとして取得し、ボリュームラベル＋日時.txtでファイル名にしたいです。
ボリュームラベル名をテキストファイル名に代入するにはどうすればいいのでしょうか？
日時のみのファイル名では以下で動作します

@ECHO OFF
echo %date%
echo %time%

set yyyy=%date:~0,4%
set mm=%date:~5,2%
set dd=%date:~8,2%

set time2=%time: =0%

set hh=%time2:~0,2%
set mn=%time2:~3,2%
set ss=%time2:~6,2%
@ECHO ON
cd C:\Windows\System32
cd /d e:
dir /s /-c > C:\Users\user\Desktop%yyyy%%mm%%dd%_%hh%%mn%%ss%.txt
:EXIT

Comments

[V1489-Cygni]

ごめんなさい。こちらに書かないと通知が行かないですよね。
追記を致しましたので、読んで下さい。

Answer 1

一例ですが、下記の %V% にボリュームラベルが入ってます。

for /f "tokens=1*" %%a in ('wmic path Win32_LogicalDisk get caption^,VolumeName') do (
    if "%%a"=="E:" call :Trim %%b
)
echo %V%
exit /b

:Trim
set V=%*
exit /b

質問者さんのスクリプトに入れると、

@ECHO OFF
echo %date%
echo %time%

set yyyy=%date:~0,4%
set mm=%date:~5,2%
set dd=%date:~8,2%

set time2=%time: =0%

set hh=%time2:~0,2%
set mn=%time2:~3,2%
set ss=%time2:~6,2%
for /f "tokens=1*" %%a in ('wmic path Win32_LogicalDisk get caption^,VolumeName') do (
    if "%%a"=="E:" call :Trim %%b
)
@ECHO ON
cd C:\Windows\System32
cd /d e:\
dir /s /-c > C:\Users\user\Desktop\%V%_%yyyy%%mm%%dd%_%hh%%mn%%ss%.txt
exit /b

:Trim
set V=%*
exit /b

＜追記＞

@ECHO OFF
echo %date%
echo %time%

set yyyy=%date:~0,4%
set mm=%date:~5,2%
set dd=%date:~8,2%

set time2=%time: =0%

set hh=%time2:~0,2%
set mn=%time2:~3,2%
set ss=%time2:~6,2%
for /f "tokens=4*" %%a in ('vol E:') do (
    set V=%%b
    goto Next
)

:Next
set V=%V: です=%
@ECHO ON
cd C:\Windows\System32
cd /d e:\
echo dir /s /-c > C:\Users\user\Desktop\%V%_%yyyy%%mm%%dd%_%hh%%mn%%ss%.txt

Comments

[fuji369jp]

HDDで動作しました。ありがとうございます

テープドライブではメディアをLTFSマウントさせた状態で実行すると、
_yyyymmdd_hhmmss.txtと出力され、ボリュームラベルが落ちてしまいました

最初に投稿した文をマウントしたテープドライブに対し実行すると、
出力結果.txtでは　"ドライブ @ のボリューム ラベルは [数字6桁] です"
と返ってきます

LTOメディアはフォーマットでtepe serial number と　Tape volume name２つが指定でき、
値の入れ方で２通り返ってきました。私はBで統一しています。

【A】
Tape serial numberを 123456
Tape volume nameを ABCDE でフォーマットした場合
m:\>vol
ドライブ M のボリューム ラベルは ABCDE です
ボリューム シリアル番号は 0000-0000 です
ーーーーーーーーーーーーーーーーーーー
【B】
Tape serial number を123456
Tape volume name をnull でフォーマットした場合
m:\>vol
ドライブ M のボリューム ラベルは 123456 です
ボリューム シリアル番号は 0000-0000 です

となります。
ボリュームラベル(実際はTape Serial Number)123456をファイル名に取得するには
どこを変えればいいのでしょうか…？

[V1489-Cygni]

申し訳ございません。テープドライブの使用時の仕組みはよく分からないです。
「wmic path Win32_LogicalDisk get caption^,VolumeName」 の VolumeName を VolumeSerialNumber に変えるとどうなるでしょうか？

項目一覧は、PowerShell を開いていただいて、
gwmi -Class Win32_LogicalDisk | % {if($_.Caption -eq 'E:'){$_ | select *}}
を実行していただいて、抽出したい項目が見つかるでしょうか？
多分、VolumeSerialNumber なのかな？と想像しているのですが・・・。

[fuji369jp]

VolumeSerialNumber に変えたところ、やはりボリューム名だけ弾かれてしまいました
Powershellを実行して覗いたところ、関係ありそうなのは
SystemName : LTO5N99A9617
VolumeDirty :
VolumeName :
VolumeSerialNumber :
Scope : System.Management.ManagementScope
となり、欲しい項目はnullでした。メディア側で持っているのかもしれません。
判ったところはここまでです。ありがとうございます。

[V1489-Cygni]

じゃあ、Vol コマンドでちゃんと表示されるのなら、Vol コマンドから抜き取りましょうか・・・。
編集で回答に追加しました。バッチファイルの保存時の文字コードは、ANSI か Shift_JIS にして下さい。

[fuji369jp]

ありがとうございます、無事tape serial numberが代入され生成されました。
HDDとテープドライブでは考え方を変えないといけないことがよくわかりました。