Replace命令による複数単語の変換方法

Question

VBAのreplace命令の機能を使って、
一行に変換対象が複数の文字列を変換したいと考えています。
事情があり、一行につき一回のコードで実装をする事になっています。

例えば、大文字COMPANYは株式会社
小文字comanyは有限会社
というふうに

ワンレコードにCOMANYとcompanyが入り交じっているので、大文字と小文字が正確に変換するようにしたいです。

複数行に分けられない制約があるため、悩みでおります。
宜しくご教示お願い致します。

Comments

[KoichiSugiyama]

「事情があり、一行につき一回のコードで実装をする事になっています。」と意味がちょっと分からないのですが、一回のreplace関数で二種類の変換をしたいという意味でしょうか？そのあたりを詳しく書いていただけると、違う視点からのアドバイスをしてくださる方もおられるかもしれません。

[edmame]

コメントありがとうございます。
電車の中で携帯から投稿したので、詳しく書けませんでしがた、実現したい内容は
ご指摘のとおり、replace関数で二種類の変換をしたいです。
コマンドで言うと
str1=("hogehoge_COMANY_hohoho_company......")
replace（str1,COMANY, 株式会社とcompany,有限会社) みたいな感じです。

宜しくご教示お願い致します。

Answer 1

無理に一行で書くならKoichiSugiyamaさんの回答になると思いますが、私は関数化をお勧めします。
複数ワードに対応した置換関数を作っておけば何かと便利かと思います。
以下サンプルです。

Sub test()
    Dim str1 As String
    str1 = "hogehoge_COMPANY_hohoho_company......"
    Debug.Print ReplaceEx(str1, "COMPANY", "株式会社")
    Debug.Print ReplaceEx(str1, "company", "有限会社")
    Debug.Print ReplaceEx(str1, "COMPANY", "株式会社", "company", "有限会社")
    Debug.Print ReplaceEx(str1, "COMPANY", "株式会社", "company", "有限会社", "hoge", "あ", "ho", "い")
End Sub

Function ReplaceEx(ByVal str As String, ParamArray words() As Variant) As String
    For i = 0 To UBound(words) - 1 Step 2
        str = Replace(str, words(i), words(i + 1))
    Next
    ReplaceEx = str
End Function

出力結果
hogehoge_株式会社_hohoho_company......
hogehoge_COMPANY_hohoho_有限会社......
hogehoge_株式会社_hohoho_有限会社......
ああ_株式会社_いいい_有限会社......

Comments

[sazi]

vbBinaryCompareを指定されていませんが、大文字/小文字の識別が出来ていますね。
手元で試してみたところ同じ結果だったのですが、逆にvbTextCompareを指定しても大文字/小文字が識別されます。
理由をご存知ですか？

[ttyp03]

試してみました。
確かにvbTextCompareが効かないですね。
Option Compare Text を冒頭で定義すると、これは効きました。
ただcompare引数のデフォルト値はvbBinaryCompareはずなのに、vbUseCompareOptionの方を見に行ってしまうのが謎です。
よくわからないですね。

[ttyp03]

あ、引数で指定してもできました。
名前付きで指定しないとダメでした。
Replace(str, words(i), words(i + 1), compare:=vbTextCompare)

[sazi]

ありがとうございます。compare引数は必ず指定する（かつ名前付きで）方が無難ですね。
因みに、質問者さんが誤記されているからですけど、COMANYになってます。
大文字/小文字の識別例としてはCOMPANYとしておいた方が良いと思います。

[ttyp03]

スペルミスは気づいてました。
それが原因かと思いましたが、違いましたね。
コードはこのあと修正しておきます。

Answer 2

どうしても一行ですましたいのであれば、ちょっと無理やりですが

str1 = ("hogehoge_COMANY_hohoho_company......")
str1 = Replace(Replace（str1,"COMANY", "株式会社", 1, -1, vbvbBinaryCompare), "company","有限会社", 1, -1, vbBinaryCompare)

こんな感じでどうでしょうか。

Comments

[edmame]

ありがとうございました。
解決出来ました。

Answer 3

Replace 関数
compare引数をvbBinaryCompareにすると大文字/小文字を識別できます。