[VB.NET]Excelのタスクの消し方

Question

visual studio2012 でwindowsフォームアプリを作成します。
データグリッドビューのデータをExcelに出力するようにしています。
ですが、Excelを閉じてもタスクが残ってしまいます。
調べながら色々と試してみましたが、全然だめでした。
ソースは以下の通りです。

 '出力ボタン
    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
       
        Dim app As Excel.Application = Nothing
        Dim book As Excel.Workbook = Nothing
        Dim sheet As Excel.Worksheet = Nothing
        Dim books As Excel.Workbooks = Nothing

        Try
            'Excelを開く
            app = New Excel.Application()

            'Bookを開く
            books = app.Workbooks
            book = books.Open("C:\form3\Book1.xlsx")

            'シートの指定
            sheet = book.Worksheets(1)

            'Excelに出力する
            For i As Integer = 0 To DataGridView1.Rows.Count - 1
          sheet.Range("A" & i + 2 & "").Value = DataGridView1.Rows(i).Cells(1).Value
                sheet.Range("B" & i + 2 & "").Value = DataGridView1.Rows(i).Cells(4).Value
                sheet.Range("C" & i + 2 & "").Value = DataGridView1.Rows(i).Cells(5).Value
                sheet.Range("D" & i + 2 & "").Value = DataGridView1.Rows(i).Cells(6).Value
                sheet.Range("E" & i + 2 & "").Value = DataGridView1.Rows(i).Cells(7).Value
            Next

            'Excelの表示
            app.Visible = True

            '5秒だけ表示する
            System.Threading.Thread.Sleep(5000)

            '保存する
            book.Save()

            '閉じる
            app.Quit()

        Catch ex As Exception
            Throw ex

        Finally

            Marshal.ReleaseComObject(sheet)
            Marshal.ReleaseComObject(books)
            Marshal.ReleaseComObject(book)
            Marshal.ReleaseComObject(app)
            
        End Try

    End Sub

Comments

[sazi]

「Excelを閉じてもタスクが残ってしまいます。」 とありますが、ここでいう「タスク」って何ですか？

Answer 1

私はC#の方を書く事が多いので読み替えてもらえると助かるのですが。。。
以下のように、エクセルを開く場合以下のようにTry構文の階層を作って確実にリリースすることをお勧めします。

Microsoft.Office.Interop.Excel.Application();
try
{
    Workbooks workbooks = excelApplication.Workbooks;
    try
    {
        Workbook workbook = workbooks.Open("d:\\Book1.xlsx");
        try
        {
            Sheets worksheets = workbook.Sheets;
            try
            {
                Worksheet worksheet = worksheets[1];
                try
                {
          処理
                }
                finally { Marshal.ReleaseComObject(worksheet); }
            }
            finally { Marshal.ReleaseComObject(worksheets); }
        }
        finally
        {
            if (workbook != null)
            {
                workbook.Close(false);
            }
            Marshal.ReleaseComObject(workbook);
        }
    }
    finally { Marshal.ReleaseComObject(workbooks); }
}
finally
{
    if (excelApplication != null)
    {
        excelApplication.Quit();
    }
    Marshal.ReleaseComObject(excelApplication);
}

Comments

[reeeo]

ソースまでありがとうございます。
読み替えて試してみたところ
sheet = DirectCast(sheets(1), Excel.Worksheet)の箇所で
型 'System.__ComObject' の COM オブジェクトをインターフェイス型 'Microsoft.Office.Interop.Excel.Worksheets' にキャストできません。とエラーが出てしまいました。

[Yuki_S]

一番最初の
Dimの所のNothing消したらそのエラー消えないですかね？

[reeeo]

Nothingを消しても同じでした。。

[Yuki_S]

ちょっと考えます。他の原因思いついたらコメントさせていただきます！

[reeeo]

申し訳ございません。上記のエラーはデータ型が間違っていた為起きたエラーでした。
現状、for文をコメントアウトして動かしたところタスクは残らず正常に終了できていました。あと解放するのはrangeだけでよろしいのでしょうか？

[Yuki_S]

上記のFor内のrangeは値にアクセスするだけなので解放は恐らく不要かと思います。
うまくいかない様なら入れてあげてください。

[reeeo]

無事できました。また何かありましたらお願いします。

Answer 2

WorksheetsとRangeの解放が必要ですね。以下サンプルコードです。

'参照設定はCOM(Microsoft Excel 16.0 Object Library)ではなく
'.NETアセンブリ(Microsoft.Office.Interop.Excel)を使用。

Imports Microsoft.Office.Interop

Public Class Form1

    '自分で解放版
    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        Using coms As New ComStack
            Dim app As New Excel.Application : coms.Push(app)
            Dim books = app.Workbooks : coms.Push(books)
            Dim book = books.Open("C:\Users\(user)\Documents\Book1.xlsx") : coms.Push(book)
            Dim sheets = book.Worksheets : coms.Push(sheets)
            Dim sheet = DirectCast(sheets(1), Excel.Worksheet) : coms.Push(sheet)
            Dim range = sheet.Range("A1") : coms.Push(range) : range.Value = "abc"
            range = sheet.Range("B2") : coms.Push(range) : range.Value = "def"
            app.Visible = True
            System.Threading.Thread.Sleep(5000)
            book.Save()
            app.Quit()
        End Using
    End Sub

    'GCで解放版
    Private Sub Button2_Click(sender As Object, e As EventArgs) Handles Button2.Click
        DoExcelTask()
        GC.Collect()
        'メモ：Excel操作とGC.Collectは別プロシージャに書く。
    End Sub

    Private Sub DoExcelTask()
        Dim app As New Excel.Application
        Dim book = app.Workbooks.Open("C:\Users\(user)\Documents\Book1.xlsx")
        Dim sheet = DirectCast(book.Worksheets(1), Excel.Worksheet)
        sheet.Range("A1").Value = "abc"
        sheet.Range("B2").Value = "def"
        app.Visible = True
        System.Threading.Thread.Sleep(5000)
        book.Save()
        app.Quit()
    End Sub

End Class

'COM解放用ヘルパークラス
Class ComStack
    Inherits Stack(Of Object)
    Implements IDisposable

    Sub Dispose() Implements IDisposable.Dispose
        Do Until Count = 0
            System.Runtime.InteropServices.Marshal.ReleaseComObject(Pop())
        Loop
        GC.SuppressFinalize(Me)
    End Sub
End Class

Answer 3

'シートの指定

sheet = book.Worksheets(1)

Worksheets はメソッドではなくプロパティなので、変数で受けて開放する必要がありますね。

Comments

[reeeo]

回答ありがとうございます。
変数で
sheet = DirectCast(sheets(1), Excel.Worksheet)としたところ
型 'System.__ComObject' の COM オブジェクトをインターフェイス型 'Microsoft.Office.Interop.Excel.Worksheets' にキャストできません。とエラーが出てしまいました。

[hihijiji]

こんな感じで
Dim sheets As Sheets
sheets = book.Worksheets
sheet = sheets(1)
代入して
sheets も開放してください。

[reeeo]

Dim sheets As Excel.Worksheets = Nothing
sheets = book.Worksheets
sheet = sheets(1)
.
.
Marshal.ReleaseComObject(sheets)
とやってもだめでした。
Nothingは解放の箇所で波線が引かれてしまうので書きました。

[hihijiji]

Range オブジェクトも同様に解放する必要があるのかも知れませんね。
また、セキュリティソフトなどでリアルタイム監視している場合は、 book.Save() と app.Quit() の間にも適当にSleepをいれると解放されたなどの話を聞いたことがあります。

[reeeo]

とりあえずはRangeを使用している箇所はコメントアウトして実行しているのですが、使用していなくても解放しなくてはいけないのですか？？

[hihijiji]

使ってないものは解放できません。

Answer 4

app→books→book→sheetの順でアクセスしているのでリリースするのはこの逆の順でリリースする必要があります。

パッと見た感じ

Marshal.ReleaseComObject(***)

のbookとbooksが逆になっているので順番を変えてみてください。
またttyp03さんのリンクにあるようにリリース前にチェックをしておいた方がいいです。

Comments

[reeeo]

コメントありがとうございます。
順番を変えてもだめでした。
ちなみにsheetをコメントアウトして行ったところタスクはちゃんと閉じられていたのでsheetがおかしいんではないかと思いました。。。

[Yuki_S]

状況があまりわかりませんが、一度アプリを閉じる前にbook.close()でブック自体を閉じる処理を入れてみたらどうなりますかね？

Answer 5

環境がなくて試していませんが、処理の最後にオブジェクトを明示的に解放してみてはいかがでしょうか。

app = Nothing
book = Nothing
sheet = Nothing
books = Nothing

下記リンク先に似たような話があります。
詳しくは読んでないですし、結構古い話なので今とは違うかもしれませんが、参考まで。
https://qa.atmarkit.co.jp/q/1227

Comments

[reeeo]

コメントありがとうございます。
すいません。リンク先を読んでもあまりよく理解できませんでした。
ちなみにsheetをコメントアウトして行ったところタスクはちゃんと閉じられていたのでsheetがおかしいんではないかと思いました。。。

[ttyp03]

リンク先は回答のネタ元にした話なので、参考程度に見てもらえれば良いです。
要は全部のオブジェクトを解放しないとダメなんじゃないの、ってことを言いたいだけです。
Yuki_Sさんの回答にあるように、解放の順番は考慮しないとダメかもしれないですね。