Excel VBAで12桁以上の数値の連番について

Question

実現したいこと

英文字を含めた12桁以上の数値を繰り返し連番で出したいです。

例:Y40000000001
Y40000000002…

Range("A2").Select Selection.NumberFormatLocal = "@"
 Range("A2").AutoFill Destination :=Range(A2:A1000)
 Application.WindowState = xlNormal

発生している問題・分からないこと

英文字を含めた12桁以上の数値を繰り返し連番する方法がわかりません。

該当のソースコード

特になし

試したこと・調べたこと

• teratailやGoogle等で検索した
• ソースコードを自分なりに変更した
• 知人に聞いた
• その他

上記の詳細・結果

英文字を含めた12桁以上の数値を繰り返し連番する方法を検索したり、自分で変えたりしてみましたが、上手くいきませんでした。

補足

特になし

Answer 1

英文字を含めた12桁以上の数値を繰り返し連番で出したい

例:Y40000000001
Y40000000002…

Sub Test1()

    Dim rngCell As Range
    Dim lngMaxLen As Long
    Dim varNewValue As Variant
    
    Application.ScreenUpdating = False
    
    With Range("A2:A1000")
        .NumberFormat = "0"
        .Cells(1, 1).Value = 40000000001#
        .DataSeries xlColumns, xlDataSeriesLinear, , 1
        lngMaxLen = Len(CStr(WorksheetFunction.Max(.Value)))
        .NumberFormat = """Y""" & String(lngMaxLen, "0")
        For Each rngCell In .Cells
            varNewValue = rngCell.Text
            rngCell.NumberFormat = "@"
            rngCell.Value = varNewValue
        Next
    End With

    Application.ScreenUpdating = True

End Sub

こんな感じの処理を実行できればよい、ということでしょうか。

Answer 2

４行目で開始したい連番を指定。
６行目のiRowには入力したい行番号を入力。
SerialNumberは通貨型を使用していますので、922,337,203,685,477までなら連番可能です。

Sub test()
    Dim iRow As Long, SerialNumber As Currency

    SerialNumber = 400000000001# '-- 開始したい連番
    
    For iRow = 2 To 1000
        Cells(iRow, 1) = "Y" & SerialNumber
        SerialNumber = SerialNumber + 1
    Next

End Sub

Answer 3

Microsoft 365 または Excel 2021 以降なら、

Sub Sample()
    Range("A2").Formula2 = "=TEXT(SEQUENCE(999,,400000000001),""!Y000000000000"")"
    With Range("A2", Cells(2, 1).End(xlDown))
        .Value = .Value
    End With
End Sub

それ以前のバージョンなら、

Sub Sample2()
    With Range("A2:A1000")
        .Formula2 = "=TEXT(400000000000+ROW()-1,""!Y000000000000"")"
        .Value = .Value
    End With
End Sub

Answer 4

セルの書式設定で表示形式を「"Y"0」をいれてあとは数値をいれればよいのでは？

Comments

[MyVBA]

ありがとうございます！
Selection.NumberFormatLocal = "@"のところで、"Y"0に変更してみましたが、連番にならず、同じ数値が繰り返し出力されました…。

[MyVBA]

結果はY2になりました。

[yambejp]

数値は「40000000001」から連番の数値を入れるんですよ