VB.NET：DB.Nullを含むテーブルの特定列データ行の小計列、合計列を追加

Question

前提・実現したいこと

複数テーブルを結合して特定列データ行の小計列、合計列を追加しようとしています。
ただし、結合テーブルの中にDB.Nullが含まれます。

https://teratail.com/questions/320488
にてDecimal型すべての合計列の追加はDBNull なら 0 に書き換える方法で一旦解決しております。
（希望する結果をそのように指定していたため）

前スレッドでベストアンサーを決定した後、実際のデータでいろいろ試している最中にDB.Nullと0を区別して表示させた方がよいと思うところがありましたので、新しいスレッドを作らせて頂きました。
今回はDB.Nullをテーブル表示として残す方法を模索しております。

結合テーブル
HIN CODE1 CODE2 CODEME1 CODEME2
100 101 102
110 111 112
300 121 142 221 242
310 131 152 231 252
200 201 202
210 211 212

希望する結果（今回はDB.Nullの表示をそのまま残します）
HIN　　CODE1 CODE2 CODEME1 CODEME2 subtotal1 subtotal2 total
100 101 102 101 102 203
110 111 112 111 112 223
300 121 142 221 242 342 384 726
310 131 152 231 252 362 404 766
200 201 202 201 202 403
210 211 212 211 212 423

subtotal1はCODE1,CODEME1の合計値（DB.Nullは0として計算）
subtotal2はCODE2,CODEME2の合計値（DB.Nullは0として計算）
totalはCODE1,CODE2,CODEME1,CODEME2の合計値

発生している問題

下記ソースコードでサンプルデータの希望する実行結果は得られていますが、
今後計算する列数が増えた場合に、Decimal型かどうかのIF文が複雑になってしまいます。
列数が増えても複雑にならないスマートな記述方法を探しております。

該当のソースコード

Imports System
Imports System.Data
Imports System.Windows.Forms

Public Class Form1

    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load

        Dim table As DataTable = New DataTable()
        table.Merge(CreateDataTable1())
        table.Merge(CreateDataTable2())
        table.Columns.Add("subtotal1", GetType(Decimal))
        table.Columns.Add("subtotal2", GetType(Decimal))
        table.Columns.Add("total", GetType(Decimal))

        Dim subtotal1 As Decimal = 0D
        Dim subtotal2 As Decimal = 0D
        Dim total As Decimal = 0D

        For i As Integer = 0 To table.Rows.Count - 1
            If TypeOf table.Rows(i).Item("CODE1") Is Decimal And TypeOf table.Rows(i).Item("CODEME1") Is Decimal Then
                subtotal1 = table.Rows(i).Item("CODE1") + table.Rows(i).Item("CODEME1")
            End If
            If TypeOf table.Rows(i).Item("CODE1") Is Decimal And TypeOf table.Rows(i).Item("CODEME1") IsNot Decimal Then
                subtotal1 = table.Rows(i).Item("CODE1")
            End If
            If TypeOf table.Rows(i).Item("CODE1") IsNot Decimal And TypeOf table.Rows(i).Item("CODEME1") Is Decimal Then
                subtotal1 = table.Rows(i).Item("CODEME1")
            End If
            If TypeOf table.Rows(i).Item("CODE2") Is Decimal And TypeOf table.Rows(i).Item("CODEME2") Is Decimal Then
                subtotal2 = table.Rows(i).Item("CODE2") + table.Rows(i).Item("CODEME2")
            End If
            If TypeOf table.Rows(i).Item("CODE2") Is Decimal And TypeOf table.Rows(i).Item("CODEME2") IsNot Decimal Then
                subtotal2 = table.Rows(i).Item("CODE2")
            End If
            If TypeOf table.Rows(i).Item("CODE2") IsNot Decimal And TypeOf table.Rows(i).Item("CODEME2") Is Decimal Then
                subtotal2 = table.Rows(i).Item("CODEME2")
            End If

            table.Rows(i).Item("subtotal1") = subtotal1
            table.Rows(i).Item("subtotal2") = subtotal2
            table.Rows(i).Item("total") = subtotal1 + subtotal2
        Next

        Me.DataGridView1.DataSource = table
    End Sub

    Protected Function CreateDataTable1() As DataTable
        Dim table As DataTable = New DataTable()
        Dim idColumn As DataColumn = New DataColumn("HIN", GetType(String))
        table.Columns.Add(idColumn)
        table.Columns.Add(New DataColumn("CODE1", GetType(Decimal)))
        table.Columns.Add(New DataColumn("CODE2", GetType(Decimal)))
        table.Rows.Add("100", 101D, 102D)
        table.Rows.Add("110", 111D, 112D)
        table.Rows.Add("300", 121D, 142D)
        table.Rows.Add("310", 131D, 152D)
        table.PrimaryKey = New DataColumn() {idColumn}
        Return table
    End Function

    Protected Function CreateDataTable2() As DataTable
        Dim table As DataTable = New DataTable()
        table.Columns.Add(New DataColumn("HIN", GetType(String)))
        table.Columns.Add(New DataColumn("CODEME1", GetType(Decimal)))
        table.Columns.Add(New DataColumn("CODEME2", GetType(Decimal)))
        table.Rows.Add("200", 201D, 202D)
        table.Rows.Add("210", 211D, 212D)
        table.Rows.Add("300", 221D, 242D)
        table.Rows.Add("310", 231D, 252D)
        Return table
    End Function


End Class

補足情報（FW/ツールのバージョンなど）

OS Windows10
VB.NET

Microsoft Visual Studio Community 2017
Version 15.6.7
VisualStudio.15.Release/15.6.7+27428.2043
Microsoft .NET Framework
Version 4.8.04084

Comments

[退会済みユーザー]

前回の方法でDBNullを置換し、その後合計すればDecimal判定は不要だと思いますが。DBNullを残したいということ？
あと回答ではないですが、table.Rows(i).Item("XXX") みたいなのを使いまくるくらいなら、For Each でDataRow を変数に受けた方がスッキリします。
For Each row As DataRow In table.Rows
row("XXX") = …
Next

[退会済みユーザー]

前のスレッドの url を書いてその続きであることを明記しよう。

[退会済みユーザー]

前のスレッドで DataTable の中身が DBNull なら 0 に書き換える回答をベストアンサーにしたのだから、その延長でいいのでは？

[Kouta2020]

radian様、前スレッドから続けてのコメントありがとうございます。
希望する結果で示したつもりが、きちんと言葉にしていなかったため分かりづらくてすみません。
おっしゃる通りDB.Nullをテーブル表示として残す方法を得たいため再度新しくスレッドを立ち上げました。

[Kouta2020]

SurferOnWww様、引き続きコメントありがとうございます。
前スレッドで質問した時は希望する結果にDB.Nullに0を入れるテーブルを示していましたので、
それに合っていた回答ということで解決したつもりでした。
前スレッドでベストアンサーを決定した後、実際のデータでいろいろ試している最中にDB.Nullと0を区別して表示させた方がよいと思うところがありましたので、新しいスレッドを作らせて頂きました。
希望する結果で示したつもりだったのですが、説明不足ですみませんでした。

[退会済みユーザー]

質問欄を編集してその事を追記してください。

[Kouta2020]

SurferOnWww様、コメントありがとうございます。
質問欄を編集致しました。ご指摘ごもっともです。

[退会済みユーザー]

上の radian さんのコメント

> table.Rows(i).Item("XXX") みたいなのを使いまくるくらいなら、For Each でDataRow を変数に受けた方がスッキリします。
For Each row As DataRow In table.Rows
row("XXX") = …
Next

もよく考えてみることをお勧めします。

[Kouta2020]

SurferOnWww様、お勧めありがとうございます。

上の radian さんのコメントを自分なりによく考えて、遅くなりましたが以下のプログラムに改善してみました。

For Each row As DataRow In table.Rows

Dim C1 = row("CODE1")
Dim C2 = row("CODE2")
Dim CM1 = row("CODEME1")
Dim CM2 = row("CODEME2")

row("subtotal1") = If(TypeOf C1 Is Decimal, C1, 0) + If(TypeOf CM1 Is Decimal, CM1, 0)
row("subtotal2") = If(TypeOf C2 Is Decimal, C2, 0) + If(TypeOf CM2 Is Decimal, CM2, 0)
row("total") = row("subtotal1") + row("subtotal2")

Next

Answer 1

DataColumn に式を設定したらどうでしょう。
DataColumn.Expression プロパティ

    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        Dim table = New DataTable()
        table.Merge(CreateDataTable1())
        table.Merge(CreateDataTable2())
        table.Columns.Add("subtotal1", GetType(Decimal), "ISNULL(CODE1,0) + ISNULL(CODEME1,0)")
        table.Columns.Add("subtotal2", GetType(Decimal), "ISNULL(CODE2,0) + ISNULL(CODEME2,0)")
        table.Columns.Add("total", GetType(Decimal), "subtotal1 + subtotal2")
        Me.DataGridView1.DataSource = table
    End Sub

Comments

[Kouta2020]

radian様、回答ありがとうございます。
回答頂いた内容にて希望する結果が得られました。
とてもシンプルで、DataColumn.Expressionも大変参考になり、今後にとても役立ちそうです。

Answer 2

私なら以下のように書きますか。

Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
 
    Dim table As DataTable = New DataTable()
    Dim t1 As String = "subtotal1"
    Dim t2 As String = "subtotal2"
    Dim t3 As String = "total"
 
    With table
        .Merge(CreateDataTable1())
        .Merge(CreateDataTable2())
        .Columns.Add(t1, GetType(Decimal))
        .Columns.Add(t2, GetType(Decimal))
        .Columns.Add(t3, GetType(Decimal))
    End With
 
    For i As Integer = 0 To table.Rows.Count - 1
 
        With table.Rows(i)
            .Item(t1) = ToDecimal(.Item("CODE1")) + ToDecimal(.Item("CODEME1"))
            .Item(t2) = ToDecimal(.Item("CODE2")) + ToDecimal(.Item("CODEME2"))
            .Item(t3) = ToDecimal(.Item(t1)) + ToDecimal(.Item(t2))
        End With
 
    Next
 
    Me.DataGridView1.DataSource = table
 
End Sub
 
Private Function ToDecimal(ByVal o As Object) As Decimal
 
    If IsDBNull(o) Then Return 0D
 
    Return If(TypeOf o Is Decimal, CDec(o), 0D)
 
End Function

Comments

[Kouta2020]

sanshimon様、回答ありがとうございます。
回答頂いた内容にて希望する結果が得られました。
ToDecimal関数を作成するアイデアはとても私一人で思いつきませんでした。
後学のため、他の回答も参考にしたいのでもうしばらく待ちたいと思います。