2点を結ぶ線分を多数グラフにプロットしたい

Question

Excelにて，X1,X2,Yの組み合わせのデータがあり，それらを使って，(X1,Y),(X2,Y)の2点を結ぶ線分を散布図の「マーカーと直線」で数十本作りたいと考えています．（下の図は2本引いたものになります）

手で系列を入力できなくないですが，何か良い方法があればご教授お願い致します。

Answer 1

だいぶ遅レスのためすでに自己解決されているかもしれませんが…。

こんなときはまず「系列を手で入力する」操作を、「マクロの記録」でVBA化してみてください。

例えば「系列3」として「X値：A4:B4、Y値：C4,C4」の系列を追加すると、

Sub Macro1()
'
' Macro1 Macro
'

'
    ActiveSheet.ChartObjects("グラフ 1").Activate
    ActiveChart.PlotArea.Select
    ActiveChart.SeriesCollection.NewSeries
    ActiveChart.SeriesCollection(3).Name = "=""系列3"""
    ActiveChart.SeriesCollection(3).XValues = "=Sheet1!$A$4:$B$4"
    ActiveChart.SeriesCollection(3).Values = "=Sheet1!$C$4, Sheet2!$C$4"
End Sub

というVBAコードが生成されます。
これを見ると何をどう設定しているのか、ある程度見えてきますね。

あとは使われているプロパティの意味を調べて、系列の名前と領域を変更しながら必要な数だけループ処理でまわせばできると思います。

---

今回は質問投稿からだいぶ日も経ってしまっていますので、速攻で使えるサンプルも提供しておきます。

以下はX1、X2、Yの値がそれぞれA列～C列に入力されているデータをもとに、2行目から10行分を系列として追加していくサンプルです。

Sub Sample()
    Dim ws As Worksheet
    Set ws = Worksheets("Sheet1")
    
    'グラフ作成
    Dim cht As Chart
    Set cht = ws.Shapes.AddChart.Chart      '新規グラフ作成
    cht.ChartType = xlXYScatterLines        '散布図（直線とマーカー）
    
    '系列追加ループ(10回)
    Dim iCnt As Integer
    For iCnt = 1 To 10
        'X座標はA列～B列の範囲を指定
        Set rngX = Range(ws.Cells(iCnt + 1, "A"), ws.Cells(iCnt + 1, "B"))
        
        'Y座標は同じセルを２回指定するため、少し特殊な書き方になっています
        Dim strY As String
        strY = ws.Name & "!" & ws.Cells(iCnt + 1, "C").Address  'Y座標セルのアドレス文字列を作成（例："Sheet1!C2"）
        Set rngY = Range(strY & "," & strY)                     'Y座標セルを2回指定したセル領域
        
        '系列の追加
        With cht.SeriesCollection.NewSeries
            .Name = "系列" & CStr(iCnt)
            .XValues = rngX
            .Values = rngY
        End With
    Next
End Sub

少しわかり難いところもあるのでコメント多めに記載してみました。
参考になれば幸いです。