yaccの四則演算優先順位について

Question

前提・実現したいこと

yaccで四則演算の定義を行ったのですが、掛け算が足し算、引き算よりも優先的に実行されるようにするにはどうすればいいでしょうか。

該当のソースコード

%token NUM;
%%
explist :
| explist expr '\n' { printf("%d\n", $2); }
;
expr : prim { $$ = $1; }
| expr '+' prim { $$ = $1 + $3; }
| expr '-' prim { $$ = $1 + $3; }
| expr '*' prim { $$ = $1 * $3; }
;
prim : NUM { $$ = atoi(yytext); }
|'(' expr ')' { $$ = $2; }
;

試したこと

% ./a.out
(1 + 2) * (3 + 1)
12
1 + 2 * 3 + 1
10
このように前から順に計算されます。通常の四則演算のように掛け算が先に行われるにはどうしたらよいでしょうか

補足情報（FW/ツールのバージョンなど）

ここにより詳細な情報を記載してください。

Answer 1

2通りの解を示しますので、試してみた結果をコメントしてください。

%token NUM
%left '+' '-'  // 左結合
%left '*'      // 上記より高優先順位
%%
explist :
| explist expr '\n' { printf("%d\n", $2); }
;
expr : prim { $$ = $1; }
| expr '+' expr { $$ = $1 + $3; }  // 優先順位指定済みなので expr でよい
| expr '-' expr { $$ = $1 - $3; }
| expr '*' expr { $$ = $1 * $3; }
;
prim : NUM { $$ = atoi(yytext); }
|'(' expr ')' { $$ = $2; }
;

または

%token NUM
%%
explist :
| explist expr '\n' { printf("%d\n", $2); }
;
expr : term { $$ = $1; }
| expr '+' term { $$ = $1 + $3; }
| expr '-' term { $$ = $1 - $3; }
;
term:  prim { $$ = $1; }
| term '*' prim { $$ = $1 * $3; }
;
prim : NUM { $$ = atoi(yytext); }
|'(' expr ')' { $$ = $2; }
;
```1G

Answer 2

構文規則を分けて、掛け算が先にreduceされるようにする必要がありますね。
似たようなことしてるページがあるので、以下が参考になるかなと
http://kmaebashi.com/programmer/devlang/yacclex.html