DataGridViewでの定数項目の編集時表示切替について

Question

###前提・実現したいこと
vb.netにおけるDataGridViewでの定数項目（0:なし、1:ありといった項目）について、
セル編集時には定数を表示し、編集完了後は名称で表示する動作を実現したいと考えています。
（フォーカスが当たっていないときは「あり」と表示され、
ダブルクリック等で編集を開始すると値が「1」になるイメージです。）

下記の質問を参考にCellFormattingイベントを利用し、定数→名称の変換は実現できたのですが、
編集開始時の名称→定数の変換の実現方法がわからず困っています。

※関連する質問
DataGridViewに入っている値に応じて表示を変更したい
https://teratail.com/questions/71977

CellBeginEventで値を置き換えようと試みたのですが、
直後にCellFormattingイベントが走るため、値が上書きされてしまうようです。
そもそもCellFormattingイベントで値を設定した際には
表示名のみ書き換わり、DataSourceの値は不変であると理解しているのですが、、、
編集開始時に定数値を表示することはできないのでしょうか？

###該当のソースコード（イメージ）

    'CellFormattingイベント
    '編集終了後は定数を名称に変換して表示
    Private Sub DataGridView_CellFormatting(ByVal sender As Object, _
    ByVal e As DataGridViewCellFormattingEventArgs) Handles DataGridView.CellFormatting
        e.Value = "あり"
    End Sub
        
    'CellBeginEditイベント
    'セル編集時は名称を定数に変換する
    Private Sub DataGridView_CellBeginEdit(ByVal sender As Object, _
     ByVal e As DataGridViewCellCancelEventArgs) Handles DataGridView.CellBeginEdit
        DataGridView.CurrentCell.Value = "1"
    End Sub

Answer 1

DataGridViewComboBoxColumn のほうがすっきりするような気はしますが、別解として値を管理するためのクラスを用意する方法です。

まず、「0が"なし"／1が"あり"」というのを管理するためのクラス MyType を用意します。
（名前は別に MyType でなくても構いませんが）
このクラスには、以下のものを実装します。

• 値の候補を定義する列挙型 Options
• 値そのもののためのプロパティ Value
• メソッド ToString() のオーバーライド
• 文字列から MyType に変換するためのメソッド Parse

Public Class MyType

    Public Enum Options
        なし = 0
        あり = 1
    End Enum

    Private _Value As Integer
    Public Property Value As Object
        Get
            Return _Value
        End Get
        Set(value As Object)
            If value = Nothing Then Return
            If TypeOf value Is Integer Then
                _Value = CType(value, Integer)
            ElseIf TypeOf value Is String Then
                Integer.TryParse(CType(value, String), _Value)
            Else
                Integer.TryParse(value.ToString(), _Value)
            End If
            If _Value <> Options.なし Then
                _Value = Options.あり
            End If
        End Set
    End Property

    Public Overrides Function ToString() As String
        If _Value = Options.なし Then
            Return Options.なし.ToString()
        Else
            Return Options.あり.ToString()
        End If
    End Function

    Public Shared Function Parse(input As String) As MyType
        Dim instance = New MyType()
        Dim v As Integer
        If Integer.TryParse(input, v) Then
            instance.Value = v
        Else
            If input = Options.なし.ToString() Then
                instance.Value = Options.なし
            Else
                instance.Value = Options.あり
            End If
        End If
        Return instance
    End Function

End Class

次に、フォーム上の DataGridView に対して以下のように修正します。

1. 列の ValueType を MyType にする
2. DataGridView の EditingControlShowing イベントを適宜処理する

' Form1 に DataGridView1 があり、そこに列 Column1 があるものと想定しています。
' 名称が異なる場合は適宜読み替えてください。

Public Class Form1

    Public Sub New()
        ' この呼び出しはデザイナーで必要です。
        InitializeComponent()

        ' InitializeComponent() 呼び出しの後で初期化を追加します。
        ' 1. 列の `ValueType` を `MyType` にする
        Column1.ValueType = GetType(MyType)
    End Sub

    ' 2. `DataGridView` の `EditingControlShowing` イベントを適宜処理する
    Private Sub DataGridView1_EditingControlShowing(sender As Object, e As DataGridViewEditingControlShowingEventArgs) Handles DataGridView1.EditingControlShowing
        Dim editingTextBox As TextBox = Nothing
        If TypeOf e.Control Is TextBox Then
            editingTextBox = CType(e.Control, TextBox)
        End If
        If editingTextBox IsNot Nothing AndAlso DataGridView1.CurrentCell.OwningColumn Is Column1 Then
            ' 現在のセルの値をもとに、EditingControlに適切な文字列をセットする
            Dim currentCellText = DataGridView1.CurrentCell.Value?.ToString()
            If String.IsNullOrEmpty(currentCellText) Then
                editingTextBox.Text = String.Empty
            ElseIf currentCellText = MyType.Options.なし.ToString() Then
                editingTextBox.Text = CType(MyType.Options.なし, Integer).ToString()
            Else
                editingTextBox.Text = CType(MyType.Options.あり, Integer).ToString()
            End If
        End If
    End Sub

Comments

[h_dog]

結局、CellFormattingイベントに以下の記述を追記することで凌ぎました。

'/ 編集時は何もしない
If DataGridView.CurrentCell.IsInEditMode = True Then
Exit Sub
End If

問題があれば頂いた情報をもとにコードを見直してみます。
丁寧な解説ありがとうございました。

[alg]

ご自身のやり方で問題が解決した場合は、無理にベストアンサーを選ばずに、ご自身の回答をつけて自己解決という形にしたほうがいいですよ。

[h_dog]

ご指摘ありがとうございます。次回よりそのように致します。

Answer 2

DataGridViewで定数項目列ならDataGridViewComboBoxColumnの方がユーザビリティ高くないですか？

Comments

[alg]

`DataGridViewComboBoxColumn` に `DataSource` を指定して、表示は文字列で"0:なし"or"1:あり"／値は0or1 とすれば、入力時に押すキーも0か1のどちらかだけで済みますしね。

[h_dog]

おっしゃる通りなのですが、上記のような動作を望む声がありまして。。。
DataGridViewComboBoxColumnでの実装も検討してみます。
ありがとうございました。