DropDownListForのVBでの書き方を知りたいです。

Question

前提・実現したいこと

DropDownListForの書き方（言語はVisual Basic）を知りたいです。

発生している問題・エラーメッセージ

Create.vbhtmlファイルの「 IEnumerable(Of SelectListItem)ViewBag.SelectOptions」の箇所に波線でエラーが出ていました。

「IEnumerable(Of SelectListItem)はインターフェース型であり、式として使用することはできません。」

該当のソースコード

※Test.vbのファイルです。

Imports System.ComponentModel.DataAnnotations
Imports System.ComponentModel
Imports Microsoft.VisualBasic

Public Class Test
    Inherits System.Web.Mvc.Controller

    <Key()>
    <DisplayName("ID")>
    Public Property Id As String

    <DisplayName("判定")>
    Public Property Judge As Integer

End Class

※TestsController.vbのファイルです。
※今回の質問に不要だと思われるActionを一部省略しております。

Imports System
Imports System.Collections.Generic
Imports System.Data
Imports System.Data.Entity
Imports System.Linq
Imports System.Net
Imports System.Web
Imports System.Web.Mvc
Imports MvcApp

Namespace Controllers
    Public Class TestsController
        Inherits Controller

        Private db As New MyMvcContext

        ' GET: Tests
        Function Index() As ActionResult
            Return View(db.Tests.ToList())
        End Function

        ' GET: Tests/Create
        Function Create() As ActionResult
            ViewBag.SelectOptions = New SelectListItem() {
                New SelectListItem() With {.Value = "1", .Text = "合格"},
                New SelectListItem() With {.Value = "0", .Text = "不合格"}
                }

            Return View()
        End Function

        ' POST: Tests/Create
        '過多ポスティング攻撃を防止するには、バインド先とする特定のプロパティを有効にしてください。
        '詳細については、https://go.microsoft.com/fwlink/?LinkId=317598 を参照してください。
        <HttpPost()>
        <ValidateAntiForgeryToken()>
        Function Create(<Bind(Include:="Id, Judge")> ByVal test As Test) As ActionResult
            If ModelState.IsValid Then
                db.Tests.Add(test)
                db.SaveChanges()
                Return RedirectToAction("Index")
            End If
            Return View(test)
        End Function
    End Class
End Namespace

※Create.vbhtmlのViewファイルです。
※コード真ん中あたりの箇所で、エラーが発生しております。

@ModelType MvcApp.Test

@Code
    ViewData("Title") = "Create"
End Code

<h2>Create</h2>

@Using (Html.BeginForm())
    @Html.AntiForgeryToken()

    @<div class="form-horizontal">
        <h4>Test</h4>
        <hr />
        @Html.ValidationSummary(True, "", New With {.class = "text-danger"})
        <div class="form-group">
            @Html.LabelFor(Function(model) model.Id, htmlAttributes:=New With {.class = "control-label col-md-2"})
            <div class="col-md-10">
                @Html.EditorFor(Function(model) model.Id, New With {.htmlAttributes = New With {.class = "form-control"}})
                @Html.ValidationMessageFor(Function(model) model.Id, "", New With {.class = "text-danger"})
            </div>
        </div>

        <div class="form-group">
            @Html.DropDownListFor(Function(model) model.Judge, IEnumerable(Of SelectListItem)ViewBag.SelectOptions, New With {.Class = "form-control"})
        </div>

        <div class="form-group">
            <div class="col-md-offset-2 col-md-10">
                <input type="submit" value="Create" class="btn btn-default" />
            </div>
        </div>
    </div>
End Using

<div>
    @Html.ActionLink("Back to List", "Index")
</div>

@Section Scripts
    @Scripts.Render("~/bundles/jqueryval")
End Section

試したこと

以下の記事を参考にしつつ、C#とVBの変換サイトを使って変換してみました。
https://www.buildinsider.net/web/bookaspmvc5/040204

今回のエラー箇所については、変換がうまくできなかったため、色々試した結果が、上記のCreate.vbhtmlのファイルになります。

【C#とVBの変換サイト】
https://converter.telerik.com/

補足情報（FW/ツールのバージョンなど）

統合開発環境
Visual Studio2019
（言語：VB.NET、プロジェクトテンプレート：ASP.NET Webアプリケーション MVC）

使用PC
Windows10

※平日は仕事のため、返信が19:30-22:00になります。
※休日の返信は不定期です。
申し訳ございませんが、どうぞよろしくお願いします。

Answer 1

キャストという言葉を知ってますか？　知らなければまずググって調べてどういうものか理解してください。

VB.NET のキャストのやり方が間違ってます。

今回のエラー箇所については、変換がうまくできなかったため、

とのことですが、telerik の変換サービスでも使い方で変換できるはず。以下がその結果です。

var x = (IEnumerable<SelectListItem>)ViewBag.SelectOptions;

　↓↓↓

Dim x = CType(ViewBag.SelectOptions, IEnumerable(Of SelectListItem))

ただ、今回そこを直して局所的なエラーは消せたからと言って、全体的な動きが期待したものになるかは怪しいですが。

DropDownListFor を使うといろいろ予期ない結果を生むことがありますので DropDownList を使うことをお勧めします。詳しくは以下の記事を見てください。

DropDownList への SelectList の渡し方
http://surferonwww.info/BlogEngine/post/2019/02/25/how-to-give-selectlist-object-to-dropdownlist.aspx

Comments

[Eltk]

>SurferOnWww様

キャストの意味は知っております。
（後で調べてわかりましたが、C#のコードがキャストしているコードだったのですね）

教えていただいたコードに修正しましたところ、（実行前に発生していた）エラーは解決されました。
ありがとうございます。

実行時にまた別のエラーが発生しておりますので、（言われているような）予期しない結果、不具合なのかもしれませんが、一度、模索してみます。

参考記事もありがとうございました。