CSVファイルの繰り返し処理で、処理済の行のデータを削除したい。

Question

VBS初心者です。
csv処理を作っているのですが、調べても実現できない状況のため、解決策やアドバイスをご教示いただきたく、質問致します。

実現したいこと

次のようなCSVファイルがあります。

日付,場所,天気
5/1,東京,晴れ
6/2,千葉,くもり
7/7,神奈川,雨

1.１行目を読み飛ばす。
2.２行目以降を１行ずつ読込、配列にして必要な部分だけを置換処理する。
晴れ→1　くもり→2　雨→3
3.別のcsvファイルに書き込む。

期待する結果

5/1,東京,1
6/2,千葉,2
7/7,神奈川,3

実行して得られる結果

5/1,東京,1
5/1,6/2,東京,千葉,1,2
5/1,6/2,7/7,東京,千葉,神奈川,1,2,3

DO LOOPで繰り返していく中で、処理済の行の配列？まで次の行で書き込まれるようになってしまいます。

発生している問題・エラーメッセージ

エラーメッセージは出ません。

該当のソースコード

Option Explicit

Dim objFS
Dim objRFile
Dim objWFile
Dim strReadFile
Dim strWriteFile
Dim strLine
Dim AryStrings
Dim i
Dim str(2)
Dim objRegExp
Dim strRep(2)

strReadFile = "C:\Users\Desktop\read.csv" '元データファイルを開く
strWriteFile = "C:\Users\Desktop\write.csv" '生成データファイル

Set objFS = Wscript.CreateObject("Scripting.FileSystemObject") 'ファイルシステムオブジェクトをつくる
Set objRFile = objFS.OpenTextFile(strReadFile) '元データファイルを開く
Set objWFile = objFS.OpenTextFile(strWriteFile,8,true) '生成データファイルの末尾に追加書き込みをする
Set objRegExp = New RegExp '正規表現による検索や置換を行うためのオブジェクト

strLine = objRFile.SkipLine '1行目を読み飛ばす

Do until objRFile.AtEndOfStream '最終行を読み込んだら繰り返し終了
	strLine = objRFile.ReadLine '次の行を読み込む
	AryStrings = Split(strLine,",") 'カンマ区切りの文字列を配列にする
		For i = 0 to 2
			'日付をそのまま入力
			If i = 0 Then
				str(i) = str(i) & AryStrings(i) & ","
			End If
			'場所をそのまま入力
			If i = 1 Then
				str(i) = str(i) & AryStrings(i) & ","
			End If
			'天気を番号に変換する
			If i = 2 Then
				objRegExp = "晴れ"
				If AryStrings(i) = objRegExp Then
					strRep(i) = Replace(AryStrings(i),"晴れ","1")
				End If
				objRegExp = "くもり"
				If AryStrings(i) = objRegExp Then
					strRep(i) = Replace(AryStrings(i),"くもり","2")
				End If
				objRegExp = "雨"
				If AryStrings(i) = objRegExp Then
					strRep(i) = Replace(AryStrings(i),"雨","3")
				End If
				str(i) = str(i) & strRep(i) & ","
			End If
			'ファイルに書き込み
			objWFile.Write(str(i))
		Next
Loop

objRFile.Close
objWFile.Close

Set objFS = Nothing
Set strReadFile = Nothing
Set strWriteFile = Nothing
Set objRFile = Nothing
Set objWFile = Nothing
Set strLine = Nothing
Set AryStrings = Nothing
Set i = Nothing
Set str(2) = Nothing
Set objRegExp = Nothing
Set strRep(2) = Nothing

何卒、よろしくお願い致します。

Answer 1

Do Untilのループ内で、配列strRepが初期化されないので、延々と文字列追加が続いてしまうからですね。
そもそもstrRepに一旦格納する必要ないと思います。
CSVの３カラム目のみが変換対象ですし、折角作成した正規表現オブジェクトが活用できてないのでこれを利用して、置換してしまえば良いでしょう。

Option Explicit

Dim objFS
Dim objRFile
Dim objWFile
Dim objRegex1
Dim objRegex2
Dim objRegex3
Dim strLine

Set objRegex1 = New RegExp
Set objRegex2 = New RegExp
Set objRegex3 = New RegExp
objRegex1.Pattern = "晴れ$"
objRegex2.Pattern = "くもり$"
objRegex3.Pattern = "雨$"

Set objFS = Wscript.CreateObject("Scripting.FileSystemObject")
Set objRFile = objFS.OpenTextFile("hogehoge.csv")
Set objWFile = objFS.OpenTextFile("fugafuga.csv", 8, true)

strLine = objRFile.SkipLine

Do until objRFile.AtEndOfStream
	strLine = objRFile.ReadLine
	strLine = objRegex1.Replace(strLine, "1")
	strLine = objRegex2.Replace(strLine, "2")
	strLine = objRegex3.Replace(strLine, "3")
	objWFile.WriteLine(strLine)
Loop

オブジェクトの後始末とか端折ってますが、、、

入力ファイル(hogehoge.csv)

日付,場所,天気
5/1,東京,晴れ
6/2,千葉,くもり
7/7,神奈川,雨

出力ファイル(fugafuga.csv)

5/1,東京,1
6/2,千葉,2
7/7,神奈川,3

Comments

[SOHR]

ご回答ありがとうございます。
strRepの初期化がポイントだったのですね。その前のAryStringsの初期化を試してみてうまくいかず、今回質問した次第でした。
変換するカラムが固定なので、ご教示いただいたコードでうまくいきました。
改めて御礼申し上げます。

Answer 2

str(i) = str(i) & AryStrings(i) & ","

と継ぎ足してしまっているのが問題ですね。
あと折角配列にしているので、出力したデータをだけ集めて最後にJoinすると楽です。
あと正規表現で検索する必要性もないですね。
あとループで回す必要もないです（この例に限りますが）
というのを踏まえてDo～Loop内を書き換えてみました。
動作確認はしていませんのであしからず。

Do until objRFile.AtEndOfStream '最終行を読み込んだら繰り返し終了
	strLine = objRFile.ReadLine '次の行を読み込む
	AryStrings = Split(strLine,",") 'カンマ区切りの文字列を配列にする

	'日付をそのまま入力
	str(0) = AryStrings(0)

	'場所をそのまま入力
	str(1) = AryStrings(1)

	'天気を番号に変換する
	Select Case AryStrings(2)
		Case "晴れ"
			str(2) = "1"
		Case "くもり"
			str(2) = "2"
		Case "雨"
			str(2) = "3"
		Case Else
			str(2) = ""
	End Select

	'ファイルに書き込み
	objWFile.Write(Join(str, ","))
Loop

Comments

[SOHR]

ご回答ありがとうございます。
str(i)の継ぎ足しが反映されていることに気づきませんでした。
こちらをstr(i) = AryStrings(i) & "," にするだけでも解消しました。
(末尾の & "," がないと、カンマ区切りの書き込みにならなかったので付け足しています。)
また、Select Case を使っての置換は知りませんでしたので、大変勉強になりました。
今後の参考にさせていただきます。

[ttyp03]

Select Case のは置換ではないですよ（文字列の一部を置き換えているわけではない）。
あくまでも出力するデータを「晴れ」なら「1」のようにしているだけです。
「今日は晴れ」みたいな文字列の「晴れ」を「1」に置き換える場合は置換処理が必要になりますが、今回はそのような必要はなかったというだけです。

[SOHR]

丁寧なご教示ありがとうございます。
まだまだ勉強不足ですが、学んだことを以降のケースで活用していけるよう精進します。