内部表現を文字列表現にする

Question

###やりたいこと
ocamlにおいて，
(Mul (Mul (x,y), Add (y,Num 1)));;
のように与えられた内部表現を
xy(y+1)
のように表現したい．

###現状のコード

type exp =
  | Num of int 
  | Var of string 
  | Add of exp * exp 
  | Mul of exp * exp;;

let make_sum a1 a2 = Add (a1,a2);;

let make_product m1 m2 = Mul (m1,m2);;

let rec string_of_exp var = function
  | Num n -> string_of_int n
  | Var x -> x
  | Add (x, y) -> "(" ^ string_of_exp (x) ^ "+" ^ string_of_exp (y) ^")"
  | Mul (x, y) -> string_of_exp (x) ^ "*" ^ string_of_exp (y);;

###表示されるエラー

type exp = Num of int | Var of string | Add of exp * exp | Mul of exp * exp
val make_sum : exp -> exp -> exp = <fun>
val make_product : exp -> exp -> exp = <fun>
File "ex3_1.ml", line 14, characters 24-41:
14 |   | Add (x, y) -> "(" ^ string_of_exp (x) ^ "+" ^ string_of_exp (y) ^")"
                             ^^^^^^^^^^^^^^^^^
Error: This expression has type exp -> string
       but an expression was expected of type string

###質問したい内容
stringとしてつなげたいのですが，上記の表現ではうまくそのように表現できていない様子です．
valはstringであるし，Numもstring_of_intでstringにしているのに，なぜstringとして受け取られなのでしょうか．

Answer 1

問題点: function 構文の使い方、引数の位置が省略形と混同されている。

解決策A: 引数を明示する場合は match var with が必要。
解決策B: 引数を明示しない場合は、var が不要。

問題点2: 変数 x, y が未定義　⇛ おそらく Var "x" ?

---

引数が意図通りに渡っているか確かめると判明すると思います。

type exp =
  | Num of int 
  | Var of string 
  | Add of exp * exp 
  | Mul of exp * exp;;


let rec string_of_exp = function
  | Num n -> string_of_int n
  | Var x -> x
  | Add (x, y) -> "(" ^ string_of_exp (x) ^ "+" ^ string_of_exp (y) ^")"
  | Mul (x, y) -> string_of_exp (x) ^ "*" ^ string_of_exp (y);;
  
let x = Var "x" and
    y = Var "y" in
  print_string (string_of_exp (Mul (Mul (x,y), Add (y,Num 1))));

print_newline ();;

出力結果

x*y*(y+1)

明示的に書く場合

let rec string_of_exp var =
  match var with
  | Num n -> string_of_int n
  | Var x -> x
  | Add (x, y) -> "(" ^ string_of_exp (x) ^ "+" ^ string_of_exp (y) ^")"
  | Mul (x, y) -> string_of_exp (x) ^ "*" ^ string_of_exp (y);;

Comments

[grape_ll]

前回書いたときから時間が空いてしまっていたので，理解が混同していました．修正したところ，問題なく動作しました，ありがとうございました．

Answer 2

手元で試したところ、ご質問のエラーと同じ場所で、以下の警告も出ました。

Warning 5 [ignored-partial-application]: this function application is partial,
maybe some arguments are missing.

string_of_exp関数に与える引数が足りないので、部分適用になっているそうです。

functionを使うとき、=の左辺に現れない、一番最後の引数がマッチングの対象になります。つまり以下のようにした場合、varが第1引数になりますが、

let rec string_of_exp var = function

functionがマッチングに使うのはvarではなくて、その後にあるはずの第2引数になります。つまりOCamlはstring_of_expが引数を2つ取ると解釈するのです。

これをstring_of_exp xのように適用すると、引数が1つ足りないので、string値が返る代わりに、第1引数が部分適用された関数exp -> stringが返ります。そのためにエラーになっています。

string_of_expの定義の1行目を以下のように修正してください（varを削除する）　これでエラーが解消するはずです。

let rec string_of_exp = function