VB background処理について windows, Visual Studio 2017、.NET Framework

Question

いつもお世話になっております。
現在ファイルアップローダーを作っている途中です。そこでは、background処理を用いて、非同期処理を行っています。backgroundに中断、再開機能をつ- リストけたいのですがうまくいきません。一応下記のようなことは試してみました。
1 BackgroundWorker1.CancelAsync()
2 System.Threading.Thread.Sleep(Thread.Sleep.infinity)
3 pause = True ,pause = False
どうぞよろしくお願いいたします。

#Region "変数宣言"
    Private m_strBtnchange As String = "no"
    Private m_folder As New FolderBrowserDialog
    Private m_strfile As String
    Private pause As Boolean = False
    Private idx As Integer = 0
#End Region
#Region "ボタンイベント"
    ''' <summary>
    ''' アップロード開始
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    Private Sub btn1_Click(sender As Object, e As EventArgs) Handles btn1.Click
        If m_strBtnchange = "ok" Then
            btn1.Text = "再開"
            m_strBtnchange = "no"
        ElseIf m_strBtnchange = "no" Then
            btn1.Text = "中断"
            m_strBtnchange = "ok"  
            BackgroundWorker1.RunWorkerAsync()
        End If
    End Sub
    ''' <summary>
    ''' フォルダの表示
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    Private Sub btn2_Click(sender As Object, e As EventArgs) Handles btn2.Click
        Try
            'FolderBrowserDialogクラスのインスタンスを作成
            '上部に表示する説明テキストを指定する
            m_folder.Description = "フォルダを指定してください。"
            'ルートフォルダを指定する
            'デフォルトでDesktop
            m_folder.RootFolder = Environment.SpecialFolder.Desktop
            '最初に選択するフォルダを指定する
            'RootFolder以下にあるフォルダである必要がある
            m_folder.SelectedPath = "C:\Windows"
            'ユーザーが新しいフォルダを作成できるようにする
            'デフォルトでTrue
            m_folder.ShowNewFolderButton = True
            'ダイアログを表示する
            If m_folder.ShowDialog(Me) = DialogResult.OK Then
                txt1.Text = ""
                ListBox1.Items.Clear()
                For Each foundFile As String In My.Computer.FileSystem.GetFiles(m_folder.SelectedPath, FileIO.SearchOption.SearchAllSubDirectories, "*.*")
                    Dim folderPath As String = IO.Path.GetDirectoryName(foundFile)
                    txt1.Text = folderPath
                    Dim fileName As String = IO.Path.GetFileName(foundFile)
                    ListBox1.Items.Add(fileName)
                Next
            End If
        Catch ex As System.UnauthorizedAccessException
            MessageBox.Show("有効なフォルダではありません。", "エラー", MessageBoxButtons.OK, MessageBoxIcon.Error)
            txt1.Text = ""
            txt1.Focus()
        End Try
    End Sub
#End Region
#Region "Background"
    Private Sub BackgroundWorker1_DoWork(sender As Object, e As System.ComponentModel.DoWorkEventArgs) Handles BackgroundWorker1.DoWork
        Dim str As String
        str = txt3.Text + txt6.Text
        Try
            If txt1.Text = "" And txt2.Text = "" Then
                MessageBox.Show("アップロード対象のファイルが1件もありません。", "エラー", MessageBoxButtons.OK, MessageBoxIcon.Error)
                Exit Sub
            End If

            For Each foundFile As String In My.Computer.FileSystem.GetFiles(m_folder.SelectedPath, FileIO.SearchOption.SearchAllSubDirectories, "*.*")
                System.Threading.Thread.Sleep(1000)
                My.Computer.Network.UploadFile(foundFile, str)
                Dim fileName As String = IO.Path.GetFileName(foundFile)
                m_strfile = fileName
                'ListBox3.Items.Add(m_strfile)
                BackgroundWorker1.ReportProgress(s, m_strfile)
            Next         
        Catch ex As System.Net.WebException
            MessageBox.Show("有効なフォルダではありません。(フォルダが大きすぎます。)", "エラー", MessageBoxButtons.OK, MessageBoxIcon.Error)
        Catch ex As System.InvalidOperationException
            MessageBox.Show("指定のサーバーへアクセスできません。", "エラー", MessageBoxButtons.OK, MessageBoxIcon.Error)
        End Try
    End Sub

    Private Sub BackgroundWorker1_ProgressChanged(sender As System.Object, e As System.ComponentModel.ProgressChangedEventArgs) Handles BackgroundWorker1.ProgressChanged
  
            ListBox3.Items.Add(m_strfile)
 
    End Sub
    Private Sub BackgroundWorker1_RunWorkerCompleted(sender As Object, e As System.ComponentModel.RunWorkerCompletedEventArgs) Handles BackgroundWorker1.RunWorkerCompleted
        m_strBtnchange = "no"
        btn1.Text = "アップロード開始"
    End Sub
    Private Sub txt1_Leave(sender As Object, e As EventArgs) Handles txt1.Leave
        Try
            m_folder.SelectedPath = txt1.Text
            For Each foundFile As String In My.Computer.FileSystem.GetFiles(m_folder.SelectedPath, FileIO.SearchOption.SearchAllSubDirectories, "*.*")
                Dim folderPath As String = IO.Path.GetDirectoryName(foundFile)
                txt2.Text = folderPath
                Dim fileName As String = IO.Path.GetFileName(foundFile)
                ListBox2.Items.Add(fileName)
            Next
        Catch ex As System.IO.DirectoryNotFoundException
            MessageBox.Show("有効なフォルダではありません。", "エラー", MessageBoxButtons.OK, MessageBoxIcon.Error)
            txt1.Text = ""
            txt1.Focus()
        Catch ex As System.ArgumentException
        End Try
    End Sub

#End Region
End Class

コード

Comments

[退会済みユーザー]

何を作っているか（WinForms? WPF? ASP.NET Web アプリ？　その他？）と開発環境（OS, Visual Studio のバージョン、.NET Framework なのか Core なのかとそのバージョン）を書いてください。

今時 BackgroundWorker などを使っているのには何かそうせざるを得ない理由があるのですか（.NET 4.0 以前とか）？　.NET 4.5 以降であれば async / await を使ってはいかがですか？　キャンセル処理の実装も容易にできると思います。

非同期タスクのキャンセル
http://surferonwww.info/BlogEngine/post/2020/09/27/cancellation-of-async-task.aspx

[jack]

返信ありがとうございます。windows, Visual Studio 2017、.NET Framework です！！
BackgroundWorkerは参考書に載っていたので、使ってみました。async / awaitを一度試してみます！

[退会済みユーザー]

非同期メソッド実装の変遷については以下の @IT の記事にまとめられていますので一読されてはいかがでしょう。

第1回　.NET開発における非同期処理の基礎と歴史
https://www.atmarkit.co.jp/fdotnet/chushin/masterasync_01/masterasync_01_02.html

BackgroundWorker はその記事の図の「Event-based」に出てきます。（過去の遺物かも）

[dodox86]

@質問者 sakanaさん

作っているアプリの形態(Windows Forms, WPF...)やバージョン情報は質問内容に付随する大切な情報ですので、本コメント欄にではなく、質問文中に追記、修正のかたちで加筆してください。

[jack]

かしこまりました。ありがとうございます！！

[退会済みユーザー]

> VB background処理について windows, Visual Studio 2017、.NET Framework

何を作っているかと開発環境の追加情報はタイトルではなく本文を編集して追記してください。

それから、windows では Winforms なのか WPF なのか ASP.NET なのかその他なのかが分かりません。.NET Framework のバージョンも書いてください。

あと、BackgroundWorker を使うことでこのまま進めたいのか、async / await を使うことに方針変更するのか、どうするのでしょう？

[退会済みユーザー]

基本的には質問のテンプレートがあるので、それに沿って記述した方がよいでしょう。
（質問作成するときに、最初に質問のテンプレート書いてある筈なんだけどな…）

[退会済みユーザー]

> VB background処理について windows, Visual Studio 2017、.NET Framework

何を作っているかと開発環境の追加情報はタイトルではなく本文を編集して追記してください。

それから、windows では Winforms なのか WPF なのか ASP.NET なのかその他なのかが分かりません。.NET Framework のバージョンも書いてください。

上記を今からでも遅くはないので必ずやってください。Teratail のスレッドは質問者さん専用の Q&A の場ではなくて、 https://teratail.com/help/question-tips に書いてあるように「質問と回答を通してお互いに知識や情報を交換・共有する場所」とのことです。その意味で質問の体裁を整えることは質問者さんの務めです。

Answer 1

とりあえずBackgroundWorkerで進められているようなので、それベースの回答をします。

BackGroundWorker.CancelAsyncを呼び出すと、BackGroundWorker.CancellationPendingがTrueに設定されるので、それを判定してDoWorkを終了します。その際に、DoWorkEventArgs.Cancel=Trueに設定すると、RunWorkerCompletedイベント内でキャンセルされたかどうかを判定する事が出来ます。
再開をする場合は、それに必要な情報をメンバ変数に保持しておき、DoWork内でメンバ変数の値を使用して処理を継続すれば良いでしょう。

Imports System.ComponentModel

Public Class Form1

    '進行状況
    Private _Percent As Integer = 0

    Private Sub BackgroundWorker1_DoWork(sender As Object, e As System.ComponentModel.DoWorkEventArgs) Handles BackgroundWorker1.DoWork
        Do While _Percent < 100

            'キャンセル要求が来ていたら中断
            If BackgroundWorker1.CancellationPending Then
                e.Cancel = True
                Exit Do
            End If

            '一秒毎に進行状況10%加算
            _Percent += 10
            Threading.Thread.Sleep(1000)

            '進行表示
            BackgroundWorker1.ReportProgress(_Percent)
        Loop
    End Sub

    Private Sub BackgroundWorker1_ProgressChanged(sender As Object, e As System.ComponentModel.ProgressChangedEventArgs) Handles BackgroundWorker1.ProgressChanged
        LabelProgress.Text = $"{e.ProgressPercentage} %"
        ProgressBar1.Value = e.ProgressPercentage
    End Sub

    Private Sub ButtonStart_Click(sender As Object, e As EventArgs) Handles ButtonStart.Click
        BackgroundWorker1.WorkerReportsProgress = True '進行状況通知有効
        BackgroundWorker1.WorkerSupportsCancellation = True 'キャンセル有効化

        'BackgroundWorker実行
        BackgroundWorker1.RunWorkerAsync()
    End Sub

    Private Sub ButtonCancel_Click(sender As Object, e As EventArgs) Handles ButtonCancel.Click
        'キャンセル要求をする(BackgroundWorker1.CancellationPending=Trueに設定される）
        BackgroundWorker1.CancelAsync()
    End Sub

    Private Sub BackgroundWorker1_RunWorkerCompleted(sender As Object, e As RunWorkerCompletedEventArgs) Handles BackgroundWorker1.RunWorkerCompleted
        If e.Cancelled Then
            LabelProgress.Text &= " 中断しました"
        Else
            LabelProgress.Text &= " 完了しました"
        End If
    End Sub

End Class

追記修正依頼でSurferOnWwwさんが紹介されているasync/awaitは新しい方法で、完全に新規でやるのであればそちらの方を推奨しますが、書き方もガラっと変わってくるので、関連する記事を探して読んで学習してみてください。一応BackgroundWorkerも使えなくなった訳ではないので、機能を満たせればいいのであれば問題ありません。