teratermマクロを使用したscp転送のエラーについて

Question

現在TeratermマクロでSCPファイル転送をするツールを作成しています。
以下のコードでマクロを実行したところ「fopen 3」というエラーが発生し、
ファイル転送ができません。
解決策を教えていただけると助かります。

;; 接続報ホスト／ユーザ名設定 
HOSTADDR = '****' 
USERNAME = '****'
SOURFILE = '/tmp/test.txt'
DESTFILE = 'C:\tmp\test.txt'

;; ①接続先ホストのパスワードを入力
MASSAGE = 'HOST : ' 
strconcat MASSAGE HOSTADDR 
strconcat MASSAGE ' / USER NAME : ' 
strconcat MASSAGE USERNAME 
passwordbox MASSAGE 'Please input a password.' 
PASSWORD = inputstr

;; ②入力確認(パスワードが入力されていない場合マクロ終了) 
strcompare PASSWORD '' 
if result=0 then 
    messagebox 'A password is not input.' 'Input error' 
    end 
endif

;; ③コマンド組立て 
COMMAND = HOSTADDR 
strconcat COMMAND ':2222 /ssh /2 /auth=password /user=' 
strconcat COMMAND USERNAME 
strconcat COMMAND ' /passwd=' 
strconcat COMMAND PASSWORD

;; ④接続 
connect COMMAND

;; ⑤接続判定1（接続出来ない場合はメッセージを表示しマクロ終了） 
if result <> 2 then 
    messagebox 'It could not be connected.' 'Connection Error' 
    end 
endif

;; ⑥接続判定2（10秒以内にプロンプトが表示されない場合TeraTerm終了） 
timeout = 10 
wait '$' '#'
if result = 0 then 
    disconnect 0 
    end 
endif

;; ⑦ファイル送信 
scpsend SOURFILE DESTFILE
mpause 5000
sendln 'exit'

;; ⑧マクロ終了 
end

Answer 1

scpsend コマンドはローカルの(つまりWindowsの)ファイルをリモートに送信します。
そのため、SOURFILE (='/tmp/test.txt')がないとエラーになっているのではないでしょうか?
リモートの(=ssh接続先の)ファイルを受信するには scprecv コマンドを使用してみてください。

参考URL
https://ttssh2.osdn.jp/manual/ja/macro/command/scpsend.html

Comments

[merci_children]

解決できました。ありがとうございます。
scpsend 送信元 送信先だったのですね。
逆だと勘違いしていました。