fortranでモジュールの中にいくつかの関数があります。関数1を関数2の中で使いたいです。どうすべきでしょうか？

Question

fortranでモジュールの中にいくつかの関数があります。関数1を関数2の中で使いたいです。wmとwpでv(x、s)を使う必要があります。よろしくお願いします。

module module_cmm
    implicit none
contains
    function v_prime(x, s) result(vpri)
        real(8) vpri, x
        integer s
        real(8) :: atil = 10
        vpri = 2.0*acos(-1.0)*atil*sin(2.0*acos(-1.0)*(x-0.25*s))
    end function v_prime
    function w_prime(u) result(wpri)
        real(8) wpri, u
        real(8) :: kupper = 10
        wpri = 2.0*acos(-1.0)*kupper*sin(2.0*acos(-1.0)*(u+1.0/3.0))
    end function w_prime
    function v(x, s) result(vres)
        real(8) vres, x
        integer s
        real(8) :: atil = 10, myutil
        vres = atil* (1.0-cos(2.0*acos(-1.0)*(x-0.25*s)))-0.25*s*myutil
    end function v
    function w(u) result(wres)
        real(8) wres, u
        real(8) :: kupper = 10
        wres = kupper*(1.0-cos(2.0*acos(-1.0)*(u+1.0/3.0)))
    end function w
    function wp(x, s) result(wpres)
        real(8) wpres, x
        integer s
        real(8) :: k = 1.0, q = 0.2
        real(8) v
        wpres = k*exp(q*(v(x, s)-v(x, s+1)))
    end function wp
    function wm(x, s) result(wmres)
        real(8) wmres, x
        integer s
        real(8) :: k = 1.0, q = 0.2
        wmres = k*exp((1.0-q)*(v(x, s)-v(x, s-1)))
    end function wm
end module module_cmm

Answer 1

質問では、何が問題なのか分かりませんが、使い方としては今のままで問題ないと思います。ただし、function wp の中で real(8) v と変数宣言しているので、これが関数名とかぶっているのでコンパイラに叱られます。

Module 内の副プログラムはお互いが見えているので、そのまま呼び出せます。

なお、細かいことを言えば、引数には intent 属性を指定してこちらの意図を明確にした方が、文法上の誤りを減らすとともに最適化も効きやすくなります。

また副プログラム内の変数宣言で初期値を与えると、その辺数は save 属性がつき、staticな永続変数になります。毎回初期化されるわけではありません。定数として用いるつもりなら、parameter 属性を付けた方が意図が明確になると思います。

変数を real(8) と倍精度宣言していますが、定数を 0.2 などと単精度で書いてあります。定数の方も 0.2d0 なり倍精度で書かないと期待した精度が得られません。

acos(-1.0) は倍精度引数にしたうえで、module parameter として real(8), parameter :: pi = acos(-1.0d0) などとする方が好ましいでしょう。

さらに細かいことを言えば、real(8) の kind の 8 は、処理系ごとに意味が異なり 8 が倍精度を意味するとは限らないので、Fortran 警察に違反切符を切られる可能性があるので要注意です。

Comments

[Okuhira007]

ありがとうございます。問題が解決しました！