フォームでボタンを押すとエラーになる

Question

###前提・実現したいこと
ExcelVBAでフォームから入力した情報を元にガントチャートを生成するシステムを作っています。
フォームに何も入力しない状態で「反映」ボタンを押したら以下のエラーメッセージが発生しました。

「On Error Resume Next」を使わないでエラーが出ないようにしたいのですが、エラーの原因がつかめません。わかるかた、ご教示願います。

###発生している問題・エラーメッセージ

実行時エラー '13'
型が一致しません。

###該当のソースコード

Private Sub CommandButton2_Click()
    'すべての項目をnull禁止
    If TextBox1.Value = "" Or ComboBox3.Text = "" Or ComboBox1.Text = "" Or ComboBox2.Text = "" Or CInt(Replace(ComboBox1.Text, "月", "")) > CInt(Replace(ComboBox2.Text, "月", "")) Then
        MsgBox "すべての入力項目を記入するか適切なデータを入れてください。"
    Else
        '該当「月」をアクティベート
        ThisWorkbook.Worksheets(ComboBox3.Text).Activate
            
        'タスクをA列に反映
        n = Cells(Rows.Count, 1).End(xlUp).Row + 1
        ActiveSheet.Cells(n, 1).Value = TextBox1.Value
        
        'タスクのチャートを反映
        '背景色と□の反映
        Range(Cells(n, CInt(Replace(ComboBox1, "月", "")) + 1), Cells(n, CInt(Replace(ComboBox2, "月", "")) + 1)).Interior.ColorIndex = 3
        Range(Cells(n, CInt(Replace(ComboBox1, "月", "")) + 1), Cells(n, CInt(Replace(ComboBox2, "月", "")) + 1)).Value = "□"
        
    End If
    
    
    
End Sub

Answer 1

フォームに何も入力していないということなので、多分、CInt()の部分で中身が空なのでエラーが出ているのでしょう。

ComboBox1に値が入力されているかどうかをIf文で判定して、処理を分岐させてみては。

Answer 2

コンボボックスに対してCIntをしているのが原因と思われます。
つまりこうなっているのでは。
CInt("")
大小比較を行いたいのはわかりますが、同時には行わないで、最初のif文では全て入力されているのかのチェック。
次に入力値の整合性チェックと段階を踏んで処理した方が良いでしょう。

Private Sub CommandButton2_Click()
    'すべての項目をnull禁止
    If TextBox1.Value = "" Or ComboBox3.Text = "" Or ComboBox1.Text = "" Or ComboBox2.Text = "" Then
        MsgBox "すべての入力項目を記入してください。"
		Exit Sub
	End If

	'選択月の整合性チェック
    If CInt(Replace(ComboBox1.Text, "月", "")) > CInt(Replace(ComboBox2.Text, "月", "")) Then
        MsgBox "適切なデータを入れてください。"
		Exit Sub
	End If

	'該当「月」をアクティベート
	ThisWorkbook.Worksheets(ComboBox3.Text).Activate

	'タスクをA列に反映
	n = Cells(Rows.Count, 1).End(xlUp).Row + 1
	ActiveSheet.Cells(n, 1).Value = TextBox1.Value

	'タスクのチャートを反映
	'背景色と□の反映
	Range(Cells(n, CInt(Replace(ComboBox1, "月", "")) + 1), Cells(n, CInt(Replace(ComboBox2, "月", "")) + 1)).Interior.ColorIndex = 3
	Range(Cells(n, CInt(Replace(ComboBox1, "月", "")) + 1), Cells(n, CInt(Replace(ComboBox2, "月", "")) + 1)).Value = "□"

End Sub

Comments

[webillion]

具体的なコードを示していただき、ありがとうございます。非常に勉強になりました。

Answer 3

CInt(Replace(ComboBox1.Text, "月", ""))

等の部分でComboBox1.TextがNULLなのでは？