バッチファイルを用いてSymantec Endpoint Protectionをアンインストールし、新しいセキュリティソフトをインストールしたい

Question

バッチファイルを用いて、OSがWindows 10のPCからSymantec Endpoint Protection(以下SEP)を
アンインストール(できればサイレントで)して、新しいセキュリティソフトをインストールしたいです。
作業の順番としては先に新しいソフトを入れてからSEPをアンインストールしたいと考えています。

色々と検索しながらプロトタイプを作りましたが、改善したい部分が複数ございます。
作成したプロトタイプは以下の通りです。

@echo off

set MYDIR=%~dp0

rem 新しいソフトが稼働しているか確認

sc qc "○○○○" >nul
if not errorlevel 1 (
 goto no_install
) else (
 goto newsoft_install
)

:no_install
echo ○○○○は既にインストール済みです。
timeout /t 3 /nobreak > nul
echo.
goto SEP_confirmation


:SEP_confirmation
rem SEPが稼働しているか確認

sc qc "SISIPSService" >nul
if not errorlevel 1 (
 goto SEP_exist
) else (
 goto SEP_not_exist
)


:SEP_exist
echo Symantec Endpoint Protectionがインストールされています。
timeout /t 3 /nobreak > nul
echo.
goto SEP_uninstall


:SEP_not_exist
echo Symantec Endpoint Protectionはインストールされていません。
timeout /t 3 /nobreak > nul
echo.
goto End


:SEP_uninstall
echo Symantec Endpoint Protectionをアンインストールします。
timeout /t 3 /nobreak > nul
echo.


set Soft=Symantec Endpoint Protection
if "%PROCESSOR_ARCHITECTURE%"=="x86" goto x86
reg query "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Uninstall" /s | find "DisplayName" | find "%Soft%">nul
if %errorlevel% equ 0 (
    set Regpath1=HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Uninstall
    goto START
) else (
    reg query "HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall" /s | find "DisplayName" | find "%Soft%">nul && (
        set Regpath1=HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall
        goto START
    )
)

:x86
reg query "HKEY_LOCAL_MACHINE\Software\Microsoft\Windows\CurrentVersion\Uninstall" /s | find "DisplayName" | find "%Soft%">nul
if %errorlevel% equ 0 (
    set Regpath1=HKEY_LOCAL_MACHINE\Software\Microsoft\Windows\CurrentVersion\Uninstall
) else (
    echo Application Program not found
    exit /b
)

:START
for /f "delims=[]" %%i in ('reg query "%Regpath1%" /s ^| findstr "%Regpath1% DisplayName %Soft%" ^| find /n /v "" ^| find "DisplayName" ^| find "%Soft%"') do (
    set /a cnt=%%i-1
)

:LOOP
for /f "tokens=1* delims=[] " %%b in ('reg query %Regpath1% /s ^| findstr "%Regpath1% DisplayName %Soft%" ^| find /n /v "" ^| findstr /r "^[%cnt%]"') do (
    echo %%c | find "%Regpath1%">nul && (
        set Regpath2=%%c
        goto SUB
    )
)
set /a cnt-=1
goto LOOP

:SUB
for /f "tokens=2*" %%a in ('reg query "%Regpath2%" ^| find "UninstallString"') do (
    set UIS=%%b
)
rem --- %UIS% に、UninstallString値が入っている。 ---

msiexec /x %UIS:~14% /passive SYMREBOOT=ReallySuppress REMOVE=ALL


rem SEPが稼働しているか確認

sc qc "SISIPSService" >nul
if not errorlevel 1 (
 goto uninstall_failed
) else (
 goto uninstall_successful
)


:uninstall_failed
echo Symantec Endpoint Protectionはアンインストールされていません。
timeout /t 3 /nobreak > nul
echo.
goto End


:uninstall_successful
echo Symantec Endpoint Protectionはアンインストールされました。
timeout /t 3 /nobreak > nul
echo.
goto End


:newsoft_install
echo ○○○○をインストールします。
timeout /t 3 /nobreak > nul
echo.


rem インストーラの存在を確認

if not exist %MYDIR%\○○○○.exe (
 goto no_exe
) else (
 goto yes_exe
)


:no_exe
echo 同じフォルダにインストーラがありません。
timeout /t 3 /nobreak > nul
echo.
goto End

:yes_exe
rem 新しいソフトをサイレントインストール

%MYDIR%\○○○○.exe /install /quiet /norestart


rem 新しいソフトが稼働しているか確認

sc qc "○○○○" >nul
if not errorlevel 1 (
 goto install_successful
) else (
 goto install_failed
)


:install_successful
echo 新しいソフトがインストールされました。
timeout /t 3 /nobreak > nul
echo.
goto SEP_uninstall


:install_failed
echo 新しいソフトはインストールされていません。
timeout /t 3 /nobreak > nul
echo.




:End
echo batを終了します。
timeout /t 3 /nobreak > nul

改善したい部分は2点ございます。

1. sc qcではなく、sc queryでRUNNING状態か否かで分岐させるようにしたい
2. バッチファイルを置いているのと同じフォルダ内に実行結果を出力したい

以上2点について色々と検索してみたのですが、どこをどう変えればいいのかよく分かりませんでした。
どなたか知恵をお貸しください。

(以下は可能であれば)
最初はSEPをサイレントでアンインストールしたくてmsiexecの行に/qnや/quietを付けてみたのですが
一向にアンインストールされず、やむを得ず現状の無人モード(/passive)で記述したところ、無事に
アンインストールが進みました。
いくら調べてもなぜ/qnや/quietではダメだったのか、どうすればよかったのかが分かりませんでした。
もしこれの解決方法をご存知の方がいれば、ご教示いただけると幸いです。

Answer 1

forを使わなくとも

sc qc "○○○○" >nul　⇒　sc query "○○○○" | findstr STATE | findstr RUNNING > nul

の置き換えで解決いたしました。

Answer 2

sc qcではなく、sc queryでRUNNING状態か否かで分岐させるようにしたい

forを使う。

【Windowsバッチ】コマンド実行結果を環境変数に代入する方法
※他にも参考になるサイトはたくさんあると思うけど一例。

バッチファイルを置いているのと同じフォルダ内に実行結果を出力したい

echoの内容を逐次>>を使ってファイルにリダイレクトするか、このバッチそのものをxxx.bat > log.txtみたいな形で出力をファイルにリダイレクトする。

どっちにするかは細かい要求によって変わるかもしれないけど、いずれにせよ>や>>の使い方がわかってれば悩まないと思う。

Comments

[Kusabi5928]

すみません、スクリプト作成に関してはド素人なもので、sc queryのforを使う書き方を教えていただけないでしょうか？

[gentaro]

ググるための情報は上記回答で十分示してあるんで、自分で調べて試してみてから何がわからないのか具体的に質問するようにして。

[gentaro]

そもそもコマンドプロンプトでfor /?で詳細な使い方のヘルプが出る。