コマンドライン引数に渡したファイル名から特定文字列を取り出す

Question

現在、７Zipを利用して、ZIPファイルなどの圧縮してほしくないファイルを除いて圧縮するバッチファイルを実現しようとしています。

その中で、圧縮したいフォルダ名をコマンドライン引数として渡した時、そのフォルダ名はそのままで、拡張子が.zipのファイルを出力したい、といったときの挙動を考えているのですが、思うような動きをしてくれません。
どのような点で間違えているのか、お教えいただけないでしょうか？

目指す動き↓

PS D:\WorkPractice> 7zipper .\bincount\                                   
圧縮後ファイル名入力...（省略可）test                                                    
パスワード入力...（省略可）                                                           
圧縮方法:拡張子...（デフォルト:zip）                                                    
                                                                          
7-Zip [64] 9.38 beta  Copyright (c) 1999-2014 Igor Pavlov  2015-01-03 
                 ～～～～～～中略～～～～～～～
PS D:\WorkPractice> ls                                                    
                                                                          
                                                                          
    ディレクトリ: D:\WorkPractice                                               
                                                                          
                                                                          
Mode                LastWriteTime         Length Name                     
----                -------------         ------ ----                     
d-----       2016/09/06     18:38                bincount                 
-a----       2017/07/13     19:14          50117 test.zip            

現状１（圧縮後ファイル名を入力しても反映されない）↓

PS D:\WorkPractice> 7zipper .\bincount\                                   
圧縮後ファイル名入力...（省略可）test                                                    
パスワード入力...（省略可）                                                           
圧縮方法:拡張子...（デフォルト:zip）                                                    
                                                                          
7-Zip [64] 9.38 beta  Copyright (c) 1999-2014 Igor Pavlov  2015-01-03 
                 ～～～～～～中略～～～～～～～
PS D:\WorkPractice> ls                                                    
                                                                          
                                                                          
    ディレクトリ: D:\WorkPractice                                               
                                                                          
                                                                          
Mode                LastWriteTime         Length Name                     
----                -------------         ------ ----                     
d-----       2016/09/06     18:38                bincount                 
-a----       2017/07/13     19:14          50117 .bincount.zip            

現状2（圧縮後ファイル名を省略したときも、不要な'.'が残る：消し方がわからない）↓

PS D:\WorkPractice> 7zipper .\bincount\                                   
圧縮後ファイル名入力...（省略可）                                                   
パスワード入力...（省略可）                                                           
圧縮方法:拡張子...（デフォルト:zip）                                                    
                                                                          
7-Zip [64] 9.38 beta  Copyright (c) 1999-2014 Igor Pavlov  2015-01-03 
                 ～～～～～～中略～～～～～～～
PS D:\WorkPractice> ls                                                    
                                                                          
                                                                          
    ディレクトリ: D:\WorkPractice                                               
                                                                          
                                                                          
Mode                LastWriteTime         Length Name                     
----                -------------         ------ ----                     
d-----       2016/09/06     18:38                bincount                 
-a----       2017/07/13     19:14          50117 .bincount.zip            

ファイルは、以下のようになります

@echo off

set PASSWORD=
set RAWFNAME=
set COMPFNAME=
set COMPMODE=zip

if not "%1" == "" (
	set RAWFNAME=%1
) else (
	set /p RAWFNAME="対象ファイル入力..."
	if "%RAWFNAME%" == "" (
		echo bye!
		exit /B FALSE
	)
)

if not "%2" == "" (
	set COMPFNAME=%1
) else (
	set /p COMPFNAME="圧縮後ファイル名入力...（省略可）"
	if "%COMPFNAME%" == "" (
		set COMPFNAME=%RAWFNAME:\=%
	)
) 

set /p STDIN="パスワード入力...（省略可）"
if not "%STDIN%" == "" (
	set PASSWORD=-p%STDIN%
)

set /p COMPMODE="圧縮方法:拡張子...（デフォルト:zip）"

set COMPFNAME=%COMPFNAME%.%COMPMODE%
set COMPMODE=-t%COMPMODE%

rem echo "%RAWFNAME%"
rem echo "%COMPFNAME%"
rem echo "%COMPMODE%"
rem echo "%PASSWORD%"

rem ここで COMPMODE="-tzip"
rem        COMPFNAME="test.zip"
rem        RAWFNAME=".\src\"
rem        PASSWORD="-pPASS"
rem などとなっていると期待通りに動く

7z a %COMPMODE% %COMPFNAME% %RAWFNAME% %PASSWORD% -xr!*7z -xr!*zip -xr!*BAK

set COMPFNAME=%RAWFNAME:.=%
set COMPFNAME=%RAWFNAME:¥=%

を試してみたりもしたのですが、¥=.zip というファイルができる結果となってしまいました。

Answer 1

遅延環境変数にかかわる問題と、単純な誤字が原因でした。ありがとうございました

現在は以下のバッチでとりあえず動いています（テストを仕切ったわけじゃないのでバグはまだあるかも）

@echo off

setlocal enabledelayedexpansion

set STDIN=
set PASSWORD=
set RAWFNAME=
set COMPFNAME=
set COMPMODE=zip

if not "%1" == "" (
	set RAWFNAME=%1
) else (
	set /p RAWFNAME="対象ファイル入力..."
	if "!RAWFNAME!" == "" (
		echo bye%
		exit /B FALSE
	)
)

if not "%2" == "" (
	set COMPFNAME=%1
) else (
	set /P COMPFNAME="圧縮後ファイル名入力...（省略可）"

rem	echo !COMPFNAME!

	if "!COMPFNAME!" == "" (
		set COMPFNAME=!RAWFNAME:.=!
		set COMPFNAME=!COMPFNAME:\=!
	) else (
		set COMPFNAME=!COMPFNAME:.=!
		set COMPFNAME=!COMPFNAME:\=!
	)

rem	echo "!COMPFNAME!"
) 

set /p STDIN="パスワード入力...（省略可）"
if not "%STDIN%" == "" (
	set PASSWORD=-p%STDIN%
rem	echo "!PASSWORD!"
)

set /p COMPMODE="圧縮方法:拡張子...（デフォルト:zip）"

set COMPFNAME=%COMPFNAME%.%COMPMODE%
set COMPMODE=-t%COMPMODE%

rem echo "%COMPMODE%"
rem echo "%RAWFNAME%"
rem echo "%COMPFNAME%"
rem echo "%COMPMODE%"
rem echo "%PASSWORD%"

setlocal disabledelayedexpansion

@echo on
7z a %COMPMODE% %COMPFNAME% %RAWFNAME% %PASSWORD% -xr!*7z -xr!*zip -xr!*BAK -xr!*lnk

Answer 2

直接的な回答でないですが、自分の場合の解決方法です。

1. まずは、単純なワンラインのコマンドで望みの結果がでるようコマンドの引数などを確認します。
2. 試してらっしゃいますが、echo で、変数を使った場合に、１の結果と同じになるか確認します。

まずは、１が望みの結果になるコマンド引数などの確認を最初にしては、いかがでしょうか。

Comments

[WoodenHamlet]

ありがとうございます。引き続きいろいろと試してみたいと思います。