MetaTrader4のヒストリカルデータを毎足完成ごとにcsv出力したい(常時更新できずに困っています)

前提・実現したいこと

MQL4を用いてヒストリカルデータを常時取得し、csvファイルに記載したい。

発生している問題・エラーメッセージ

インジケーターを挿入したタイミングでのみしかcsv出力を行うことができません。
時間足のろうそくが完成したタイミングでcsvを頻繁に更新したいです。

該当のソースコード

MQL4
1#property strict
2
3input int MaxBars = 1000;//出力したいデータ量を入力(ろうそくの本数)
4input   string WriteFileName   = "Test.csv";     //出力したいファイル名を入力
5int filehandle = FileOpen(WriteFileName, FILE_CSV | FILE_WRITE, ",");
6
7int OnCalculate(const int rates_total,
8                const int prev_calculated,
9                const datetime &time[],
10                const double &open[],
11                const double &high[],
12                const double &low[],
13                const double &close[],
14                const long &tick_volume[],
15                const long &volume[],
16                const int &spread[]){
17                
18   int limit = Bars - IndicatorCounted() - 1;
19   limit = MathMin(limit,MaxBars);
20   
21   if (filehandle > 0) {
22      FileWrite(handle, ServerAddress(), Symbol(), Period());                  
23      FileWrite(handle, "DATE","TIME","HIGH","LOW","CLOSE","OPEN","VOLUME");   
24      
25      for(int i = limit; i>=0;i--){
26         FileWrite(filehandle, TimeYear(Time[i]) + "/" +TimeMonth(Time[i]) + "/" + 
27         TimeDay(Time[i]) ,  TimeHour(Time[i]) + ":" + TimeMinute(Time[i]) ,Open[i], 
28         Close[i], High[i], Low[i],Volume[i] );
29      }
30      
31   FileClose(filehandle);
32   Comment(WriteFileName+" はMQL4>File フォルダに出力されました。 "+TimeToStr(TimeCurrent(), TIME_SECONDS) );
33   }
34   return(rates_total);
35}

試したこと

ティック更新で処理をしようとしました。

グローバルで始値、終値、高値、安値、時間、出来高に対して配列宣言を行い
もともとの組み込まれている
Open[i]のような配列ではなく、新たにiOpen(NULL , 0 , i)を代入してやってみました。

しかし、こちらの場合csv出力するとファイルが破損して開くことができませんでした。

補足情報（FW/ツールのバージョンなど）

MetaEditorを用いて記載しています。

行動規範の内容に同意します

回答1件

ベストアンサー

前回更新した時刻を記憶しておく
0番目は更新中のバーなので、1番目まで出力する

というふうにすれば出来ると思います。
試しに作ってみたソースは下記になります。(並びはOHLCになっています)

MQ4
1#property strict
2
3input int MaxBars = 1000;//出力したいデータ量を入力(ろうそくの本数)
4input string WriteFileName = "Test.csv";     //出力したいファイル名を入力
5int handle = INVALID_HANDLE;
6
7int OnInit()
8{
9    handle = FileOpen(WriteFileName, FILE_CSV | FILE_WRITE | FILE_SHARE_READ, ",");
10    if (handle == INVALID_HANDLE) {
11        return INIT_FAILED;
12    }
13
14    FileWrite(handle, ServerAddress(), Symbol(), Period());
15    FileWrite(handle, "DATE", "TIME", "OPEN", "HIGH", "LOW", "CLOSE", "VOLUME");
16
17    return INIT_SUCCEEDED;
18}
19
20void OnDeinit(const int)
21{
22    FileClose(handle);
23}
24
25int OnCalculate(const int rates_total,
26                const int prev_calculated,
27                const datetime &time[],
28                const double &open[],
29                const double &high[],
30                const double &low[],
31                const double &close[],
32                const long &tick_volume[],
33                const long &volume[],
34                const int &spread[])
35{
36    static datetime prevTime = 0;
37
38    datetime currTime = iTime(NULL, PERIOD_CURRENT, 0);
39
40    if(currTime == prevTime) {
41        return rates_total;
42    }
43
44    prevTime = currTime;
45
46    int limit = Bars - IndicatorCounted() - 1;
47    limit = MathMin(limit, MaxBars);
48
49    for(int i = limit; i >= 1; i--) {
50        FileWrite(handle, StringFormat("%04d/%02d/%02d", TimeYear(Time[i]), TimeMonth(Time[i]), TimeDay(Time[i])),
51                  TimeToString(Time[i], TIME_MINUTES),
52                  Open[i],
53                  High[i],
54                  Low[i],
55                  Close[i],
56                  Volume[i]);
57    }
58
59    FileFlush(handle);
60
61    Comment(WriteFileName + " はMQL4>File フォルダに出力されました。 " + TimeToStr(prevTime, TIME_SECONDS) );
62
63    return(rates_total);
64}