不規則なデータファイルをコマンドラインでcsvファイルに整形したいです。どなたか教えていただけないでしょうか？

こういうのはどうでしょう。今、ちょっと忙しいので、書きっぱなしでろくに検証していませんが。

BEGIN {
    no_of_fields = split("名前,年齢,住所,電話", keys, ",");
    for (i = 1; i <= no_of_fields; i++) {
        key2index[keys[i]] = i;
    }
    line = "";
    for (i = 1; i <= no_of_fields; i++) {
        line = line "," keys[i];
    }
    print substr(line, 2);
}

{
    key = $1;
    idx = key2index[key];
    val = $2;
}

{
    if (fields[idx] != "") {
        flush();
    }
    fields[idx] = val;
    vals++;
}

END {
    if (vals > 0) {
        flush();
    }
}

function flush() {
    line = "";
    for (i = 1; i <= no_of_fields; i++) {
        line = line "," fields[i];
        fields[i] = "";
    }
    print substr(line, 2);
    vals = 0;
}

実行は次のように。

$ sed -e 's/^\s\+//g' -e 's/[\s:=＝]/ /g' sample1.txt | awk -f pretify.awk
名前,年齢,住所,電話
あ,,住所あ,電話あ
い,年齢い,,※※
う,年齢う,住所う,電話う
ほげほげ,,住所え,電話え
名前お,年齢お,住所お,電話お

根本的な問題として、レコードを区別する基準が不明瞭のようです。

名前 ほげほげ
住所=住所え
            電話 電話え
名前＝名前お
電話 電話お

これは１件としますか？２件としますか？
上記のgrepの処理では、名前ー住所その他の対応関係をつけることが全くできないように思います。

ご提示の例とお答えと同じになる様にはしてみました。

echo 名前,年齢,住所,電話
sed -e"s/^[ \t]*//" -e"s/\t/ /g" -e"s/[=＝:]/ /" sample1.txt |
awk '{if($1 in v){printf"%s,%s,%s,%s\n",v["名前"],v["年齢"],v["住所"],v["電話"];delete v;}v[$1]=$2}END{printf"%s,%s,%s,%s\n",v["名前"],v["年齢"],v["住所"],v["電話"]}'

フローとしては以下のような感じでしょうか。

（１）先頭の不要スペースを削除する
（２）区切り文字を統一する
（３）空行から空行までを一まとまりとして処理
ハッシュを利用し、ヘッダ名称と値をそれぞれ格納
一まとまりが終わるまで上記を実施

ヘッダ順にカンマを挿入しながら出力

年齢 年齢う

名前 う
住所:住所う
電話 電話う

残念ながら上記がうまく処理できません。
これはヘッダが全て存在しているという過程が成り立てば処理ができますが、そうでない場合、どのように一まとまりと判断するか適切に判断できないためです。

名前 ほげほげ
住所=住所え
            電話 電話え
名前＝名前お
電話 電話お

年齢 年齢お
住所 住所お

こちらもKojiDoiさんが指摘の通りです。
先の問題は、名前がない場合は次の塊も同じブロックと判断するとか、あるかもしれませんが、次の問題は次のブロックと判断したいところですが、先の問題との兼ね合いでうまく両者を同じように処理できないと思われます。

まとめると、ヘッダが全てあるわけではなく、その順番も決まっていないため、一つのブロックとして扱うべきデータの分離ができないことです。
何かしらそれができる方法、ルールが必要で、それを上記のステップのいずれかに入れる必要があります。基本的には（３）になります。