VB.NETで、ショートカットキーを押した時にLeaveイベントを発生させたい

Question

![イメージ説明]WIDTH:600

VB.NETで上記の画像のようなフォームを作り、テキストボックスにフォーカスがある状態で
Alt + Bを押してボタンのクリックイベントを発生させる前に、LeaveまたはLostFocusイベントを発火させたいのですが、画像の出力のようにValidate系のイベントが発生した後、そのままClickイベントが発生してしまいます。

LeaveまたはLostFocusイベントを発生させることは可能でしょうか。
ご教示願います。

Public Class Form1
    '出力
    Private Sub t(msg As String)
        Trace.TraceInformation(msg)
    End Sub

    'ボタンイベント
    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        t("Click!")
    End Sub

    'テキストボックスイベント
    Private Sub TextBox1_Enter(sender As Object, e As EventArgs) Handles TextBox1.Enter
        t("Enter!")
    End Sub

    Private Sub TextBox1_Leave(sender As Object, e As EventArgs) Handles TextBox1.Leave
        t("Leave!")
    End Sub

    Private Sub TextBox1_LostFocus(sender As Object, e As EventArgs) Handles TextBox1.LostFocus
        t("LostFocus")
    End Sub

    Private Sub TextBox1_Validated(sender As Object, e As EventArgs) Handles TextBox1.Validated
        t("Validated")
    End Sub

    Private Sub TextBox1_Validating(sender As Object, e As System.ComponentModel.CancelEventArgs) Handles TextBox1.Validating
        t("Validating")
    End Sub

End Class

ついでに、TeratailでVBのコードを書くときの言語名を教えて下さい(汗）

Answer 1

こんにちは。

Buttonを選択させるのが最も単純そうかなーと思いました。
タイミングはニーモニックキーを無効化してKeyDownとかでも良いかなと思ったんですが、
以下のほうが簡単なのでFormのProcessMnemonicでやることに。

Public Class Form1

    Protected Overrides Function ProcessMnemonic(charCode As Char) As Boolean
        If IsMnemonic(charCode, Button1.Text) Then
            Button1.Select()
        End If
        Return MyBase.ProcessMnemonic(charCode)
    End Function

End Class

Comments

[tamogi]

遅くなりましたが、回答ありがとうございました。
上記の方法で問題なく動作し、非常に助かりました。