オブジェクトが奥の位置になるに連れ、Bloomによる滲みが弱くなってしまう。手前と均一にできないか？

Question

自作のゲームの中で、直線（四角ポリゴン）を使って部屋の中を表現しています。
Bloom And Flaresを使用して、直線を滲ませてみました。
しかし、画像をみていただけるとおわかりになると思いますが、
手前から奥に行くにつれ、滲みが弱くなってしまいます。
奥の方ではもはや滲みがみられません。
しっかり奥の方でも滲みが出るように、滲みを均一にするにはどうしたら良いのでしょうか。
Bloomの設定の問題でしょうか？
お分かりになる方がいらっしゃいましたら、アドバイスをいただけると幸いです。
以下の画像はそれぞれ、
・現在のゲーム画面
・直線に設定しているマテリアル
・カメラに設定しているBloom and Flaresの設定
です。よろしくお願いいたします。

Answer 1

ちょっと見た感じ、Bloom And Flares側の設定ではだめかもしれませんね...
おそらくBloom And Flaresは「レンダリングされた画像の高輝度部分を抽出」→「高輝度部分画像をぼかす」→「元の画像と合成する」といった手順を取っているかと思いますので、遠くの線は画面内に占める面積が小さくて、光彩の出方も小さくなっているものと思われます。

そこで、「カメラから遠くにあるピクセルほどEmissionが増幅されるサーフェイスシェーダー」を作って、線のマテリアルのShaderをStandardの代わりにそれに差し替えてみる、というのはどうでしょう。これなら遠くの線はより強く発光し、光彩のサイズも大きくなるかと思います。

例えばこんな感じでいかがでしょう?

Shader "Custom/EnhanceEmission" { // 名前はお好みのものを付けてください
	Properties {
		_Color ("Color", Color) = (1,1,1,1)
		_MainTex ("Albedo (RGB)", 2D) = "white" {}
		_Glossiness ("Smoothness", Range(0,1)) = 0.5
		_Metallic ("Metallic", Range(0,1)) = 0.0
		[HDR] _EmissionColor ("Emission Color", Color) = (0,0,0) // 追加
		_EmissionMap ("Emission", 2D) = "white" {} // 追加
		_EmissionExponent ("Emission Exponent", Float) = 1.0 // 追加
	}
	SubShader {
		Tags { "RenderType"="Opaque" }
		LOD 200
		
		CGPROGRAM
		// Physically based Standard lighting model, and enable shadows on all light types
		#pragma surface surf Standard fullforwardshadows

		// Use shader model 3.0 target, to get nicer looking lighting
		#pragma target 3.0

		sampler2D _MainTex;
		sampler2D _EmissionMap; // 追加

		struct Input {
			float2 uv_MainTex;
			float4 screenPos; // 追加
		};

		half _Glossiness;
		half _Metallic;
		fixed4 _Color;
		half4 _EmissionColor; // 追加
		float _EmissionExponent; // 追加

		// Add instancing support for this shader. You need to check 'Enable Instancing' on materials that use the shader.
		// See https://docs.unity3d.com/Manual/GPUInstancing.html for more information about instancing.
		// #pragma instancing_options assumeuniformscaling
		UNITY_INSTANCING_CBUFFER_START(Props)
			// put more per-instance properties here
		UNITY_INSTANCING_CBUFFER_END

		void surf (Input IN, inout SurfaceOutputStandard o) {
			// Albedo comes from a texture tinted by color
			fixed4 c = tex2D (_MainTex, IN.uv_MainTex) * _Color;
			half3 e = tex2D (_EmissionMap, IN.uv_MainTex).rgb * _EmissionColor.rgb; // 追加
			o.Albedo = c.rgb;
			// Metallic and smoothness come from slider variables
			o.Metallic = _Metallic;
			o.Smoothness = _Glossiness;
			o.Alpha = c.a;
			o.Emission = e * pow (max (IN.screenPos.w, 1.0), _EmissionExponent); // 追加...screenPos.wには縮尺率、つまりカメラ座標系でのz成分が入っているはずなので、これをかけてみる
			                                                                   // 一応、maxを使って1倍未満にならないようにしています
			                                                                   // さらに係数を_EmissionExponent乗するようにして、距離による増幅の効き方をいくらか調節できるようにしてみました
		}
		ENDCG
	}
	FallBack "Diffuse"
}

Comments

[Ray_pub]

御返事が遅くなって申し訳ありません。
ありがとうございます。遠くの線もはっきり見えるようになりました。
少しぼかしが強すぎるので、調整する方法を教えていただけないでしょうか。
シェーダーに関して全くの素人なので、愚問かもしれません。申し訳ないのですが、よろしくお願いします。

[Bongo]

いえいえ、おかまいなく。
今回試作したものの場合だと、「Emission Exponent」を大きくするほど遠くのものの発光が強まります。例えば0で増幅なし、0.5で距離の平方根に比例、1で距離に比例、2で距離の2乗に比例...といった具合です。初期値を1にしましたが、遠くのものが光りすぎているようでしたら、0.75〜0.25ぐらいに下げてみてください。また、Emissionが増幅される都合上、元々の「Emission Color」の輝度をすこし下げるとバランスが取れるかもしれません。
ぼかし幅自体の調節はBloom And Flares側の「Blur spread」をいじることで全体的に調整することになるでしょう。