自作関数の作り方のコツと画像に速度を持たせる方法

Question

void mato (float vx){
vx+=1;
image(img[0],vx+20,150,50,50);}

いかの画像が右へ移動するようにしたいのですが、分かりません。
誰か教えてください。

Answer 1

解決しました。ありがとうございます。
すみません、クラスの使い方が分からなくて、クラスとはどのように使いますか？

Comments

[TN8001]

> 解決しました。ありがとうございます。

この欄は回答を投稿する場所です。
回答のお礼や疑問はコメント欄に書いてください（回答の下のほうに「コメント」というボタンがあります）

> すみません、クラスの使い方が分からなくて、クラスとはどのように使いますか？

回答でクラスを定義も使用もしていますが、どの辺がわからないですか？
画像が複数になればわかりそうですか？

あまりに根本的な話になると、ここで説明しきれなくなります^^;
参考ページを紹介しておきます。

回答はこちらに寄せて回答しました。英語ですが自動翻訳で大体読めると思います。
[Objects / Processing.org](https://processing.org/tutorials/objects)

例えばこちらではボールを１個からいきなり60個に増やしています。
[b-10 オブジェクト指向プログラミング (OOP) - Proessing 学習ノート](https://www.d-improvement.jp/learning/processing/2011-b/10.html)

こちらでは跳ね回るボールを題材にクラスを解説されています。
[[Processing×Java] クラスの使いかた - Qiita](https://qiita.com/masterkeaton12/items/a8ef4603dce9b05fa840)

Answer 2

いかの画像が右へ移動するようにしたいのですが、分かりません。

どう動かしたいのかがコード片から読み取れないのですが、等速運動でいいんですかね？

PImage img;
int imgX;

void setup() {
  size(400, 300);
  img = loadImage("https://teratail-v2.storage.googleapis.com/uploads/avatars/u13/132786/KnkDDC5A_thumbnail.jpg");
}

void draw() {
  background(128);
  mato(imgX++); // imgが固定なのにxだけ引数なのはちょっと違和感（imgを複数場所に出すとかなら。まあ）
//  mato(); // こうでいいんじゃん？感
}

void mato(float x) {
  image(img, x, 150, 50, 50);
}

void mato() {
  image(img, imgX++, 50, 50, 50);
}

クラスを使うとコードは増えますが、グローバル変数が減って管理しやすいかもしれません。
オブジェクト/Processing.org

Character ika;

void setup() {
  size(400, 300);
  PImage img = loadImage("https://teratail-v2.storage.googleapis.com/uploads/avatars/u13/132786/KnkDDC5A_thumbnail.jpg");
  ika =  new Character(img, 0, 150, 2);
}

void draw() {
  background(128);
  ika.move();
  ika.display();
}


class Character {
  PImage img;
  float xpos;
  float ypos;
  float xspeed;

  Character(PImage tempImg, float tempXpos, float tempYpos, float tempXspeed) {
    img = tempImg;
    xpos = tempXpos;
    ypos = tempYpos;
    xspeed = tempXspeed;
  }

  void display() {
    image(img, xpos, ypos, 50, 50);
  }

  void move() {
    xpos = xpos + xspeed;
    if (xpos > width) {
      xpos = 0;
    }
  }
}

---

質問の補足として画像を張るのはいいですが、アクティブウィンドウだけにしたほうがいいですよ。
windows11 スクリーンショット - Google 検索