zipを解凍してxmlを修正するPGM

Question

zipファイルの中にあるxmlの特定のタグの値を修正するPGMを作りたいです。
下記がサンプルになります。abc.zipにabc.xmlがあり、「test1です」を「テスト１です」に書き換えたいです。
どのような言語でどうコーディングするのが楽でしょうか
端末上で動作されるイメージなのでVBAかパワーシェルかVbscriptあたりで考えています。
vbaで調べてみると泥くさいことをしないといけない感じでした。(①zip解凍,②xml修正)
サンプルを提示して頂けますと助かります。

abc.zip
abc.xml

<?xml version="1.0" encoding="UTF-8"?>

 <test>
<test1>test1です</test1>
<test2>test2です</test2>
 </test>

-------------------------------①zip解凍--------------------------------
Public Sub UnZipFile(ByVal SrcPath As Variant, _
Optional ByVal DestFolderPath As Variant = "")
'ZIPファイルを解凍
'SrcPath：元ファイル
'DestFolderPath：出力先、指定しない場合は元ファイルと同じ場所
'※出力先に同名ファイルがあった場合はユーザー判断で処理
With CreateObject("Scripting.FileSystemObject")
If .FileExists(SrcPath) = False Then Exit Sub
If LCase(.GetExtensionName(SrcPath)) <> "zip" Then Exit Sub
If IsFolder(DestFolderPath) = False Then
DestFolderPath = .GetFile(SrcPath).ParentFolder.Path
End If
End With

With CreateObject("Shell.Application")
.NameSpace(DestFolderPath).CopyHere .NameSpace(SrcPath).Items
End With
End Sub

Private Function IsFolder(ByVal SrcPath As String) As Boolean
IsFolder = CreateObject("Scripting.FileSystemObject").FolderExists(SrcPath)
End Function

Private Function IsFile(ByVal SrcPath As String) As Boolean
IsFile = CreateObject("Scripting.FileSystemObject").FileExists(SrcPath)
End Function

Private Function AddPathSeparator(ByVal SrcPath As String) As String
If Right(SrcPath, 1) <> ChrW(92) Then SrcPath = SrcPath & ChrW(92)
AddPathSeparator = SrcPath
End Function
-------------------------------②xml修正--------------------------------
Sub loadXml()
Dim xD As New MSXML2.DOMDocument60

' ファイルから読み込み
xD.Load "D:\test.xml"

' 値取得方法1
Debug.Print "Test Case 1"
Debug.Print xD.DocumentElement.SelectSingleNode("test1").Text
Debug.Print vbCrLf
↑修正のやり方がわかりません。。。。。。。。。。

End Sub

Answer 1

どの部分が泥臭いのか、よくわかりませんが、
ZIPファイルの解凍のその方法は、サポート対象外ですのでうまくいかない場合があります。

CopyHere メソッドから Zip ファイルを処理することはできません

UNZIP32.DLL, 7-zip32.DLL等の外部のライブラリを使う方がいいでしょう。

7-zip32.DLLを利用してZIPファイルの作成と解凍 - hatena chips

XMLの読み込み、書き込みについては下記のコードをご参考に。
VBAのコードです。
要参照設定 Microsoft XML, v6.0

Sub loadXml()
    Dim xD As New MSXML2.DOMDocument60
    Dim xN As MSXML2.IXMLDOMNode
    
    ' ファイルから読み込み
    xD.Load "c:\test\abc.xml"

    'test1ノードの取得
    Set xN = xD.DocumentElement.SelectSingleNode("test1")
    'test1ノードの書き換え
    xN.Text = Replace(xN.Text, "test1です", "テスト１です")

    Set xN = xD.DocumentElement.SelectSingleNode("test2")
    xN.Text = Replace(xN.Text, "test2です", "テスト２です")

    'ファイルに上書き
    xD.Save "c:\test\abc.xml"
    
    Set xN = Nothing
    Set xD = Nothing
End Sub