VB.NET ListViewで並び替えした後でも選択したアイテムを移動させたい

Question

ソートする前の状態では、上下ボタンで選択したアイテムを移動させる事が
出来ていましたが、ソート後では上下ボタンでアイテムが移動出来なくなりました。
ソート後でも、選択したアイテムを移動させたいのですが、原因が分かりません。
どなたか教えて頂きたいと思います。宜しくお願い致します。
※FromにListViewとButtonを2つ配置しています。

Imports System.Text
Imports Microsoft.VisualBasic.FileIO
Public Class Form1
    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        With ListView1
            .GridLines = True
            .View = View.Details
            .FullRowSelect = True
            .MultiSelect = False
            .Columns.Add("　 I D", 70, HorizontalAlignment.Center)
            .Columns.Add("会　社　名", 200, HorizontalAlignment.Center)
            .Columns.Add("名　前", 130, HorizontalAlignment.Center)
        End With
        Using parser As New TextFieldParser("C:\Users\ユーザー名\テスト.csv", Encoding.UTF8)
            parser.TextFieldType = FieldType.Delimited
            parser.HasFieldsEnclosedInQuotes = True
            parser.SetDelimiters(",")
            ListView1.Items.Clear()
            While Not parser.EndOfData
                Dim fields As String() = parser.ReadFields()
                ListView1.Items.Add(New ListViewItem(fields))
            End While
        End Using
    End Sub

    ' 「↑」ボタン
    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        'アイテムが選択されていない場合抜ける
        If ListView1.SelectedItems.Count = 0 Then
            Return
        End If
        '先頭のアイテムが選択されている場合抜ける
        If ListView1.SelectedItems(0).Index = 0 Then
            Return
        End If
        '挿入先のインデックス
        Dim insertPosition As Integer = ListView1.SelectedItems(0).Index - 1
        '選択されたアイテム
        Dim itm As ListViewItem = ListView1.SelectedItems(0)
        '選択されたアイテムを削除する
        ListView1.Items.Remove(itm)
        'アイテムを挿入する
        ListView1.Items.Insert(insertPosition, itm)
        ListView1.Select()
        ListView1.EnsureVisible(insertPosition)
    End Sub

    ' 「↓」ボタン
    Private Sub Button2_Click(sender As Object, e As EventArgs) Handles Button2.Click
        'アイテムが選択されていない場合抜ける
        If ListView1.SelectedItems.Count = 0 Then
            Return
        End If
        '最後のアイテムが選択されている場合抜ける
        If ListView1.SelectedItems(0).Index = ListView1.Items.Count - 1 Then
            Return
        End If
        '挿入先のインデックス
        Dim insertPosition As Integer = ListView1.SelectedItems(0).Index + 1
        '選択されたアイテム
        Dim itm As ListViewItem = ListView1.SelectedItems(0)
        '選択されたアイテムを削除する
        ListView1.Items.Remove(itm)
        'アイテムを挿入する
        ListView1.Items.Insert(insertPosition, itm)
        ListView1.Select()
        ListView1.EnsureVisible(insertPosition)
    End Sub

    'フォームのカラムクリックイベント
    Private Sub ListView1_ColumnClick(ByVal sender As Object,
                ByVal e As System.Windows.Forms.ColumnClickEventArgs) _
                  Handles ListView1.ColumnClick
        Static no(2) As Integer  '列のソート状態保持用
        If no(e.Column) = 0 Then
            '初回または昇順
            Me.ListView1.ListViewItemSorter = New ListViewItemComparer(e.Column, 0)
            no(e.Column) = 1    '次回は降順
        Else
            '降順
            Me.ListView1.ListViewItemSorter = New ListViewItemComparer(e.Column, 1)
            no(e.Column) = 0    '次回は昇順
        End If
    End Sub

    'ListViewItemComparerクラスをフォームコードに追加
    Class ListViewItemComparer
        Implements IComparer

        Private col As Integer
        Private sort As Integer

        Public Sub New()
            col = 0
            sort = 0
        End Sub

        Public Sub New(ByVal column As Integer, ByVal sortflg As Integer)
            'column  : 列番号
            'sortflg : ソート(0=昇順,1=降順)
            '--------------------------------
            col = column
            sort = sortflg
        End Sub

        Public Function Compare(ByVal x As Object, ByVal y As Object) As Integer _
           Implements IComparer.Compare
            If sort = 0 Then
                '昇順
                Return [String].Compare(CType(x, ListViewItem).SubItems(col).Text,
                                        CType(y, ListViewItem).SubItems(col).Text)
            Else
                '降順
                Return -[String].Compare(CType(x, ListViewItem).SubItems(col).Text,
                                         CType(y, ListViewItem).SubItems(col).Text)
            End If
        End Function
    End Class
End Class

Comments

[YAmaGNZ]

ListView.ListViewItemSorterプロパティの説明に
https://docs.microsoft.com/ja-jp/dotnet/api/system.windows.forms.listview.listviewitemsorter?view=netframework-4.8
Sort または項目がリストに追加されたときに、コントロール内の項目の並べ替えを実行するオブジェクトを指定できます。
とあります。
アイテムを消して挿入した結果ソートされているだけなのではないでしょうか。

[sin777]

遅くなりましたが、回答有難う御座いました。
フォームのカラムクリックイベントの
Me.ListView1.ListViewItemSorter = New ListViewItemComparer(e.Column, 0)の後と、
Me.ListView1.ListViewItemSorter = New ListViewItemComparer(e.Column, 1)の後に
「ListView1.ListViewItemSorter = Nothing」の一行を入れる事で
解決しました。
有難う御座いました。

Answer 1

フォームのカラムクリックイベントの
Me.ListView1.ListViewItemSorter = New ListViewItemComparer(e.Column, 0)の後と、
Me.ListView1.ListViewItemSorter = New ListViewItemComparer(e.Column, 1)の後に
「ListView1.ListViewItemSorter = Nothing」の一行を入れる事で解決しました。