Excel 相対参照で文字列に+1したいです。

Question

お疲れ様です。
Takkoです。

現在Excelを使用して試験用データを作成することとなり、
約9万件のテストデータを作成することとなりました。

そこで尋ねたいことがありまして、
ご教授いただければと思います。

今回、作成するデータは全件違う内容になるようにという前提で、
A1sell ,B1sell
試験００００１データ,0001
試験００００１データ,0002
試験００００１データ,0003
試験００００２データ,0001
試験００００２データ,0002
試験００００２データ,0003
試験００００３データ,0001
試験００００３データ,0002
試験００００３データ,0003

・
・
・
・
試験３００００データ,1001
試験３００００データ,1002
試験３００００データ,1003

となるようにデータを作成したいと考えています。
また試験に使用するA1sellの数字は全角数字となります。

b1sellの方は、c1sellに計算用の数値1000を入力し、
それぞれ
= c1 + 1
= c1 + 2
= c1 + 3
とし、相対参照で下に計算式を引っ張って作成することが出来たのですが、
Asellのデータがどうにもうまくいきませんで、困っています。
d1sellに計算用全角数字'００００１を入力し、
= "試験" & D1 & "データ"
= "試験" & D1 & "データ"
= "試験" & D1 & "データ"
= "試験" & D1 + １ & "データ"
= "試験" & D1 + １ & "データ"
= "試験" & D1 + １ & "データ"

と言う風に4行目以降も作成したいのですが、
どうすればよろしいでしょうか。

お願いします。

追記
'００００１とすることで、セル上の表記が１になることを避けているのですが、
これを行うと+1の計算が出来ないです。

'をはずすと計算は出来ますが、試験１データとなってしまいます。

Answer 1

A1セルに以下の関数式を入れてください。
="試験" & JIS(TEXT(INT((CELL("row",A1)-1)/3)+1,"00000")) & "データ"

A1セルを選択して、コピーしてください。

A2セルからA90000セルまで(89999個のセル）を選択して、貼り付けてください。

そうすれば、A列には希望するような文字列が表示されるはずです。
多くの関数式を含むセルを残しておくと動作が遅くなるので（再計算を初めてしまう為）、A1セルからA90000セルまでを選択して、コピーし、値で貼り付けしてください。

＝＝
関数式についての解説（ネストの深いところから順に説明します）
CELL("row",A1)
A1セルの行番号をCELL("row",A1)で調べています。A1セルなら１、A2セルなら2、A3セルなら3というように行番号が返されます。

INT((CELL("row",A1)-1)/3)+1
３行ごとに試験の番号を変えるので、３で割った行番号を使いたいところですが、３で割って整数化すると、1,2,3が0,0,1になりますから、３で割る前に行番号を１つ減らし、1,2,3行目が0に、4,5,6が1になるようにしてから、1を加えました。

TEXT(INT((CELL("row",A1)-1)/3)+1,"00000")
試験番号は先頭に0を付け加えて５桁で表現する形式ですから、そうなるようにTEXT関数を使っています。

"試験" & JIS(TEXT(INT((CELL("row",A1)-1)/3)+1,"00000")) & "データ"
tukurokuさんの回答にあるJIS関数を使って試験番号を全角文字に変換し、前に"試験"、後ろに"データ"を文字列をつなぐ演算子 & で付けるようにして出来上がりました。

追伸：
B列については、最初の９行は0001,0002,0003の繰り返しですが、最後の3行は1001,1002,1003になっていて、どのようなルールで値を変えているのか判りませんでした。
ルールが判れば、それに合うような関数式を書くことは可能だと思います。

Answer 2

ROW()関数でセルの行を利用します。
１行目からの前提なので、２行目以降から開始する場合は調整して下さい。

A1="試験" & JIS(TEXT(INT((ROW()+2)/3),"00000")) &"データ"
B1=TEXT(MOD(ROW()-1,3)+1,"0000")

※先頭はセルの場所を示しています。=以降をそのセルに設定して下さい。
相対参照はしていないので、オートフィルでもコピーでも大丈夫です。

Answer 3

D列の値は「半角で入力」し、参照するセルではTEXT関数でゼロパディングした後、JIS関数を用いて全角に変換します。

A	...	D
= "試験" & JIS(TEXT(D1,"000000"))	...	1
= "試験" & JIS(TEXT(D1+1,"000000"))	...

参考サイト
半角->全角
ゼロパディング