VBSでExcelの起動を確認

Question

前提・実現したいこと

VBSでExcelが起動しているかを確認できるプログラムを組みたいです。
VBS初心者のため、プロトタイプでも結構ですので教えていただきたいです。

Comments

[kaina]

Officeのバージョンの質問と同様です。
ご自分で調べた上での質問ですか？

Answer 1

結構長いプログラムになりますが、載せておきます。

Sub Main()
    'WMIにて使用する各種オブジェクトを定義・生成する。
    Dim oClassSet
    Dim oClass
    Dim oLocator
    Dim oService
    'ここの名前を間違えるとアウト！！
    Dim TargetAppName:TargetAppName = "notepad.exe"
    Dim ExistFlag:ExistFlag = False
    'ローカルコンピュータに接続する。
    Set oLocator = WScript.CreateObject("WbemScripting.SWbemLocator")
    Set oService = oLocator.ConnectServer
    'クエリー条件を WQL にて指定する。
    Set oClassSet = oService.ExecQuery("Select * From Win32_Process")
    'コレクションを解析する。
    For Each oClass In oClassSet
        '対象のプロセス名が存在するかを判定します。
        If InStr(oClass.Description,TargetAppName) > 0 Then
            '対象のプロセスが存在すればフラグを立てます。
            ExistFlag = True
            Exit For
        End If
    Next

    '使用した各種オブジェクトを後片付けする。
    Set oClassSet = Nothing
    Set oClass = Nothing
    Set oService = Nothing
    Set oLocator = Nothing

    '存在チェックフラグがFalseの場合の処理
    If ExistFlag = False Then
        '==========================================
        'ここにやりたい処理を記載する。
        '==========================================
    End If
End Sub

参考URL：https://www.depthbomb.net/?p=1163

Answer 2

起動中のアプリケーション、プロセスを取得する: Win32_Process - WMI Sample (VBS)
などがとっかかりでしょう。