Excel重複データのチェック

Question

エクセルで特定の列のセルにデータを入力した時に、同じ列内に重複データがある場合、
重複データの行の色を変えて、更に可能であれば、アラートで「●個目の重複データです」と表示させたいのですが、実現できなくて悩んでおります。

条件付き書式を使ったのですが、行全体の色を変えれませんでした。

もし解決策などございましたら、ご教示いただければと思います。

①

↓
メールアドレスの[e-mail]を入力した瞬間に色が変わって、アラートで「●個目の重複データです」と表示

↓

②既に重複データがあるデータを登録する場合も同じ挙動

↓

Answer 1

条件付き書式設定で対処できます。

条件書式設定で、「式を使用して、書式設定するセルを決定」を選択し、
下の様な式を入れれば、可能です。

Comments

[jal0994]

ご回答いただきありがとうございます。
期待する動きとしては、重複データがあった場合、データを入力しているセルだけでなく、行全体の色を変えたいという事でした。
こちらの方法も参考にさせていただきます！
ありがとうございます！

Answer 2

ご要望の機能は関数だけでは難しいと思いますので、プログラムを作成しました。

これを使用すれば、ご要望の機能が実装されます。

[使いかた]
ご要望の機能が欲しいブックを開いた状態で、Alt + F11 キーを押下。
以下の画面が開きます。

左側の「プロジェクト -VBAProject」と記載されたところにて、ご要望の機能の機能を実装したいシートをダブルクリックします。
その後、右側のテキストエディタに下記のソースコードを貼り付けます。

ソースコード中に
「【TODO】 重複チェックを実施したい範囲に変更して下さい」
と記載された箇所がありますので、これはご自身の機能を実装したい列などを指定して下さい。

※わからないことがあれば引き続きコメント頂けたら回答させて頂きます。

' 変数宣言を強制(バグ防止のため)
Option Explicit

' 指定したセルの重複チェック(この関数はセルの値が変更される度に発火)
Private Sub Worksheet_Change(ByVal target As Range)
    
    ' 定数宣言
    ' 【TODO】 重複チェックを実施したい範囲に変更して下さい
    ' 例)B列の重複チェックをしたい場合は"B:B"
    Const TARGET_RANGE As String = "B:B"
    
    ' 変数宣言
    Dim vars As Range
    Dim var As Range
    Dim counter As Long
    Dim i As Long
    
    ' 変更されたセルが重複データチェック対象でない場合は処理終了
    If Intersect(target, Range(TARGET_RANGE)) Is Nothing Then
        Exit Sub
    End If
    
    ' チェック対象行を取得
    Set vars = Intersect(Columns(target.Column), Range(TARGET_RANGE))
    
    ' 重複データ数を初期化
    counter = 0
    
    ' 重複チェック対象を走査
    For i = vars.Cells(1).Row To GetLastRow(target)
        With vars.Cells(i, 1)
            If target.Text = .Text And target.Address <> .Address Then
                counter = counter + 1
                Rows(.Row).Interior.ColorIndex = 40
            End If
        End With
    Next
    
    ' 変更したセルの色を最新化
    If counter = 0 Then
        Rows(target.Row).Interior.ColorIndex = False
    Else
        counter = counter + 1
        Rows(target.Row).Interior.ColorIndex = 40
    End If
    
    ' メッセージ出力
    If counter <> 0 Then
        MsgBox counter & "個目の重複データです", vbExclamation + vbOKOnly, "警告"
    End If
        
End Sub

' 最終行取得
Private Function GetLastRow(ByRef pRange As Range) As Long
    GetLastRow = Cells(Columns(pRange.Column).Rows.Count, pRange.Column).End(xlUp).Row
End Function

Comments

[jal0994]

連絡が遅れてしまい、申し訳ございません。
細かくプログラムを作成していただき、本当にありがとうございます。
やはり実現させるにはプログラムを組むしかないんですね。
記載していただいたプログラムで期待どおりの動きができたんで本当に助かりました！
また機会がありましたら、ご教示いただければと思います。

Answer 3

課題：　　　　異常な値を入力させたくない（何個目かの重複かを知らせられれば、重複をなくせるのでは？的なことでしょうか）
解決策（案）：色を変えて目立つようにしてユーザーのポカヨケをしたい
ということでしょうか？

・解決策
解決方法は少し異なりますが、入力規則+Countifで対応できると思います。

重複登録をしようと（入力規則を違反）する場合、そもそも値を更新することすらできないため、ポカヨケとしてはこれだけで十分だと思います。参考までに、色を変える方法では、ユーザーに気づかせるのみで、気づかないリスクまでは排除しきれません。

---

もし、色を変えるやりかたをするのであれば、隣の列に「先頭行～対象の行」までの範囲に対してcountifを実施、その行に条件付き書式で2以上の整数であれば色を変える、のような処理が必要になりますね。

Comments

[jal0994]

連絡が遅れてしまい申し訳ございません。
課題としては、重複データは入力可能にして、重複データを入力した瞬間に、「〇個目の重複データです」とアラート表示させて、重複データの行全体の色を変える事を目的としていました。
baseballyama様から回答いただいた様に、プログラムを組んで実行するしかないようなので、プログラミンを組んで解決したいと思います。
回答いただき、ありがとうございました。