vbaでのオブジェクト指向について

Question

エクセルのvbaで1つのCSVデータを基に、「営業所別」「営業別」、「得意先別」,etc
の帳票を出力する処理を組もうかと考えています。
この案件にあたり、今までのmoduleのみの手続き型での実装から、オブジェクト指向での
プログラムをやってみようと思い立ちました。

いくつかサイトを参考にして作ろうとしているのですが、クラスの生成から
つまずいてしまっています。
クラスにworksheetオブジェクトを持たせたいのですが、下記のエラーが出ます。
「コンパイルエラー：
オブジェクトモジュールにはインターフェース'WS'用の'absClass'が必要です」

string型などでは上手くいったので、オブジェクトを持たせる場合に何か方法があるのかと思いますが、ググっても上手く出てきませんでした。
最悪、シート名だけ持たせてmodule側で処理してもいいのですが、他に便利な方法があれば試してみたいです。

'スーパークラス：absClass.cls

Option Explicit

'プロパティ
Public WS As Worksheet

Public Sub msgName(vdata As Worksheet)
End Sub

'サブクラス：centerToMonth.cls

Option Explicit
'---コンパイルエラー：
'---オブジェクトモジュールにはインターフェース'WS'用の'absClass'が必要です。
Implements absClass

'プロパティ
Private WS As Worksheet

Private Property Get absClass_WS() As WorkSheet
    absClass_WS = WS
End Property
Private Property Let absClass_WS(ByVal RHS As WorkSheet)
    WS = RHS
End Property

Private Sub absClass_msgName(vdata As Worksheet)
    Debug.Print vdata.name
End Sub

'module.bas

Sub test()
    Dim objabs As absClass
    Dim objcon As centerToMonth
    
    Set objcon = New centerToMonth
    Set objabs = objcon

    With objabs
        MsgBox .WS
        
        'MsgBox ActiveWorkbook.Worksheets("営業所別売上修正一覧表（月間）").name
        .WS = ActiveWorkbook.Worksheets("営業所別売上修正一覧表（月間）")
        .msgName
    End With
End Sub

参考：https://sites.google.com/site/compositiosystemae/home/vbaworld/upper/interface

以上、ご教授いただければと思います。
よろしくお願い致します。

Answer 1

VBA でのスーパークラスには、必要なプロパティ、メソッドすべてのインターフェイスが必要になるとのことです。
参考

これをもとに、提示されたクラス、モジュールを以下のように変更してみました。

(1) absClass

'スーパークラス：absClass.cls

Option Explicit

'プロパティ
'Public WS As Worksheet

'' プロパティのインターフェイスを用意する。
Public Property Get WS() As Worksheet
End Property

'' オブジェクトの場合は、Let ではなく Set
Public Property Set WS(ByVal RHS As Worksheet)
End Property

Public Sub msgName(vdata As Worksheet)
End Sub

(2) centerToMonth

'サブクラス：centerToMonth.cls

Option Explicit
'---コンパイルエラー：
'---オブジェクトモジュールにはインターフェース'WS'用の'absClass'が必要です。
'' -> WS オブジェクトの「プロパティ」のインターフェイスがないので、出てきて当然のエラーです。

Implements absClass

'' クラス内で保有数 WS の宣言。
'プロパティ
Private WS As Worksheet

'' プロパティの実装
'' それぞれ、オブジェクトなので set する。
Public Property Get absClass_WS() As Worksheet
    Set absClass_WS = WS
End Property
Public Property Set absClass_WS(ByVal RHS As Worksheet)
    Set WS = RHS
End Property

Public Sub absClass_msgName(vdata As Worksheet)
    Debug.Print vdata.Name
End Sub

(3) Module1

Option Explicit

'module.bas

Sub test()

    ' スーパークラスで宣言したあと、派生クラスで New する。
    Dim objabs As absClass
    'Dim objcon As centerToMonth
    Set objabs = New centerToMonth
    'Set objabs = objcon

    With objabs
        'MsgBox .WS
        'MsgBox ActiveWorkbook.Worksheets("営業所別売上修正一覧表（月間）").name
        Set .WS = ActiveWorkbook.Worksheets("営業所別売上修正一覧表（月間）")
        .msgName .WS
        
    End With
End Sub

Excel 2013 では動作しました。
以上、ご参考になれば幸いです。

Comments

[K.T_build]

ありがとうございます。
頂いたプログラムで動作できました。
オブジェクトをクラスに実装する場合は、スーパークラスにインターフェースを宣言する必要があるのですね。
勉強になりました。

Answer 2

'プロパティ
Private WS As Worksheet

Private Property Get absClass_WS() As String
    absClass_WS = WS
End Property
Private Property Let absClass_WS(ByVal RHS As String)
    WS = RHS
End Property

「Get absClass_WS() As String」→「Get absClass_WS() As Worksheet」
「ByVal RHS As String」→「ByVal RHS As Worksheet」
ではないでしょうか？

■追記
StringをWorksheetに変更
LetをSetに変更

absClass

Option Explicit

'プロパティ
Public WS As Worksheet

Public Sub msgName(vdata As Worksheet)
End Sub

centerToMonth

Option Explicit
'---コンパイルエラー：
'---オブジェクトモジュールにはインターフェース'WS'用の'absClass'が必要です。
Implements absClass

'プロパティ
Private WS As Worksheet

Private Property Get absClass_WS() As Worksheet
    absClass_WS = WS
End Property
Private Property Set absClass_WS(ByVal RHS As Worksheet)
    WS = RHS
End Property

Private Sub absClass_msgName(vdata As Worksheet)
    Debug.Print vdata.Name
End Sub

Modules1

Sub test()
    Dim objabs As absClass
    Dim objcon As centerToMonth

    Set objcon = New centerToMonth
    Set objabs = objcon

    ''' このあたりはエラーになるのでコメントアウト
    With objabs
        'MsgBox .WS 

        'MsgBox ActiveWorkbook.Worksheets("営業所別売上修正一覧表（月間）").name
        '.WS = ActiveWorkbook.Worksheets("営業所別売上修正一覧表（月間）")
        '.msgName .WS
    End With
End Sub

Comments

[K.T_build]

回答ありがとうございます。
修正し、試してみましたが同様のエラーが発生しました。

[K.T_build]

頂いたご指摘を基に、再度質問文を修正いたしました。

[退会済みユーザー]

オブジェクトの場合はLetではなくSetを使うようです。これでどうでしょうか？
Private Property Let absClass_WS(ByVal RHS As WorkSheet)
↓
Private Property Set absClass_WS(ByVal RHS As WorkSheet)

[K.T_build]

Setで試してみましたが、こちらでも同様にエラーが発生しました。
試しにスーパークラス(absClass)からプロパティを抜いたら動作するようになりました。
原因は不明ですが、、、

[K.T_build]

試した操作説明があいまいすぎる回答だったので、再度回答します。
正）試しにabsClassから「Public WS As Worksheet」 をコメントアウトしたところ、正常に動作しました。

[退会済みユーザー]

当方では特にエラーなく動作しました。Excelのバージョンは2010です。
一応、動いたソースを追記します。