Visual Basic x OpenCVSharp4でGetIndexer()を使用したMatへのアクセスを行いたい

Question

前提・実現したいこと

Visual Basic.NETでOpenCVSharpを使用し、画像認識による自動化ソフトを作成しています。
機能の1つを実装するために、GetIndexer()を使用してMatのピクセルデータにアクセスするコードを書いています。
現在OpenCVSharp 4.1.0.20190416を使用しており、最新バージョン(4.4.0.20200725)にアップデートしようとしたところ、以下のエラーメッセージが発生しました。

発生している問題・エラーメッセージ

エラー	BC32044	型引数 'Vec3b' は、制約型 '?' から継承したり、この型を実装したりしません。
エラー	BC30649	'' の型はサポートされていません。

該当のソースコード

'Version 4.1.0.20190416
Dim src As Mat = New Mat("xxx.png", ImreadModes.AnyColor)

Dim matofbyte_tpl As MatOfByte3 = New MatOfByte3(src)
Dim indexer_tpl As MatIndexer(Of Vec3b) = matofbyte_tpl.GetIndexer()

For y = 0 To src.Height - 1
    For x = 0 To src.Width - 1

        '各ピクセルのRGB値を取得
        Dim rgb As Vec3b = indexer_tpl(y, x)
        Debug.WriteLine("R:{0}, G:{1}, B:{2}", rgb(2), rgb(1), rgb(0))

    Next

Next


'Version 4.4.0.20200725
Dim src As Mat = New Mat("xxx.png", ImreadModes.AnyColor)

Dim matofbyte_tpl As Mat(Of Vec3b) = New Mat(Of Vec3b)(src) 'この行でエラーが発生します。
Dim indexer_tpl As MatIndexer(Of Vec3b) = matofbyte_tpl.GetIndexer()

For y = 0 To src.Height - 1
    For x = 0 To src.Width - 1

        '各ピクセルのRGB値を取得
        Dim rgb As Vec3b = indexer_tpl(y, x)
        Debug.WriteLine("R:{0}, G:{1}, B:{2}", rgb(2), rgb(1), rgb(0))

    Next

Next

試したこと

バージョン4.1.0.20190416から4.1.1.20191017へのアップデートで使用できなくなったことを確認しました。
OpenCVSharpのコミットを見てみると、MatOfXXXというクラス？が削除され、以下のように記述するようになったようです。
https://github.com/shimat/opencvsharp/compare/4.1.0.20190417...4.1.1.20191023

-            using (var imgt = new MatOfByte3(img))
+            using (var imgt = new Mat<Vec3b>(img))

C#で記述したところ正常に動作することを確認できたので、VB.NETでの書き方に問題があると考えています。

Mat src = new Mat("xxx.png", ImreadModes.AnyColor);
Mat<Vec3b> matofbyte_tpl = new Mat<Vec3b>(src);
MatIndexer<Vec3b> indexer_tpl = matofbyte_tpl.GetIndexer();

for (int y = 0; y < src.Height; y++)
{
    for (int x = 0; x < src.Width; x++)
    {
        Vec3b rgb = indexer_tpl[y, x];

        Debug.WriteLine("R:{0}, G:{1}, B:{2}",rgb[2],rgb[1],rgb[0]);

    }
}

エラー内容を調べ、解決方法も見てみたのですが、型パラメーターに指定されたすべてのインターフェイスを実装し～　や、サポートされる型を使用、新しい型を開発等と書かれており、理解が及ばず質問させていただいた次第です。

よろしくお願いいたします。

補足情報（FW/ツールのバージョンなど）

開発環境
VisualStudio 2019
VisualBasic
Microsoft .Net Framework 4.7.2

追記(2020-07-26 13:26)

以下のコードでもMatへのアクセス（RGB値の取得）を行うことができました。シンタックスハイライトが少しおかしいような…？

'Imports System.Runtime.InteropServices
'Imports OpenCvSharp

Dim src As Mat = Cv2.ImRead("xxx.png", ImreadModes.AnyColor)
Dim bgr As Byte() = New Byte(3 * src.Total() - 1) {} '画像のピクセル数xチャンネル数分のByte配列を確保する。

Marshal.Copy(src.Data, bgr, 0, bgr.Length)

For i = 0 To bgr.Length - 1 Step 3
    '(B,G,R)=(255,0,0)…全体を青色にしてみる
    bgr(i) = 255 'B
    bgr(i + 1) = 0 'G
    bgr(i + 2) = 0 'R

Next

Marshal.Copy(bgr, 0, src.Data, bgr.Length)

Cv2.ImShow("Result", src)

Answer 1

自分もOpenCV初心者で最新バージョンを使っていないため、動かなかったら申し訳ございませんが、

Dim src As Mat = Cv2.ImRead("xxx.png", ImreadModes.AnyColor)
Dim indexer_tpl As Mat.Indexer(Of Vec3b)=src.GetGenericIndexer(Of Vec3b)
For y = 0 To src.Height - 1
    For x = 0 To src.Width - 1
        Dim rgb As Vec3b = indexer_tpl(y, x)
        '処理
    Next
Next

で問題なく動作しませんか？

加えて、New Mat()で画像読み込んでも、実際にちゃんとデーターが読み込まれているか確認しましたか？（自分の場合は読み込まれていないことが多かったです。原因不明。）

追記(2020-07-26 13:26)とコメントに対するコメント（2020-07-26 15:53）

追加情報のお知らせありがとうございます。どうでもいいことかもしれませんが、RGB値読んで簡単な処理をするだけならOpenCvSharpを導入するまでもなく同じようにバイト配列読む方法で、System.Drawing（GDI+であってるかな）でできるので念のため載せておきます。

Imports System.Runtime.InteropServices
Using bmp As New Bitmap("xxx.png")
    Dim bmpData1 As Imaging.BitmapData = bmp.LockBits(New Rectangle(Point.Empty, bmp.Size), Imaging.ImageLockMode.ReadOnly, Imaging.PixelFormat.Format32bppArgb)
    Dim pix1 As IntPtr = bmpData1.Scan0
    Dim dataLength As Integer = bmpData1.Stride * bmpData1.Height
    For i = 0 To dataLength - 1 Step 4
        Dim c As Color = Color.FromArgb(Marshal.ReadByte(pix1, i + 3), Marshal.ReadByte(pix1, i + 2), Marshal.ReadByte(pix1, i + 1), Marshal.ReadByte(pix1, i))                       
    Next
    bmp.UnlockBits(bmpData1)
End Using

Comments

[lemongrass]

回答ありがとうございます。
GetGenericIndexer()を使用して、4.4.0.20200725で稼働することを確認できました。ありがとうございます！

私の環境ではNew Mat()で特に問題なく読み込めていましたが、Imreadを使ったほうが良いようですね（実際のアプリではImreadを使用していたのになんでNew Mat()で書いたんだろう…）。

処理速度を見てみましたが、GetIndexer()とGetGenericIndexer()それぞれの処理速度を100回ループした平均で見てみると、大体3倍ちょっとGetIndexerを使用したほうが早い結果となりました。実用上問題なければバージョンアップ、あれば現在のバージョンを使い続けていこうと思います。
（同バージョンで比較したいためC#、画像サイズ：630x360
　GetIndexer()→22ms
　GetGenericIndexer()→72ms）

Mat<Vec3b>がVB.NETで使用できないのは、（もし記述方法があっていれば）C#の仕様変更にVB.NETがサポートできていないことが理由なのではとOpenCVSharpのIssueを見てふと思いました。
https://github.com/shimat/opencvsharp/issues/911

[lemongrass]

↑のIssueの助言を頼りに調べてみたところ、高速にRGB値を得ることができました（コードは質問内容に追記いたしました）。RGB値を得るだけでも色々な手法がありますね…

[lemongrass]

追記コメント、GDI+を利用した方法についての記載ありがとうございます。
後出しになってしまいますが、画像認識を具体的に書くと2枚の画像…デスクトップ上の画面をキャプチャした画像と事前にキャプチャした画像（テンプレート）を比較するもので、RGB値を利用したものの他にテンプレートマッチングやヒストグラム、AKAZE等様々な種類の比較ができるように作成しています。前処理の時点で画像を既にMatに変換している為、MatのままRGB値を取得しよう、ということで制作していました（プロフィールに一応制作物へのURLを貼っておきます…恥ずかしいので適当なタイミングで削除します）。

今後またなにか作るときには参考にさせていただきます。
（Marshal.Copyを使用したコードをStepを使った方法に書き換えました。喜びに舞い上がってて）