VB6 コマンドライン引数について

Question

VB6で、コマンドライン引数に フォルダーパスを入れたいのですが、
パスに半角スペースが入るので、ダブルクォーテーションで括ってデバッグし、
プログラム側でコマンドライン引数を取得すると、ダブルクォーテーションが入っていました。
VisualStudioでのデバック時にダブルクォーテーションが含まれないような方法はあるでしょうか。
実際にこのEXEをコマンドプロンプト等で実行する際にダブルクォーテーションを付けても
このようなことは起こらないと思うので、運用上は問題ないですが・・・。
コマンドライン引数は、[プロジェクトのプロパティ]-[実行可能ファイルの作成]-[コマンドライン引数]のところに入れています。

Answer 1

VB6 でコマンドライン引数をキチンと処理するのは結構やっかいなので CommandLineToArgvW を使ってみてください。

CommandLineToArgvW function (shellapi.h)
https://docs.microsoft.com/en-us/windows/win32/api/shellapi/nf-shellapi-commandlinetoargvw

Option Explicit

Private Declare Function CommandLineToArgvW Lib "shell32" (ByVal lpCmdLine As Long, pNumArgs As Integer) As Long
Private Declare Function LocalFree Lib "kernel32" (ByVal hMem As Long) As Long
Private Declare Function lstrlenW Lib "kernel32" (ByVal lpString As Long) As Long
Private Declare Function lstrcpyW Lib "kernel32" (ByVal lpString1 As Long, ByVal lpString2 As Long) As Long
Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (Destination As Any, Source As Any, ByVal Length As Long)

Private Const OFFSET_4      As Currency = 4294967296@
Private Const MAXINT_4      As Currency = 2147483647

Public Function DivCommand(ByVal iCommand As String) As String()
    Dim lpszArgs    As Long
    Dim nArgs       As Integer
    Dim i           As Long
    Dim nRet        As Long
    Dim sArgs()     As String

    lpszArgs = CommandLineToArgvW(StrPtr(iCommand), nArgs)
    If lpszArgs <> 0 Then
        ReDim sArgs(nArgs - 1)
        For i = 0 To nArgs - 1
            sArgs(i) = ToStringW(GetPointer(lpszArgs, i))
        Next
        nRet = LocalFree(lpszArgs)
    End If
    DivCommand = sArgs

End Function

Private Function GetPointer(ByVal iAddress As Long, ByVal iIndex As Long) As Long
Dim lpAddress As Long
Dim lpPointer As Long

    lpAddress = SLONG(ULONG(iAddress) + iIndex * 4)
    
    CopyMemory lpPointer, ByVal lpAddress, Len(lpPointer)
    GetPointer = lpPointer

End Function

Private Function SLONG(ByVal Value As Currency) As Long
    If Value < 0 Or Value >= OFFSET_4 Then Error 6
    If Value <= MAXINT_4 Then
        SLONG = Value
    Else
        SLONG = Value - OFFSET_4
    End If
End Function

Private Function ULONG(ByVal Value As Long) As Currency
    If Value < 0 Then
        ULONG = Value + OFFSET_4
    Else
        ULONG = Value
    End If
End Function

Private Function ToStringW(ByVal lpAddr As Long) As String
Dim nLen As Long
Dim strBuffer As String

    If lpAddr <> 0 Then
        nLen = lstrlenW(lpAddr)
        If nLen > 0 Then
            strBuffer = String(nLen + 1, vbNullChar)
            Call lstrcpyW(StrPtr(strBuffer), lpAddr)
            ToStringW = Left(strBuffer, InStr(strBuffer, vbNullChar) - 1)
        Else
            ToStringW = ""
        End If
    Else
        ToStringW = ""
    End If

End Function

使い方

Sub Main()
    Dim v As Variant
    For Each v In DivCommand(Command)
        MsgBox v
    Next
End Sub

Answer 2

削除する必要があるなら、コードで削除すればいいです。
が、そういう場合、削除すると動かなくなる場合があるので、そのままにしておくほうがいいかと思います。

運用上問題ないならなおさら